ArmVirtPkg/PrePi: use standard PeCoff routines for self-relocation

[mirror_edk2.git] / ArmVirtPkg / PrePi / Arm / ModuleEntryPoint.S

//\r
//  Copyright (c) 2011-2013, ARM Limited. All rights reserved.\r
//  Copyright (c) 2015-2016, Linaro Limited. All rights reserved.\r
//\r
//  SPDX-License-Identifier: BSD-2-Clause-Patent\r
//\r
//\r
\r
#include <AsmMacroIoLib.h>\r
\r
ASM_FUNC(_ModuleEntryPoint)\r
  // Do early platform specific actions\r
  bl    ASM_PFX(ArmPlatformPeiBootAction)\r
\r
  // Get ID of this CPU in Multicore system\r
  bl    ASM_PFX(ArmReadMpidr)\r
  // Keep a copy of the MpId register value\r
  mov   r10, r0\r
\r
// Check if we can install the stack at the top of the System Memory or if we need\r
// to install the stacks at the bottom of the Firmware Device (case the FD is located\r
// at the top of the DRAM)\r
_SetupStackPosition:\r
  // Compute Top of System Memory\r
  LDRL  (r1, PcdGet64 (PcdSystemMemoryBase))\r
  ADRL  (r12, PcdGet64 (PcdSystemMemorySize))\r
  ldrd  r2, r3, [r12]\r
\r
  // calculate the top of memory\r
  adds  r2, r2, r1\r
  sub   r2, r2, #1\r
  addcs r3, r3, #1\r
\r
  // truncate the memory used by UEFI to 4 GB range\r
  teq   r3, #0\r
  movne r1, #-1\r
  moveq r1, r2\r
\r
  // Calculate Top of the Firmware Device\r
  LDRL  (r2, PcdGet64 (PcdFdBaseAddress))\r
  MOV32 (r3, FixedPcdGet32 (PcdFdSize) - 1)\r
  add   r3, r3, r2      // r3 = FdTop = PcdFdBaseAddress + PcdFdSize\r
\r
  // UEFI Memory Size (stacks are allocated in this region)\r
  MOV32 (r4, FixedPcdGet32(PcdSystemMemoryUefiRegionSize))\r
\r
  //\r
  // Reserve the memory for the UEFI region (contain stacks on its top)\r
  //\r
\r
  // Calculate how much space there is between the top of the Firmware and the Top of the System Memory\r
  subs  r0, r1, r3   // r0 = SystemMemoryTop - FdTop\r
  bmi   _SetupStack  // Jump if negative (FdTop > SystemMemoryTop). Case when the PrePi is in XIP memory outside of the DRAM\r
  cmp   r0, r4\r
  bge   _SetupStack\r
\r
  // Case the top of stacks is the FdBaseAddress\r
  mov   r1, r2\r
\r
_SetupStack:\r
  // r1 contains the top of the stack (and the UEFI Memory)\r
\r
  // Because the 'push' instruction is equivalent to 'stmdb' (decrement before), we need to increment\r
  // one to the top of the stack. We check if incrementing one does not overflow (case of DRAM at the\r
  // top of the memory space)\r
  adds  r11, r1, #1\r
  bcs   _SetupOverflowStack\r
\r
_SetupAlignedStack:\r
  mov   r1, r11\r
  b     _GetBaseUefiMemory\r
\r
_SetupOverflowStack:\r
  // Case memory at the top of the address space. Ensure the top of the stack is EFI_PAGE_SIZE\r
  // aligned (4KB)\r
  MOV32 (r11, (~EFI_PAGE_MASK) & 0xffffffff)\r
  and   r1, r1, r11\r
\r
_GetBaseUefiMemory:\r
  // Calculate the Base of the UEFI Memory\r
  sub   r11, r1, r4\r
\r
_GetStackBase:\r
  // r1 = The top of the Mpcore Stacks\r
  mov   sp, r1\r
\r
  // Stack for the primary core = PrimaryCoreStack\r
  MOV32 (r2, FixedPcdGet32(PcdCPUCorePrimaryStackSize))\r
  sub   r9, r1, r2\r
\r
  mov   r0, r10\r
  mov   r1, r11\r
  mov   r2, r9\r
\r
  // Jump to PrePiCore C code\r
  //    r0 = MpId\r
  //    r1 = UefiMemoryBase\r
  //    r2 = StacksBase\r
  bl    ASM_PFX(CEntryPoint)\r
\r
_NeverReturn:\r
  b _NeverReturn\r
\r
ASM_PFX(ArmPlatformPeiBootAction):\r
  //\r
  // If we are booting from RAM using the Linux kernel boot protocol, r0 will\r
  // point to the DTB image in memory. Otherwise, use the default value defined\r
  // by the platform.\r
  //\r
  teq   r0, #0\r
  bne   0f\r
  LDRL  (r0, PcdGet64 (PcdDeviceTreeInitialBaseAddress))\r
\r
0:mov   r11, r14            // preserve LR\r
  mov   r10, r0             // preserve DTB pointer\r
  mov   r9, r1              // preserve base of image pointer\r
\r
  //\r
  // The base of the runtime image has been preserved in r1. Check whether\r
  // the expected magic number can be found in the header.\r
  //\r
  ldr   r8, .LArm32LinuxMagic\r
  ldr   r7, [r1, #0x24]\r
  cmp   r7, r8\r
  bne   .Lout\r
\r
  //\r
  //\r
  // OK, so far so good. We have confirmed that we likely have a DTB and are\r
  // booting via the ARM Linux boot protocol. Update the base-of-image PCD\r
  // to the actual relocated value, and add the shift of PcdFdBaseAddress to\r
  // PcdFvBaseAddress as well\r
  //\r
  ADRL  (r8, PcdGet64 (PcdFdBaseAddress))\r
  ADRL  (r7, PcdGet64 (PcdFvBaseAddress))\r
  ldr   r6, [r8]\r
  ldr   r5, [r7]\r
  sub   r5, r5, r6\r
  add   r5, r5, r1\r
  str   r1, [r8]\r
  str   r5, [r7]\r
\r
  //\r
  // The runtime address may be different from the link time address so fix\r
  // up the PE/COFF relocations. Since we are calling a C function, use the\r
  // window at the beginning of the FD image as a temp stack.\r
  //\r
  mov   r0, r5\r
  ADRL  (r1, PeCoffLoaderImageReadFromMemory)\r
  mov   sp, r5\r
  bl    RelocatePeCoffImage\r
\r
  //\r
  // Discover the memory size and offset from the DTB, and record in the\r
  // respective PCDs. This will also return false if a corrupt DTB is\r
  // encountered.\r
  //\r
  mov   r0, r10\r
  ADRL  (r1, PcdGet64 (PcdSystemMemoryBase))\r
  ADRL  (r2, PcdGet64 (PcdSystemMemorySize))\r
  bl    FindMemnode\r
  teq   r0, #0\r
  beq   .Lout\r
\r
  //\r
  // Copy the DTB to the slack space right after the 64 byte arm64/Linux style\r
  // image header at the base of this image (defined in the FDF), and record the\r
  // pointer in PcdDeviceTreeInitialBaseAddress.\r
  //\r
  ADRL  (r8, PcdGet64 (PcdDeviceTreeInitialBaseAddress))\r
  add   r9, r9, #0x40\r
  str   r9, [r8]\r
\r
  mov   r0, r9\r
  mov   r1, r10\r
  bl    CopyFdt\r
\r
.Lout:\r
  bx    r11\r
\r
.LArm32LinuxMagic:\r
  .byte   0x18, 0x28, 0x6f, 0x01\r