]>
Commit | Line | Data |
---|---|---|
1 | package PVE::Storage::RBDPlugin; | |
2 | ||
3 | use strict; | |
4 | use warnings; | |
5 | ||
6 | use IO::File; | |
7 | use JSON; | |
8 | use Net::IP; | |
9 | ||
10 | use PVE::CephConfig; | |
11 | use PVE::JSONSchema qw(get_standard_option); | |
12 | use PVE::ProcFSTools; | |
13 | use PVE::RADOS; | |
14 | use PVE::Storage::Plugin; | |
15 | use PVE::Tools qw(run_command trim); | |
16 | ||
17 | use base qw(PVE::Storage::Plugin); | |
18 | ||
19 | my $get_parent_image_name = sub { | |
20 | my ($parent) = @_; | |
21 | return undef if !$parent; | |
22 | return $parent->{image} . "@" . $parent->{snapshot}; | |
23 | }; | |
24 | ||
25 | my sub get_rbd_path { | |
26 | my ($scfg, $volume) = @_; | |
27 | my $path = $scfg->{pool} ? $scfg->{pool} : 'rbd'; | |
28 | $path .= "/$scfg->{namespace}" if defined($scfg->{namespace}); | |
29 | $path .= "/$volume" if defined($volume); | |
30 | return $path; | |
31 | }; | |
32 | ||
33 | my $build_cmd = sub { | |
34 | my ($binary, $scfg, $storeid, $op, @options) = @_; | |
35 | ||
36 | my $cmd_option = PVE::CephConfig::ceph_connect_option($scfg, $storeid); | |
37 | my $pool = $scfg->{pool} ? $scfg->{pool} : 'rbd'; | |
38 | ||
39 | my $cmd = [$binary, '-p', $pool]; | |
40 | ||
41 | if (defined(my $namespace = $scfg->{namespace})) { | |
42 | # some subcommands will fail if the --namespace parameter is present | |
43 | my $no_namespace_parameter = { | |
44 | unmap => 1, | |
45 | }; | |
46 | push @$cmd, '--namespace', "$namespace" if !$no_namespace_parameter->{$op}; | |
47 | } | |
48 | push @$cmd, '-c', $cmd_option->{ceph_conf} if ($cmd_option->{ceph_conf}); | |
49 | push @$cmd, '-m', $cmd_option->{mon_host} if ($cmd_option->{mon_host}); | |
50 | push @$cmd, '--auth_supported', $cmd_option->{auth_supported} if ($cmd_option->{auth_supported}); | |
51 | push @$cmd, '-n', "client.$cmd_option->{userid}" if ($cmd_option->{userid}); | |
52 | push @$cmd, '--keyring', $cmd_option->{keyring} if ($cmd_option->{keyring}); | |
53 | ||
54 | push @$cmd, $op; | |
55 | ||
56 | push @$cmd, @options if scalar(@options); | |
57 | ||
58 | return $cmd; | |
59 | }; | |
60 | ||
61 | my $rbd_cmd = sub { | |
62 | my ($scfg, $storeid, $op, @options) = @_; | |
63 | ||
64 | return $build_cmd->('/usr/bin/rbd', $scfg, $storeid, $op, @options); | |
65 | }; | |
66 | ||
67 | my $rados_cmd = sub { | |
68 | my ($scfg, $storeid, $op, @options) = @_; | |
69 | ||
70 | return $build_cmd->('/usr/bin/rados', $scfg, $storeid, $op, @options); | |
71 | }; | |
72 | ||
73 | my $librados_connect = sub { | |
74 | my ($scfg, $storeid, $options) = @_; | |
75 | ||
76 | my $librados_config = PVE::CephConfig::ceph_connect_option($scfg, $storeid); | |
77 | ||
78 | my $rados = PVE::RADOS->new(%$librados_config); | |
79 | ||
80 | return $rados; | |
81 | }; | |
82 | ||
83 | # needed for volumes created using ceph jewel (or higher) | |
84 | my $krbd_feature_update = sub { | |
85 | my ($scfg, $storeid, $name) = @_; | |
86 | ||
87 | my (@disable, @enable); | |
88 | my ($kmajor, $kminor) = PVE::ProcFSTools::kernel_version(); | |
89 | ||
90 | if ($kmajor > 5 || $kmajor == 5 && $kminor >= 3) { | |
91 | # 'deep-flatten' can only be disabled, not enabled after image creation | |
92 | push @enable, 'fast-diff', 'object-map'; | |
93 | } else { | |
94 | push @disable, 'fast-diff', 'object-map', 'deep-flatten'; | |
95 | } | |
96 | ||
97 | if ($kmajor >= 5) { | |
98 | push @enable, 'exclusive-lock'; | |
99 | } else { | |
100 | push @disable, 'exclusive-lock'; | |
101 | } | |
102 | ||
103 | my $active_features_list = (rbd_volume_info($scfg, $storeid, $name))[4]; | |
104 | my $active_features = { map { $_ => 1 } @$active_features_list }; | |
105 | ||
106 | my $to_disable = join(',', grep { $active_features->{$_} } @disable); | |
107 | my $to_enable = join(',', grep { !$active_features->{$_} } @enable ); | |
108 | ||
109 | if ($to_disable) { | |
110 | print "disable RBD image features this kernel RBD drivers is not compatible with: $to_disable\n"; | |
111 | my $cmd = $rbd_cmd->($scfg, $storeid, 'feature', 'disable', $name, $to_disable); | |
112 | run_rbd_command( | |
113 | $cmd, | |
114 | errmsg => "could not disable krbd-incompatible image features '$to_disable' for rbd image: $name", | |
115 | ); | |
116 | } | |
117 | if ($to_enable) { | |
118 | print "enable RBD image features this kernel RBD drivers supports: $to_enable\n"; | |
119 | eval { | |
120 | my $cmd = $rbd_cmd->($scfg, $storeid, 'feature', 'enable', $name, $to_enable); | |
121 | run_rbd_command( | |
122 | $cmd, | |
123 | errmsg => "could not enable krbd-compatible image features '$to_enable' for rbd image: $name", | |
124 | ); | |
125 | }; | |
126 | warn "$@" if $@; | |
127 | } | |
128 | }; | |
129 | ||
130 | sub run_rbd_command { | |
131 | my ($cmd, %args) = @_; | |
132 | ||
133 | my $lasterr; | |
134 | my $errmsg = $args{errmsg} . ": " || ""; | |
135 | if (!exists($args{errfunc})) { | |
136 | # ' error: 2014-02-06 11:51:59.839135 7f09f94d0760 -1 librbd: snap_unprotect: can't unprotect; | |
137 | # at least 1 child(ren) in pool cephstor1 | |
138 | $args{errfunc} = sub { | |
139 | my $line = shift; | |
140 | if ($line =~ m/^\d{4}-\d{2}-\d{2} \d{2}:\d{2}:\d{2}\.\d+ [0-9a-f]+ [\-\d]+ librbd: (.*)$/) { | |
141 | $lasterr = "$1\n"; | |
142 | } else { | |
143 | $lasterr = $line; | |
144 | } | |
145 | print STDERR $lasterr; | |
146 | *STDERR->flush(); | |
147 | }; | |
148 | } | |
149 | ||
150 | eval { run_command($cmd, %args); }; | |
151 | if (my $err = $@) { | |
152 | die $errmsg . $lasterr if length($lasterr); | |
153 | die $err; | |
154 | } | |
155 | ||
156 | return undef; | |
157 | } | |
158 | ||
159 | sub rbd_ls { | |
160 | my ($scfg, $storeid) = @_; | |
161 | ||
162 | my $pool = $scfg->{pool} ? $scfg->{pool} : 'rbd'; | |
163 | $pool .= "/$scfg->{namespace}" if defined($scfg->{namespace}); | |
164 | ||
165 | my $raw = ''; | |
166 | my $parser = sub { $raw .= shift }; | |
167 | ||
168 | my $cmd = $rbd_cmd->($scfg, $storeid, 'ls', '-l', '--format', 'json'); | |
169 | eval { | |
170 | run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser); | |
171 | }; | |
172 | my $err = $@; | |
173 | ||
174 | die $err if $err && $err !~ m/doesn't contain rbd images/ ; | |
175 | ||
176 | my $result; | |
177 | if ($raw eq '') { | |
178 | $result = []; | |
179 | } elsif ($raw =~ m/^(\[.*\])$/s) { # untaint | |
180 | $result = JSON::decode_json($1); | |
181 | } else { | |
182 | die "got unexpected data from rbd ls: '$raw'\n"; | |
183 | } | |
184 | ||
185 | my $list = {}; | |
186 | ||
187 | foreach my $el (@$result) { | |
188 | next if defined($el->{snapshot}); | |
189 | ||
190 | my $image = $el->{image}; | |
191 | ||
192 | my ($owner) = $image =~ m/^(?:vm|base)-(\d+)-/; | |
193 | next if !defined($owner); | |
194 | ||
195 | $list->{$pool}->{$image} = { | |
196 | name => $image, | |
197 | size => $el->{size}, | |
198 | parent => $get_parent_image_name->($el->{parent}), | |
199 | vmid => $owner | |
200 | }; | |
201 | } | |
202 | ||
203 | return $list; | |
204 | } | |
205 | ||
206 | sub rbd_ls_snap { | |
207 | my ($scfg, $storeid, $name) = @_; | |
208 | ||
209 | my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'ls', $name, '--format', 'json'); | |
210 | ||
211 | my $raw = ''; | |
212 | run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => sub { $raw .= shift; }); | |
213 | ||
214 | my $list; | |
215 | if ($raw =~ m/^(\[.*\])$/s) { # untaint | |
216 | $list = eval { JSON::decode_json($1) }; | |
217 | die "invalid JSON output from 'rbd snap ls $name': $@\n" if $@; | |
218 | } else { | |
219 | die "got unexpected data from 'rbd snap ls $name': '$raw'\n"; | |
220 | } | |
221 | ||
222 | $list = [] if !defined($list); | |
223 | ||
224 | my $res = {}; | |
225 | foreach my $el (@$list) { | |
226 | my $snap = $el->{name}; | |
227 | my $protected = defined($el->{protected}) && $el->{protected} eq "true" ? 1 : undef; | |
228 | $res->{$snap} = { | |
229 | name => $snap, | |
230 | id => $el->{id} // undef, | |
231 | size => $el->{size} // 0, | |
232 | protected => $protected, | |
233 | }; | |
234 | } | |
235 | return $res; | |
236 | } | |
237 | ||
238 | sub rbd_volume_info { | |
239 | my ($scfg, $storeid, $volname, $snap) = @_; | |
240 | ||
241 | my $cmd = undef; | |
242 | ||
243 | my @options = ('info', $volname, '--format', 'json'); | |
244 | if ($snap) { | |
245 | push @options, '--snap', $snap; | |
246 | } | |
247 | ||
248 | $cmd = $rbd_cmd->($scfg, $storeid, @options); | |
249 | ||
250 | my $raw = ''; | |
251 | my $parser = sub { $raw .= shift }; | |
252 | ||
253 | run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser); | |
254 | ||
255 | my $volume; | |
256 | if ($raw eq '') { | |
257 | $volume = {}; | |
258 | } elsif ($raw =~ m/^(\{.*\})$/s) { # untaint | |
259 | $volume = JSON::decode_json($1); | |
260 | } else { | |
261 | die "got unexpected data from rbd info: '$raw'\n"; | |
262 | } | |
263 | ||
264 | $volume->{parent} = $get_parent_image_name->($volume->{parent}); | |
265 | $volume->{protected} = defined($volume->{protected}) && $volume->{protected} eq "true" ? 1 : undef; | |
266 | ||
267 | return $volume->@{qw(size parent format protected features)}; | |
268 | } | |
269 | ||
270 | # Configuration | |
271 | ||
272 | sub type { | |
273 | return 'rbd'; | |
274 | } | |
275 | ||
276 | sub plugindata { | |
277 | return { | |
278 | content => [ {images => 1, rootdir => 1}, { images => 1 }], | |
279 | }; | |
280 | } | |
281 | ||
282 | sub properties { | |
283 | return { | |
284 | monhost => { | |
285 | description => "IP addresses of monitors (for external clusters).", | |
286 | type => 'string', format => 'pve-storage-portal-dns-list', | |
287 | }, | |
288 | pool => { | |
289 | description => "Pool.", | |
290 | type => 'string', | |
291 | }, | |
292 | namespace => { | |
293 | description => "RBD Namespace.", | |
294 | type => 'string', | |
295 | }, | |
296 | username => { | |
297 | description => "RBD Id.", | |
298 | type => 'string', | |
299 | }, | |
300 | authsupported => { | |
301 | description => "Authsupported.", | |
302 | type => 'string', | |
303 | }, | |
304 | krbd => { | |
305 | description => "Always access rbd through krbd kernel module.", | |
306 | type => 'boolean', | |
307 | }, | |
308 | keyring => { | |
309 | description => "Client keyring contents (for external clusters).", | |
310 | type => 'string', | |
311 | }, | |
312 | }; | |
313 | } | |
314 | ||
315 | sub options { | |
316 | return { | |
317 | nodes => { optional => 1 }, | |
318 | disable => { optional => 1 }, | |
319 | monhost => { optional => 1}, | |
320 | pool => { optional => 1 }, | |
321 | namespace => { optional => 1 }, | |
322 | username => { optional => 1 }, | |
323 | content => { optional => 1 }, | |
324 | krbd => { optional => 1 }, | |
325 | keyring => { optional => 1 }, | |
326 | bwlimit => { optional => 1 }, | |
327 | }; | |
328 | } | |
329 | ||
330 | # Storage implementation | |
331 | ||
332 | sub on_add_hook { | |
333 | my ($class, $storeid, $scfg, %param) = @_; | |
334 | ||
335 | my $secret = $param{keyring} if defined $param{keyring} // undef; | |
336 | PVE::CephConfig::ceph_create_keyfile($scfg->{type}, $storeid, $secret); | |
337 | ||
338 | return; | |
339 | } | |
340 | ||
341 | sub on_update_hook { | |
342 | my ($class, $storeid, $scfg, %param) = @_; | |
343 | ||
344 | if (exists($param{keyring})) { | |
345 | if (defined($param{keyring})) { | |
346 | PVE::CephConfig::ceph_create_keyfile($scfg->{type}, $storeid, $param{keyring}); | |
347 | } else { | |
348 | PVE::CephConfig::ceph_remove_keyfile($scfg->{type}, $storeid); | |
349 | } | |
350 | } | |
351 | ||
352 | return; | |
353 | } | |
354 | ||
355 | sub on_delete_hook { | |
356 | my ($class, $storeid, $scfg) = @_; | |
357 | PVE::CephConfig::ceph_remove_keyfile($scfg->{type}, $storeid); | |
358 | return; | |
359 | } | |
360 | ||
361 | sub parse_volname { | |
362 | my ($class, $volname) = @_; | |
363 | ||
364 | if ($volname =~ m/^((base-(\d+)-\S+)\/)?((base)?(vm)?-(\d+)-\S+)$/) { | |
365 | return ('images', $4, $7, $2, $3, $5, 'raw'); | |
366 | } | |
367 | ||
368 | die "unable to parse rbd volume name '$volname'\n"; | |
369 | } | |
370 | ||
371 | sub path { | |
372 | my ($class, $scfg, $volname, $storeid, $snapname) = @_; | |
373 | ||
374 | my $cmd_option = PVE::CephConfig::ceph_connect_option($scfg, $storeid); | |
375 | my ($vtype, $name, $vmid) = $class->parse_volname($volname); | |
376 | $name .= '@'.$snapname if $snapname; | |
377 | ||
378 | my $rbd_path = get_rbd_path($scfg, $name); | |
379 | return ("/dev/rbd/${rbd_path}", $vmid, $vtype) if $scfg->{krbd}; | |
380 | ||
381 | my $path = "rbd:${rbd_path}"; | |
382 | ||
383 | $path .= ":conf=$cmd_option->{ceph_conf}" if $cmd_option->{ceph_conf}; | |
384 | if (defined($scfg->{monhost})) { | |
385 | my $monhost = PVE::CephConfig::hostlist($scfg->{monhost}, ';'); | |
386 | $monhost =~ s/:/\\:/g; | |
387 | $path .= ":mon_host=$monhost"; | |
388 | $path .= ":auth_supported=$cmd_option->{auth_supported}"; | |
389 | } | |
390 | ||
391 | $path .= ":id=$cmd_option->{userid}:keyring=$cmd_option->{keyring}" if ($cmd_option->{keyring}); | |
392 | ||
393 | return ($path, $vmid, $vtype); | |
394 | } | |
395 | ||
396 | sub find_free_diskname { | |
397 | my ($class, $storeid, $scfg, $vmid, $fmt, $add_fmt_suffix) = @_; | |
398 | ||
399 | my $cmd = $rbd_cmd->($scfg, $storeid, 'ls'); | |
400 | ||
401 | my $disk_list = []; | |
402 | ||
403 | my $parser = sub { | |
404 | my $line = shift; | |
405 | if ($line =~ m/^(.*)$/) { # untaint | |
406 | push @$disk_list, $1; | |
407 | } | |
408 | }; | |
409 | ||
410 | eval { | |
411 | run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser); | |
412 | }; | |
413 | my $err = $@; | |
414 | ||
415 | die $err if $err && $err !~ m/doesn't contain rbd images/; | |
416 | ||
417 | return PVE::Storage::Plugin::get_next_vm_diskname($disk_list, $storeid, $vmid, undef, $scfg); | |
418 | } | |
419 | ||
420 | sub create_base { | |
421 | my ($class, $storeid, $scfg, $volname) = @_; | |
422 | ||
423 | my $snap = '__base__'; | |
424 | ||
425 | my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) = | |
426 | $class->parse_volname($volname); | |
427 | ||
428 | die "create_base not possible with base image\n" if $isBase; | |
429 | ||
430 | my ($size, $parent, $format, undef) = rbd_volume_info($scfg, $storeid, $name); | |
431 | die "rbd volume info on '$name' failed\n" if !($size); | |
432 | ||
433 | die "rbd image must be at format V2" if $format ne "2"; | |
434 | ||
435 | die "volname '$volname' contains wrong information about parent $parent $basename\n" | |
436 | if $basename && (!$parent || $parent ne $basename."@".$snap); | |
437 | ||
438 | my $newname = $name; | |
439 | $newname =~ s/^vm-/base-/; | |
440 | ||
441 | my $newvolname = $basename ? "$basename/$newname" : "$newname"; | |
442 | ||
443 | my $cmd = $rbd_cmd->( | |
444 | $scfg, | |
445 | $storeid, | |
446 | 'rename', | |
447 | get_rbd_path($scfg, $name), | |
448 | get_rbd_path($scfg, $newname), | |
449 | ); | |
450 | run_rbd_command($cmd, errmsg => "rbd rename '$name' error"); | |
451 | ||
452 | my $running = undef; #fixme : is create_base always offline ? | |
453 | ||
454 | $class->volume_snapshot($scfg, $storeid, $newname, $snap, $running); | |
455 | ||
456 | my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $newname, $snap); | |
457 | ||
458 | if (!$protected){ | |
459 | my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'protect', $newname, '--snap', $snap); | |
460 | run_rbd_command($cmd, errmsg => "rbd protect $newname snap '$snap' error"); | |
461 | } | |
462 | ||
463 | return $newvolname; | |
464 | ||
465 | } | |
466 | ||
467 | sub clone_image { | |
468 | my ($class, $scfg, $storeid, $volname, $vmid, $snapname) = @_; | |
469 | ||
470 | my $snap = '__base__'; | |
471 | $snap = $snapname if length $snapname; | |
472 | ||
473 | my ($vtype, $basename, $basevmid, undef, undef, $isBase) = | |
474 | $class->parse_volname($volname); | |
475 | ||
476 | die "$volname is not a base image and snapname is not provided\n" | |
477 | if !$isBase && !length($snapname); | |
478 | ||
479 | my $name = $class->find_free_diskname($storeid, $scfg, $vmid); | |
480 | ||
481 | warn "clone $volname: $basename snapname $snap to $name\n"; | |
482 | ||
483 | if (length($snapname)) { | |
484 | my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $volname, $snapname); | |
485 | ||
486 | if (!$protected) { | |
487 | my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'protect', $volname, '--snap', $snapname); | |
488 | run_rbd_command($cmd, errmsg => "rbd protect $volname snap $snapname error"); | |
489 | } | |
490 | } | |
491 | ||
492 | my $newvol = "$basename/$name"; | |
493 | $newvol = $name if length($snapname); | |
494 | ||
495 | my $cmd = $rbd_cmd->( | |
496 | $scfg, | |
497 | $storeid, | |
498 | 'clone', | |
499 | get_rbd_path($scfg, $basename), | |
500 | '--snap', | |
501 | $snap, | |
502 | get_rbd_path($scfg, $name), | |
503 | ); | |
504 | ||
505 | run_rbd_command($cmd, errmsg => "rbd clone '$basename' error"); | |
506 | ||
507 | return $newvol; | |
508 | } | |
509 | ||
510 | sub alloc_image { | |
511 | my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_; | |
512 | ||
513 | ||
514 | die "illegal name '$name' - should be 'vm-$vmid-*'\n" | |
515 | if $name && $name !~ m/^vm-$vmid-/; | |
516 | ||
517 | $name = $class->find_free_diskname($storeid, $scfg, $vmid) if !$name; | |
518 | ||
519 | my $cmd = $rbd_cmd->($scfg, $storeid, 'create', '--image-format' , 2, '--size', int(($size+1023)/1024), $name); | |
520 | run_rbd_command($cmd, errmsg => "rbd create '$name' error"); | |
521 | ||
522 | return $name; | |
523 | } | |
524 | ||
525 | sub free_image { | |
526 | my ($class, $storeid, $scfg, $volname, $isBase) = @_; | |
527 | ||
528 | my ($vtype, $name, $vmid, undef, undef, undef) = | |
529 | $class->parse_volname($volname); | |
530 | ||
531 | ||
532 | my $snaps = rbd_ls_snap($scfg, $storeid, $name); | |
533 | foreach my $snap (keys %$snaps) { | |
534 | if ($snaps->{$snap}->{protected}) { | |
535 | my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap); | |
536 | run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error"); | |
537 | } | |
538 | } | |
539 | ||
540 | $class->deactivate_volume($storeid, $scfg, $volname); | |
541 | ||
542 | my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'purge', $name); | |
543 | run_rbd_command($cmd, errmsg => "rbd snap purge '$volname' error"); | |
544 | ||
545 | $cmd = $rbd_cmd->($scfg, $storeid, 'rm', $name); | |
546 | run_rbd_command($cmd, errmsg => "rbd rm '$volname' error"); | |
547 | ||
548 | return undef; | |
549 | } | |
550 | ||
551 | sub list_images { | |
552 | my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_; | |
553 | ||
554 | $cache->{rbd} = rbd_ls($scfg, $storeid) if !$cache->{rbd}; | |
555 | ||
556 | my $dat = $cache->{rbd}->{get_rbd_path($scfg)}; | |
557 | return [] if !$dat; # nothing found | |
558 | ||
559 | my $res = []; | |
560 | for my $image (sort keys %$dat) { | |
561 | my $info = $dat->{$image}; | |
562 | my ($volname, $parent, $owner) = $info->@{'name', 'parent', 'vmid'}; | |
563 | ||
564 | if ($parent && $parent =~ m/^(base-\d+-\S+)\@__base__$/) { | |
565 | $info->{volid} = "$storeid:$1/$volname"; | |
566 | } else { | |
567 | $info->{volid} = "$storeid:$volname"; | |
568 | } | |
569 | ||
570 | if ($vollist) { | |
571 | my $found = grep { $_ eq $info->{volid} } @$vollist; | |
572 | next if !$found; | |
573 | } else { | |
574 | next if defined ($vmid) && ($owner ne $vmid); | |
575 | } | |
576 | ||
577 | $info->{format} = 'raw'; | |
578 | ||
579 | push @$res, $info; | |
580 | } | |
581 | ||
582 | return $res; | |
583 | } | |
584 | ||
585 | sub status { | |
586 | my ($class, $storeid, $scfg, $cache) = @_; | |
587 | ||
588 | my $rados = $librados_connect->($scfg, $storeid); | |
589 | my $df = $rados->mon_command({ prefix => 'df', format => 'json' }); | |
590 | ||
591 | my ($d) = grep { $_->{name} eq $scfg->{pool} } @{$df->{pools}}; | |
592 | ||
593 | # max_avail -> max available space for data w/o replication in the pool | |
594 | # bytes_used -> data w/o replication in the pool | |
595 | my $free = $d->{stats}->{max_avail}; | |
596 | my $used = $d->{stats}->{stored} // $d->{stats}->{bytes_used}; | |
597 | my $total = $used + $free; | |
598 | my $active = 1; | |
599 | ||
600 | return ($total, $free, $used, $active); | |
601 | } | |
602 | ||
603 | sub activate_storage { | |
604 | my ($class, $storeid, $scfg, $cache) = @_; | |
605 | return 1; | |
606 | } | |
607 | ||
608 | sub deactivate_storage { | |
609 | my ($class, $storeid, $scfg, $cache) = @_; | |
610 | return 1; | |
611 | } | |
612 | ||
613 | my sub get_kernel_device_path { | |
614 | my ($scfg, $name) = @_; | |
615 | return "/dev/rbd/" . get_rbd_path($scfg, $name); | |
616 | }; | |
617 | ||
618 | sub map_volume { | |
619 | my ($class, $storeid, $scfg, $volname, $snapname) = @_; | |
620 | ||
621 | my ($vtype, $img_name, $vmid) = $class->parse_volname($volname); | |
622 | ||
623 | my $name = $img_name; | |
624 | $name .= '@'.$snapname if $snapname; | |
625 | ||
626 | my $kerneldev = get_kernel_device_path($scfg, $name); | |
627 | ||
628 | return $kerneldev if -b $kerneldev; # already mapped | |
629 | ||
630 | # features can only be enabled/disabled for image, not for snapshot! | |
631 | $krbd_feature_update->($scfg, $storeid, $img_name); | |
632 | ||
633 | my $cmd = $rbd_cmd->($scfg, $storeid, 'map', $name); | |
634 | run_rbd_command($cmd, errmsg => "can't map rbd volume $name"); | |
635 | ||
636 | return $kerneldev; | |
637 | } | |
638 | ||
639 | sub unmap_volume { | |
640 | my ($class, $storeid, $scfg, $volname, $snapname) = @_; | |
641 | ||
642 | my ($vtype, $name, $vmid) = $class->parse_volname($volname); | |
643 | $name .= '@'.$snapname if $snapname; | |
644 | ||
645 | my $kerneldev = get_kernel_device_path($scfg, $name); | |
646 | ||
647 | if (-b $kerneldev) { | |
648 | my $cmd = $rbd_cmd->($scfg, $storeid, 'unmap', $kerneldev); | |
649 | run_rbd_command($cmd, errmsg => "can't unmap rbd device $kerneldev"); | |
650 | } | |
651 | ||
652 | return 1; | |
653 | } | |
654 | ||
655 | sub activate_volume { | |
656 | my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_; | |
657 | ||
658 | $class->map_volume($storeid, $scfg, $volname, $snapname) if $scfg->{krbd}; | |
659 | ||
660 | return 1; | |
661 | } | |
662 | ||
663 | sub deactivate_volume { | |
664 | my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_; | |
665 | ||
666 | $class->unmap_volume($storeid, $scfg, $volname, $snapname); | |
667 | ||
668 | return 1; | |
669 | } | |
670 | ||
671 | sub volume_size_info { | |
672 | my ($class, $scfg, $storeid, $volname, $timeout) = @_; | |
673 | ||
674 | my ($vtype, $name, $vmid) = $class->parse_volname($volname); | |
675 | my ($size, undef) = rbd_volume_info($scfg, $storeid, $name); | |
676 | return $size; | |
677 | } | |
678 | ||
679 | sub volume_resize { | |
680 | my ($class, $scfg, $storeid, $volname, $size, $running) = @_; | |
681 | ||
682 | return 1 if $running && !$scfg->{krbd}; # FIXME??? | |
683 | ||
684 | my ($vtype, $name, $vmid) = $class->parse_volname($volname); | |
685 | ||
686 | my $cmd = $rbd_cmd->($scfg, $storeid, 'resize', '--allow-shrink', '--size', ($size/1024/1024), $name); | |
687 | run_rbd_command($cmd, errmsg => "rbd resize '$volname' error"); | |
688 | return undef; | |
689 | } | |
690 | ||
691 | sub volume_snapshot { | |
692 | my ($class, $scfg, $storeid, $volname, $snap) = @_; | |
693 | ||
694 | my ($vtype, $name, $vmid) = $class->parse_volname($volname); | |
695 | ||
696 | my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'create', '--snap', $snap, $name); | |
697 | run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error"); | |
698 | return undef; | |
699 | } | |
700 | ||
701 | sub volume_snapshot_rollback { | |
702 | my ($class, $scfg, $storeid, $volname, $snap) = @_; | |
703 | ||
704 | my ($vtype, $name, $vmid) = $class->parse_volname($volname); | |
705 | ||
706 | my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'rollback', '--snap', $snap, $name); | |
707 | run_rbd_command($cmd, errmsg => "rbd snapshot $volname to '$snap' error"); | |
708 | } | |
709 | ||
710 | sub volume_snapshot_delete { | |
711 | my ($class, $scfg, $storeid, $volname, $snap, $running) = @_; | |
712 | ||
713 | return 1 if $running && !$scfg->{krbd}; # FIXME: ???? | |
714 | ||
715 | $class->deactivate_volume($storeid, $scfg, $volname, $snap, {}); | |
716 | ||
717 | my ($vtype, $name, $vmid) = $class->parse_volname($volname); | |
718 | ||
719 | my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $name, $snap); | |
720 | if ($protected){ | |
721 | my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap); | |
722 | run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error"); | |
723 | } | |
724 | ||
725 | my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'rm', '--snap', $snap, $name); | |
726 | ||
727 | run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error"); | |
728 | ||
729 | return undef; | |
730 | } | |
731 | ||
732 | sub volume_snapshot_needs_fsfreeze { | |
733 | return 1; | |
734 | } | |
735 | ||
736 | sub volume_has_feature { | |
737 | my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_; | |
738 | ||
739 | my $features = { | |
740 | snapshot => { current => 1, snap => 1}, | |
741 | clone => { base => 1, snap => 1}, | |
742 | template => { current => 1}, | |
743 | copy => { base => 1, current => 1, snap => 1}, | |
744 | sparseinit => { base => 1, current => 1}, | |
745 | }; | |
746 | ||
747 | my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) = $class->parse_volname($volname); | |
748 | ||
749 | my $key = undef; | |
750 | if ($snapname){ | |
751 | $key = 'snap'; | |
752 | } else { | |
753 | $key = $isBase ? 'base' : 'current'; | |
754 | } | |
755 | return 1 if $features->{$feature}->{$key}; | |
756 | ||
757 | return undef; | |
758 | } | |
759 | ||
760 | 1; |