+# Note: we use this to wait until vncterm/spiceterm is ready
+sub wait_for_vnc_port {
+ my ($port, $family, $timeout) = @_;
+
+ $timeout = 5 if !$timeout;
+ my $sleeptime = 0;
+ my $starttime = [gettimeofday];
+ my $elapsed;
+
+ my $cmd = ['/bin/ss', '-Htln', "sport = :$port"];
+ push @$cmd, $family == AF_INET6 ? '-6' : '-4' if defined($family);
+
+ my $found;
+ while (($elapsed = tv_interval($starttime)) < $timeout) {
+ # -Htln = don't print header, tcp, listening sockets only, numeric ports
+ run_command($cmd, outfunc => sub {
+ my $line = shift;
+ if ($line =~ m/^LISTEN\s+\d+\s+\d+\s+\S+:(\d+)\s/) {
+ $found = 1 if ($port == $1);
+ }
+ });
+ return 1 if $found;
+ $sleeptime += 100000 if $sleeptime < 1000000;
+ usleep($sleeptime);
+ }
+
+ die "Timeout while waiting for port '$port' to get ready!\n";
+}
+
+sub next_unused_port {
+ my ($range_start, $range_end, $family, $address) = @_;
+
+ # We use a file to register allocated ports.
+ # Those registrations expires after $expiretime.
+ # We use this to avoid race conditions between
+ # allocation and use of ports.
+
+ my $filename = "/var/tmp/pve-reserved-ports";
+
+ my $code = sub {
+
+ my $expiretime = 5;
+ my $ctime = time();
+
+ my $ports = {};
+
+ if (my $fh = IO::File->new ($filename, "r")) {
+ while (my $line = <$fh>) {
+ if ($line =~ m/^(\d+)\s(\d+)$/) {
+ my ($port, $timestamp) = ($1, $2);
+ if (($timestamp + $expiretime) > $ctime) {
+ $ports->{$port} = $timestamp; # not expired
+ }
+ }
+ }
+ }
+
+ my $newport;
+ my %sockargs = (Listen => 5,
+ ReuseAddr => 1,
+ Family => $family,
+ Proto => IPPROTO_TCP,
+ GetAddrInfoFlags => 0);
+ $sockargs{LocalAddr} = $address if defined($address);
+
+ for (my $p = $range_start; $p < $range_end; $p++) {
+ next if $ports->{$p}; # reserved
+
+ $sockargs{LocalPort} = $p;
+ my $sock = IO::Socket::IP->new(%sockargs);
+
+ if ($sock) {
+ close($sock);
+ $newport = $p;
+ $ports->{$p} = $ctime;
+ last;
+ }
+ }
+
+ my $data = "";
+ foreach my $p (keys %$ports) {
+ $data .= "$p $ports->{$p}\n";
+ }
+
+ file_set_contents($filename, $data);
+
+ return $newport;
+ };
+
+ my $p = lock_file('/var/lock/pve-ports.lck', 10, $code);
+ die $@ if $@;
+
+ die "unable to find free port (${range_start}-${range_end})\n" if !$p;
+
+ return $p;
+}
+
+sub next_migrate_port {
+ my ($family, $address) = @_;
+ return next_unused_port(60000, 60050, $family, $address);
+}
+
+sub next_vnc_port {
+ my ($family, $address) = @_;
+ return next_unused_port(5900, 6000, $family, $address);
+}
+
+sub next_spice_port {
+ my ($family, $address) = @_;
+ return next_unused_port(61000, 61099, $family, $address);
+}
+
+sub must_stringify {
+ my ($value) = @_;
+ eval { $value = "$value" };
+ return "error turning value into a string: $@" if $@;
+ return $value;
+}
+
+# sigkill after $timeout a $sub running in a fork if it can't write a pipe
+# the $sub has to return a single scalar
+sub run_fork_with_timeout {
+ my ($timeout, $sub) = @_;
+
+ my $res;
+ my $error;
+ my $pipe_out = IO::Pipe->new();
+
+ # disable pending alarms, save their remaining time
+ my $prev_alarm = alarm 0;
+
+ # avoid leaving a zombie if the parent gets interrupted
+ my $sig_received;
+
+ my $child = fork();
+ if (!defined($child)) {
+ die "fork failed: $!\n";
+ return $res;
+ }
+
+ if (!$child) {
+ $pipe_out->writer();
+
+ eval {
+ $res = $sub->();
+ print {$pipe_out} encode_json({ result => $res });
+ $pipe_out->flush();
+ };
+ if (my $err = $@) {
+ print {$pipe_out} encode_json({ error => must_stringify($err) });
+ $pipe_out->flush();
+ POSIX::_exit(1);
+ }
+ POSIX::_exit(0);
+ }
+
+ local $SIG{INT} = sub { $sig_received++; };
+ local $SIG{TERM} = sub {
+ $error //= "interrupted by unexpected signal\n";
+ kill('TERM', $child);
+ };
+
+ $pipe_out->reader();
+
+ my $readvalues = sub {
+ local $/ = undef;
+ my $child_res = decode_json(readline_nointr($pipe_out));
+ $res = $child_res->{result};
+ $error = $child_res->{error};
+ };
+ eval {
+ if (defined($timeout)) {
+ run_with_timeout($timeout, $readvalues);
+ } else {
+ $readvalues->();
+ }
+ };
+ warn $@ if $@;
+ $pipe_out->close();
+ kill('KILL', $child);
+ waitpid($child, 0);
+
+ alarm $prev_alarm;
+ die "interrupted by unexpected signal\n" if $sig_received;
+
+ die $error if $error;
+ return $res;
+}
+
+sub run_fork {
+ my ($code) = @_;
+ return run_fork_with_timeout(undef, $code);
+}
+
+# NOTE: NFS syscall can't be interrupted, so alarm does
+# not work to provide timeouts.
+# from 'man nfs': "Only SIGKILL can interrupt a pending NFS operation"
+# So fork() before using Filesys::Df
+sub df {
+ my ($path, $timeout) = @_;
+
+ my $df = sub { return Filesys::Df::df($path, 1) };
+
+ my $res = eval { run_fork_with_timeout($timeout, $df) } // {};
+ warn $@ if $@;
+
+ # untaint the values
+ my ($blocks, $used, $bavail) = map { defined($_) ? (/^(\d+)$/) : 0 }
+ $res->@{qw(blocks used bavail)};
+
+ return {
+ total => $blocks,
+ used => $used,
+ avail => $bavail,
+ };
+}
+
+sub du {
+ my ($path, $timeout) = @_;
+
+ my $size;
+
+ $timeout //= 10;
+
+ my $parser = sub {
+ my $line = shift;
+
+ if ($line =~ m/^(\d+)\s+total$/) {
+ $size = $1;
+ }
+ };
+
+ run_command(['du', '-scb', $path], outfunc => $parser, timeout => $timeout);
+
+ return $size;
+}
+
+# UPID helper
+# We use this to uniquely identify a process.
+# An 'Unique Process ID' has the following format:
+# "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
+
+sub upid_encode {
+ my $d = shift;
+
+ # Note: pstart can be > 32bit if uptime > 497 days, so this can result in
+ # more that 8 characters for pstart
+ return sprintf("UPID:%s:%08X:%08X:%08X:%s:%s:%s:", $d->{node}, $d->{pid},
+ $d->{pstart}, $d->{starttime}, $d->{type}, $d->{id},
+ $d->{user});
+}
+
+sub upid_decode {
+ my ($upid, $noerr) = @_;
+
+ my $res;
+ my $filename;
+
+ # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
+ # Note: allow up to 9 characters for pstart (work until 20 years uptime)
+ if ($upid =~ m/^UPID:([a-zA-Z0-9]([a-zA-Z0-9\-]*[a-zA-Z0-9])?):([0-9A-Fa-f]{8}):([0-9A-Fa-f]{8,9}):([0-9A-Fa-f]{8}):([^:\s]+):([^:\s]*):([^:\s]+):$/) {
+ $res->{node} = $1;
+ $res->{pid} = hex($3);
+ $res->{pstart} = hex($4);
+ $res->{starttime} = hex($5);
+ $res->{type} = $6;
+ $res->{id} = $7;
+ $res->{user} = $8;
+
+ my $subdir = substr($5, 7, 8);
+ $filename = "$pvetaskdir/$subdir/$upid";
+
+ } else {
+ return undef if $noerr;
+ die "unable to parse worker upid '$upid'\n";
+ }
+
+ return wantarray ? ($res, $filename) : $res;
+}
+
+sub upid_open {
+ my ($upid) = @_;
+
+ my ($task, $filename) = upid_decode($upid);
+
+ my $dirname = dirname($filename);
+ make_path($dirname);
+
+ my $wwwid = getpwnam('www-data') ||
+ die "getpwnam failed";
+
+ my $perm = 0640;
+
+ my $outfh = IO::File->new ($filename, O_WRONLY|O_CREAT|O_EXCL, $perm) ||
+ die "unable to create output file '$filename' - $!\n";
+ chown $wwwid, -1, $outfh;
+
+ return $outfh;
+};
+
+sub upid_read_status {
+ my ($upid) = @_;
+
+ my ($task, $filename) = upid_decode($upid);
+ my $fh = IO::File->new($filename, "r");
+ return "unable to open file - $!" if !$fh;
+ my $maxlen = 4096;
+ sysseek($fh, -$maxlen, 2);
+ my $readbuf = '';
+ my $br = sysread($fh, $readbuf, $maxlen);
+ close($fh);
+ if ($br) {
+ return "unable to extract last line"
+ if $readbuf !~ m/\n?(.+)$/;
+ my $line = $1;
+ if ($line =~ m/^TASK OK$/) {
+ return 'OK';
+ } elsif ($line =~ m/^TASK ERROR: (.+)$/) {
+ return $1;
+ } else {
+ return "unexpected status";
+ }
+ }
+ return "unable to read tail (got $br bytes)";
+}
+
+# useful functions to store comments in config files
+sub encode_text {
+ my ($text) = @_;
+
+ # all control and hi-bit characters, and ':'
+ my $unsafe = "^\x20-\x39\x3b-\x7e";
+ return uri_escape(Encode::encode("utf8", $text), $unsafe);
+}
+
+sub decode_text {
+ my ($data) = @_;
+
+ return Encode::decode("utf8", uri_unescape($data));
+}
+
+# depreciated - do not use!
+# we now decode all parameters by default
+sub decode_utf8_parameters {
+ my ($param) = @_;
+
+ foreach my $p (qw(comment description firstname lastname)) {
+ $param->{$p} = decode('utf8', $param->{$p}) if $param->{$p};
+ }
+
+ return $param;
+}
+
+sub random_ether_addr {
+ my ($prefix) = @_;
+
+ my ($seconds, $microseconds) = gettimeofday;
+
+ my $rand = Digest::SHA::sha1($$, rand(), $seconds, $microseconds);
+
+ # clear multicast, set local id
+ vec($rand, 0, 8) = (vec($rand, 0, 8) & 0xfe) | 2;
+
+ my $addr = sprintf("%02X:%02X:%02X:%02X:%02X:%02X", unpack("C6", $rand));
+ if (defined($prefix)) {
+ $addr = uc($prefix) . substr($addr, length($prefix));
+ }
+ return $addr;
+}
+
+sub shellquote {
+ my $str = shift;
+
+ return String::ShellQuote::shell_quote($str);
+}
+
+sub cmd2string {
+ my ($cmd) = @_;
+
+ die "no arguments" if !$cmd;
+
+ return $cmd if !ref($cmd);
+
+ my @qa = ();
+ foreach my $arg (@$cmd) { push @qa, shellquote($arg); }
+
+ return join (' ', @qa);
+}
+
+# split an shell argument string into an array,
+sub split_args {
+ my ($str) = @_;
+
+ return $str ? [ Text::ParseWords::shellwords($str) ] : [];
+}
+
+sub dump_logfile {
+ my ($filename, $start, $limit, $filter) = @_;
+
+ my $lines = [];
+ my $count = 0;
+
+ my $fh = IO::File->new($filename, "r");
+ if (!$fh) {
+ $count++;
+ push @$lines, { n => $count, t => "unable to open file - $!"};
+ return ($count, $lines);
+ }
+
+ $start = 0 if !$start;
+ $limit = 50 if !$limit;
+
+ my $line;
+
+ if ($filter) {
+ # duplicate code, so that we do not slow down normal path
+ while (defined($line = <$fh>)) {
+ next if $line !~ m/$filter/;
+ next if $count++ < $start;
+ next if $limit <= 0;
+ chomp $line;
+ push @$lines, { n => $count, t => $line};
+ $limit--;
+ }
+ } else {
+ while (defined($line = <$fh>)) {
+ next if $count++ < $start;
+ next if $limit <= 0;
+ chomp $line;
+ push @$lines, { n => $count, t => $line};
+ $limit--;
+ }
+ }
+
+ close($fh);
+
+ # HACK: ExtJS store.guaranteeRange() does not like empty array
+ # so we add a line
+ if (!$count) {
+ $count++;
+ push @$lines, { n => $count, t => "no content"};
+ }
+
+ return ($count, $lines);
+}
+
+sub dump_journal {
+ my ($start, $limit, $since, $until, $service) = @_;
+
+ my $lines = [];
+ my $count = 0;
+
+ $start = 0 if !$start;
+ $limit = 50 if !$limit;
+
+ my $parser = sub {
+ my $line = shift;
+
+ return if $count++ < $start;
+ return if $limit <= 0;
+ push @$lines, { n => int($count), t => $line};
+ $limit--;
+ };
+
+ my $cmd = ['journalctl', '-o', 'short', '--no-pager'];
+
+ push @$cmd, '--unit', $service if $service;
+ push @$cmd, '--since', $since if $since;
+ push @$cmd, '--until', $until if $until;
+ run_command($cmd, outfunc => $parser);
+
+ # HACK: ExtJS store.guaranteeRange() does not like empty array
+ # so we add a line
+ if (!$count) {
+ $count++;
+ push @$lines, { n => $count, t => "no content"};
+ }
+
+ return ($count, $lines);
+}
+
+sub dir_glob_regex {
+ my ($dir, $regex) = @_;
+
+ my $dh = IO::Dir->new ($dir);
+ return wantarray ? () : undef if !$dh;
+
+ while (defined(my $tmp = $dh->read)) {
+ if (my @res = $tmp =~ m/^($regex)$/) {
+ $dh->close;
+ return wantarray ? @res : $tmp;
+ }
+ }
+ $dh->close;
+
+ return wantarray ? () : undef;
+}
+
+sub dir_glob_foreach {
+ my ($dir, $regex, $func) = @_;
+
+ my $dh = IO::Dir->new ($dir);
+ if (defined $dh) {
+ while (defined(my $tmp = $dh->read)) {
+ if (my @res = $tmp =~ m/^($regex)$/) {
+ &$func (@res);
+ }
+ }
+ }
+}
+
+sub assert_if_modified {
+ my ($digest1, $digest2) = @_;
+
+ if ($digest1 && $digest2 && ($digest1 ne $digest2)) {
+ die "detected modified configuration - file changed by other user? Try again.\n";
+ }
+}
+
+# Digest for short strings
+# like FNV32a, but we only return 31 bits (positive numbers)
+sub fnv31a {
+ my ($string) = @_;
+
+ my $hval = 0x811c9dc5;
+
+ foreach my $c (unpack('C*', $string)) {
+ $hval ^= $c;
+ $hval += (
+ (($hval << 1) ) +
+ (($hval << 4) ) +
+ (($hval << 7) ) +
+ (($hval << 8) ) +
+ (($hval << 24) ) );
+ $hval = $hval & 0xffffffff;
+ }
+ return $hval & 0x7fffffff;
+}
+
+sub fnv31a_hex { return sprintf("%X", fnv31a(@_)); }
+
+sub unpack_sockaddr_in46 {
+ my ($sin) = @_;
+ my $family = Socket::sockaddr_family($sin);
+ my ($port, $host) = ($family == AF_INET6 ? Socket::unpack_sockaddr_in6($sin)
+ : Socket::unpack_sockaddr_in($sin));
+ return ($family, $port, $host);
+}
+
+sub getaddrinfo_all {
+ my ($hostname, @opts) = @_;
+ my %hints = ( flags => AI_V4MAPPED | AI_ALL,
+ @opts );
+ my ($err, @res) = Socket::getaddrinfo($hostname, '0', \%hints);
+ die "failed to get address info for: $hostname: $err\n" if $err;
+ return @res;
+}
+
+sub get_host_address_family {
+ my ($hostname, $socktype) = @_;
+ my @res = getaddrinfo_all($hostname, socktype => $socktype);
+ return $res[0]->{family};
+}
+
+# get the fully qualified domain name of a host
+# same logic as hostname(1): The FQDN is the name getaddrinfo(3) returns,
+# given a nodename as a parameter
+sub get_fqdn {
+ my ($nodename) = @_;
+
+ my $hints = {
+ flags => AI_CANONNAME,
+ socktype => SOCK_DGRAM
+ };
+
+ my ($err, @addrs) = Socket::getaddrinfo($nodename, undef, $hints);
+
+ die "getaddrinfo: $err" if $err;
+
+ return $addrs[0]->{canonname};
+}
+
+# Parses any sane kind of host, or host+port pair:
+# The port is always optional and thus may be undef.
+sub parse_host_and_port {
+ my ($address) = @_;
+ if ($address =~ /^($IPV4RE|[[:alnum:]\-.]+)(?::(\d+))?$/ || # ipv4 or host with optional ':port'
+ $address =~ /^\[($IPV6RE|$IPV4RE|[[:alnum:]\-.]+)\](?::(\d+))?$/ || # anything in brackets with optional ':port'
+ $address =~ /^($IPV6RE)(?:\.(\d+))?$/) # ipv6 with optional port separated by dot
+ {
+ return ($1, $2, 1); # end with 1 to support simple if(parse...) tests
+ }
+ return; # nothing
+}
+
+sub unshare($) {
+ my ($flags) = @_;
+ return 0 == syscall(PVE::APIClient::Syscall::unshare, $flags);
+}
+
+sub setns($$) {
+ my ($fileno, $nstype) = @_;
+ return 0 == syscall(PVE::APIClient::Syscall::setns, $fileno, $nstype);
+}
+
+sub syncfs($) {
+ my ($fileno) = @_;
+ return 0 == syscall(PVE::APIClient::Syscall::syncfs, $fileno);
+}
+
+sub sync_mountpoint {
+ my ($path) = @_;
+ sysopen my $fd, $path, O_PATH or die "failed to open $path: $!\n";
+ my $result = syncfs(fileno($fd));
+ close($fd);
+ return $result;
+}
+
+# support sending multi-part mail messages with a text and or a HTML part
+# mailto may be a single email string or an array of receivers
+sub sendmail {
+ my ($mailto, $subject, $text, $html, $mailfrom, $author) = @_;
+ my $mail_re = qr/[^-a-zA-Z0-9+._@]/;
+
+ $mailto = [ $mailto ] if !ref($mailto);
+
+ foreach (@$mailto) {
+ die "illegal character in mailto address\n"
+ if ($_ =~ $mail_re);
+ }
+
+ my $rcvrtxt = join (', ', @$mailto);
+
+ $mailfrom = $mailfrom || "root";
+ die "illegal character in mailfrom address\n"
+ if $mailfrom =~ $mail_re;
+
+ $author = $author || 'Proxmox VE';
+
+ open (MAIL, "|-", "sendmail", "-B", "8BITMIME", "-f", $mailfrom, @$mailto) ||
+ die "unable to open 'sendmail' - $!";
+
+ # multipart spec see https://www.ietf.org/rfc/rfc1521.txt
+ my $boundary = "----_=_NextPart_001_".int(time).$$;
+
+ print MAIL "Content-Type: multipart/alternative;\n";
+ print MAIL "\tboundary=\"$boundary\"\n";
+ print MAIL "MIME-Version: 1.0\n";
+
+ print MAIL "FROM: $author <$mailfrom>\n";
+ print MAIL "TO: $rcvrtxt\n";
+ print MAIL "SUBJECT: $subject\n";
+ print MAIL "\n";
+ print MAIL "This is a multi-part message in MIME format.\n\n";
+ print MAIL "--$boundary\n";
+
+ if (defined($text)) {
+ print MAIL "Content-Type: text/plain;\n";
+ print MAIL "\tcharset=\"UTF8\"\n";
+ print MAIL "Content-Transfer-Encoding: 8bit\n";
+ print MAIL "\n";
+
+ # avoid 'remove extra line breaks' issue (MS Outlook)
+ my $fill = ' ';
+ $text =~ s/^/$fill/gm;
+
+ print MAIL $text;
+
+ print MAIL "\n--$boundary\n";
+ }
+
+ if (defined($html)) {
+ print MAIL "Content-Type: text/html;\n";
+ print MAIL "\tcharset=\"UTF8\"\n";
+ print MAIL "Content-Transfer-Encoding: 8bit\n";
+ print MAIL "\n";
+
+ print MAIL $html;
+
+ print MAIL "\n--$boundary--\n";
+ }
+
+ close(MAIL);
+}
+
+sub tempfile {
+ my ($perm, %opts) = @_;
+
+ # default permissions are stricter than with file_set_contents
+ $perm = 0600 if !defined($perm);
+
+ my $dir = $opts{dir} // '/run';
+ my $mode = $opts{mode} // O_RDWR;
+ $mode |= O_EXCL if !$opts{allow_links};
+
+ my $fh = IO::File->new($dir, $mode | O_TMPFILE, $perm);
+ if (!$fh && $! == EOPNOTSUPP) {
+ $dir = '/tmp' if !defined($opts{dir});
+ $dir .= "/.tmpfile.$$";
+ $fh = IO::File->new($dir, $mode | O_CREAT | O_EXCL, $perm);
+ unlink($dir) if $fh;
+ }
+ die "failed to create tempfile: $!\n" if !$fh;
+ return $fh;
+}
+
+sub tempfile_contents {
+ my ($data, $perm, %opts) = @_;
+
+ my $fh = tempfile($perm, %opts);
+ eval {
+ die "unable to write to tempfile: $!\n" if !print {$fh} $data;
+ die "unable to flush to tempfile: $!\n" if !defined($fh->flush());
+ };
+ if (my $err = $@) {
+ close $fh;
+ die $err;
+ }
+
+ return ("/proc/$$/fd/".$fh->fileno, $fh);
+}
+
+sub validate_ssh_public_keys {
+ my ($raw) = @_;
+ my @lines = split(/\n/, $raw);
+
+ foreach my $line (@lines) {
+ next if $line =~ m/^\s*$/;
+ eval {
+ my ($filename, $handle) = tempfile_contents($line);
+ run_command(["ssh-keygen", "-l", "-f", $filename],
+ outfunc => sub {}, errfunc => sub {});
+ };
+ die "SSH public key validation error\n" if $@;
+ }
+}
+
+sub openat($$$;$) {
+ my ($dirfd, $pathname, $flags, $mode) = @_;
+ my $fd = syscall(PVE::APIClient::Syscall::openat, $dirfd, $pathname, $flags, $mode//0);
+ return undef if $fd < 0;
+ # sysopen() doesn't deal with numeric file descriptors apparently
+ # so we need to convert to a mode string for IO::Handle->new_from_fd
+ my $flagstr = ($flags & O_RDWR) ? 'rw' : ($flags & O_WRONLY) ? 'w' : 'r';
+ my $handle = IO::Handle->new_from_fd($fd, $flagstr);
+ return $handle if $handle;
+ my $err = $!; # save error before closing the raw fd
+ syscall(PVE::APIClient::Syscall::close, $fd); # close
+ $! = $err;
+ return undef;
+}
+
+sub mkdirat($$$) {
+ my ($dirfd, $name, $mode) = @_;
+ return syscall(PVE::APIClient::Syscall::mkdirat, $dirfd, $name, $mode) == 0;
+}
+
+my $salt_starter = time();
+
+sub encrypt_pw {
+ my ($pw) = @_;
+
+ $salt_starter++;
+ my $salt = substr(Digest::SHA::sha1_base64(time() + $salt_starter + $$), 0, 8);
+
+ # crypt does not want '+' in salt (see 'man crypt')
+ $salt =~ s/\+/X/g;
+
+ return crypt(encode("utf8", $pw), "\$5\$$salt\$");
+}
+
+# intended usage: convert_size($val, "kb" => "gb")
+# we round up to the next integer by default
+# E.g. `convert_size(1023, "b" => "kb")` returns 1
+# use $no_round_up to switch this off, above example would then return 0
+# this is also true for converting down e.g. 0.0005 gb to mb returns 1
+# (0 if $no_round_up is true)
+# allowed formats for value:
+# 1234
+# 1234.
+# 1234.1234
+# .1234
+sub convert_size {
+ my ($value, $from, $to, $no_round_up) = @_;
+
+ my $units = {
+ b => 0,
+ kb => 1,
+ mb => 2,
+ gb => 3,
+ tb => 4,
+ pb => 5,
+ };
+
+ die "no value given"
+ if !defined($value) || $value eq "";
+
+ $from = lc($from // ''); $to = lc($to // '');
+ die "unknown 'from' and/or 'to' units ($from => $to)"
+ if !defined($units->{$from}) || !defined($units->{$to});
+
+ die "value '$value' is not a valid, positive number"
+ if $value !~ m/^(?:[0-9]+\.?[0-9]*|[0-9]*\.[0-9]+)$/;
+
+ my $shift_amount = ($units->{$from} - $units->{$to}) * 10;
+
+ $value *= 2**$shift_amount;
+ $value++ if !$no_round_up && ($value - int($value)) > 0.0;
+
+ return int($value);
+}
+
+# uninterruptible readline
+# retries on EINTR
+sub readline_nointr {
+ my ($fh) = @_;
+ my $line;
+ while (1) {
+ $line = <$fh>;
+ last if defined($line) || ($! != EINTR);
+ }
+ return $line;
+}
+