CryptoPkg/Test: Add unit test for CryptoBn

[mirror_edk2.git] / CryptoPkg / Library / IntrinsicLib / Ia32 / MathLlshr.asm

;***\r
;llshr.asm - long shift right\r
;\r
;       Copyright (c) Microsoft Corporation. All rights reserved.\r
;       SPDX-License-Identifier: BSD-2-Clause-Patent\r
;\r
;Purpose:\r
;       define signed long shift right routine\r
;           __allshr\r
;\r
;Original Implemenation: MSVC 14.12.25827\r
;\r
;*******************************************************************************\r
    .686\r
    .model  flat,C\r
    .code\r
\r
\r
\r
;***\r
;llshr - long shift right\r
;\r
;Purpose:\r
;       Does a signed Long Shift Right\r
;       Shifts a long right any number of bits.\r
;\r
;Entry:\r
;       EDX:EAX - long value to be shifted\r
;       CL    - number of bits to shift by\r
;\r
;Exit:\r
;       EDX:EAX - shifted value\r
;\r
;Uses:\r
;       CL is destroyed.\r
;\r
;Exceptions:\r
;\r
;*******************************************************************************\r
_allshr PROC NEAR\r
\r
;\r
; Handle shifts of 64 bits or more (if shifting 64 bits or more, the result\r
; depends only on the high order bit of edx).\r
;\r
        cmp     cl,64\r
        jae     short RETSIGN\r
\r
;\r
; Handle shifts of between 0 and 31 bits\r
;\r
        cmp     cl, 32\r
        jae     short MORE32\r
        shrd    eax,edx,cl\r
        sar     edx,cl\r
        ret\r
\r
;\r
; Handle shifts of between 32 and 63 bits\r
;\r
MORE32:\r
        mov     eax,edx\r
        sar     edx,31\r
        and     cl,31\r
        sar     eax,cl\r
        ret\r
\r
;\r
; Return double precision 0 or -1, depending on the sign of edx\r
;\r
RETSIGN:\r
        sar     edx,31\r
        mov     eax,edx\r
        ret\r
\r
_allshr ENDP\r
\r
        end\r