Preserve hii section in GCC binaries

[mirror_edk2.git] / BaseTools / Scripts / GccBase.lds

/** @file\r
\r
  Unified linker script for GCC based builds\r
\r
  Copyright (c) 2010 - 2015, Intel Corporation. All rights reserved.<BR>\r
  Copyright (c) 2015, Linaro Ltd. All rights reserved.<BR>\r
  (C) Copyright 2016 Hewlett Packard Enterprise Development LP<BR>\r
\r
  This program and the accompanying materials are licensed and made available under\r
  the terms and conditions of the BSD License that accompanies this distribution.\r
  The full text of the license may be found at\r
  http://opensource.org/licenses/bsd-license.php.\r
\r
  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
\r
**/\r
\r
SECTIONS {\r
\r
  /*\r
   * The PE/COFF binary consists of DOS and PE/COFF headers, and a sequence of\r
   * section headers adding up to PECOFF_HEADER_SIZE bytes (which differs\r
   * between 32-bit and 64-bit builds). The actual start of the .text section\r
   * will be rounded up based on its actual alignment.\r
   */\r
  . = PECOFF_HEADER_SIZE;\r
\r
  .text : ALIGN(CONSTANT(COMMONPAGESIZE)) {\r
    *(.text .text.* .stub .gnu.linkonce.t.*)\r
    *(.rodata .rodata.* .gnu.linkonce.r.*)\r
    *(.got .got.*)\r
\r
    /*\r
     * The contents of AutoGen.c files are constant from the POV of the program,\r
     * but most of its contents end up in .data or .bss by default since few of\r
     * the variable definitions that get emitted are declared as CONST.\r
     */\r
    *:AutoGen.obj(.data .data.* .bss .bss.*)\r
  }\r
\r
  /*\r
   * The alignment of the .data section should be less than or equal to the\r
   * alignment of the .text section. This ensures that the relative offset\r
   * between these sections is the same in the ELF and the PE/COFF versions of\r
   * this binary.\r
   */\r
  .data ALIGN(ALIGNOF(.text)) : ALIGN(CONSTANT(COMMONPAGESIZE)) {\r
    *(.data .data.* .gnu.linkonce.d.*)\r
    *(.bss .bss.*)\r
  }\r
\r
  .eh_frame ALIGN(CONSTANT(COMMONPAGESIZE)) : {\r
    KEEP (*(.eh_frame))\r
  }\r
\r
  .rela ALIGN(CONSTANT(COMMONPAGESIZE)) : {\r
    *(.rela .rela.*)\r
  }\r
\r
  .hii : ALIGN(CONSTANT(COMMONPAGESIZE)) {\r
    KEEP (*(.hii))\r
  }\r
\r
  /DISCARD/ : {\r
    *(.note.GNU-stack)\r
    *(.gnu_debuglink)\r
    *(.interp)\r
    *(.dynsym)\r
    *(.dynstr)\r
    *(.dynamic)\r
    *(.hash)\r
    *(.comment)\r
    *(COMMON)\r
  }\r
}\r