1. Correct File header to ## @file

[mirror_edk2.git] / EdkCompatibilityPkg / Compatibility / MpServicesOnFrameworkMpServicesThunk / IA32 / MpFuncs.asm

;------------------------------------------------------------------------------\r
; IA32 assembly file for AP startup vector.\r
;\r
; Copyright (c) 2009, Intel Corporation\r
; All rights reserved. This program and the accompanying materials\r
; are licensed and made available under the terms and conditions of the BSD License\r
; which accompanies this distribution.  The full text of the license may be found at\r
; http://opensource.org/licenses/bsd-license.php\r
;\r
; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
;\r
;------------------------------------------------------------------------------\r
\r
.686p\r
.model  flat        \r
.code        \r
\r
include AsmInclude.inc\r
;-------------------------------------------------------------------------------------\r
FJMP32  MACRO   Selector, Offset\r
            DB      066h\r
            DB      067h\r
            DB      0EAh            ; far jump\r
            DD      Offset          ; 32-bit offset\r
            DW      Selector        ; 16-bit selector\r
            ENDM\r
\r
;-------------------------------------------------------------------------------------\r
;RendezvousFunnelProc  procedure follows. All APs execute their procedure. This\r
;procedure serializes all the AP processors through an Init sequence. It must be\r
;noted that APs arrive here very raw...ie: real mode, no stack.\r
;ALSO THIS PROCEDURE IS EXECUTED BY APs ONLY ON 16 BIT MODE. HENCE THIS PROC\r
;IS IN MACHINE CODE.\r
;-------------------------------------------------------------------------------------\r
;RendezvousFunnelProc (&WakeUpBuffer,MemAddress);\r
\r
RendezvousFunnelProc   PROC  near C  PUBLIC\r
RendezvousFunnelProcStart::\r
\r
\r
; At this point CS = 0x(vv00) and ip= 0x0.\r
\r
        db 8ch,  0c8h                 ; mov        ax,  cs\r
        db 8eh,  0d8h                 ; mov        ds,  ax\r
        db 8eh,  0c0h                 ; mov        es,  ax\r
        db 8eh,  0d0h                 ; mov        ss,  ax \r
        db 33h,  0c0h                 ; xor        ax,  ax\r
        db 8eh,  0e0h                 ; mov        fs,  ax\r
        db 8eh,  0e8h                 ; mov        gs,  ax\r
\r
; Switch to flat mode.\r
\r
        db 0BEh\r
        dw BufferStart                ; mov        si, BufferStart\r
        db 66h,  8Bh, 0Ch             ; mov        ecx,dword ptr [si]          ; ECX is keeping the start address of wakeup buffer\r
\r
        db 0FAh                       ; cli\r
        db 0BEh\r
        dw GdtrProfile                ; mov        si, GdtrProfile\r
        db 66h                        ; db         66h\r
        db 2Eh,0Fh, 01h, 14h          ; lgdt       fword ptr cs:[si]\r
        \r
        db 33h, 0C0h                  ; xor        ax,  ax\r
        db 8Eh, 0D8h                  ; mov        ds,  ax\r
        db 0Fh, 20h, 0C0h             ; mov        eax, cr0                    ; Get control register 0\r
        db 66h, 83h, 0C8h, 01h        ; or         eax, 000000001h             ; Set PE bit (bit #0)\r
        db 0Fh, 22h, 0C0h             ; mov        cr0, eax\r
\r
\r
FLAT32_JUMP::\r
        FJMP32  010h,0h               ; Far jmp using code segment descriptor\r
\r
ProtectedModeStart::                  ; protected mode entry point\r
\r
        mov         ax,  8h\r
        mov         ds,  ax\r
        mov         es,  ax\r
        mov         fs,  ax\r
        mov         gs,  ax\r
        mov         ss,  ax           ; Flat mode setup.\r
\r
\r
        mov         edi, esi\r
        add         edi, LockLocation\r
        mov         al,  NotVacantFlag\r
TestLock::\r
        xchg        byte ptr [edi], al\r
        cmp         al,  NotVacantFlag\r
        jz          TestLock\r
\r
ProgramStack::\r
\r
        mov         edi, esi\r
        add         edi, StackSize\r
        mov         eax, dword ptr [edi]\r
        mov         edi, esi\r
        add         edi, StackStart\r
        add         eax, dword ptr [edi]\r
        mov         esp, eax\r
        mov         dword ptr [edi], eax\r
\r
Releaselock::\r
        mov         al,  VacantFlag\r
        mov         edi, esi\r
        add         edi, LockLocation\r
        xchg        byte ptr [edi], al\r
\r
        ;\r
        ; Call C Function\r
        ;\r
        mov         edi, esi\r
        add         edi, RendezvousProc\r
        mov         ebx, dword ptr [edi]\r
\r
        test        ebx, ebx\r
        jz          GoToSleep\r
        call        ebx                           ; Call C function\r
\r
GoToSleep::\r
\r
        cli\r
        hlt\r
        jmp         $-2\r
        \r
RendezvousFunnelProc   ENDP\r
RendezvousFunnelProcEnd::\r
;-------------------------------------------------------------------------------------\r
;  AsmGetAddressMap (&AddressMap);\r
;-------------------------------------------------------------------------------------\r
AsmGetAddressMap   PROC  near C  PUBLIC\r
\r
        pushad\r
        mov         ebp,esp\r
   \r
        mov         ebx, dword ptr [ebp+24h]\r
        mov         dword ptr [ebx], RendezvousFunnelProcStart\r
        mov         dword ptr [ebx+4h], ProtectedModeStart - RendezvousFunnelProcStart\r
        mov         dword ptr [ebx+8h], FLAT32_JUMP - RendezvousFunnelProcStart\r
        mov         dword ptr [ebx+0ch], 0\r
        mov         dword ptr [ebx+10h], 0\r
        mov         dword ptr [ebx+14h], RendezvousFunnelProcEnd - RendezvousFunnelProcStart\r
        \r
        popad\r
        ret\r
AsmGetAddressMap   ENDP\r
\r
END\r