UefiCpuPkg: Move AsmRelocateApLoopStart from Mpfuncs.nasm to AmdSev.nasm

[mirror_edk2.git] / MdePkg / Library / BaseMemoryLibOptDxe / AArch64 / ScanMem.S

//\r
// Copyright (c) 2014, ARM Limited\r
// All rights Reserved.\r
// SPDX-License-Identifier: BSD-2-Clause-Patent\r
//\r
\r
// Assumptions:\r
//\r
// ARMv8-a, AArch64\r
// Neon Available.\r
//\r
\r
// Arguments and results.\r
#define srcin     x0\r
#define cntin     x1\r
#define chrin     w2\r
\r
#define result    x0\r
\r
#define src       x3\r
#define  tmp       x4\r
#define wtmp2     w5\r
#define synd      x6\r
#define soff      x9\r
#define cntrem    x10\r
\r
#define vrepchr   v0\r
#define vdata1    v1\r
#define vdata2    v2\r
#define vhas_chr1 v3\r
#define vhas_chr2 v4\r
#define vrepmask  v5\r
#define vend      v6\r
\r
//\r
// Core algorithm:\r
//\r
// For each 32-byte chunk we calculate a 64-bit syndrome value, with two bits\r
// per byte. For each tuple, bit 0 is set if the relevant byte matched the\r
// requested character and bit 1 is not used (faster than using a 32bit\r
// syndrome). Since the bits in the syndrome reflect exactly the order in which\r
// things occur in the original string, counting trailing zeros allows to\r
// identify exactly which byte has matched.\r
//\r
\r
ASM_GLOBAL ASM_PFX(InternalMemScanMem8)\r
ASM_PFX(InternalMemScanMem8):\r
    // Do not dereference srcin if no bytes to compare.\r
    cbz  cntin, .Lzero_length\r
    //\r
    // Magic constant 0x40100401 allows us to identify which lane matches\r
    // the requested byte.\r
    //\r
    mov     wtmp2, #0x0401\r
    movk    wtmp2, #0x4010, lsl #16\r
    dup     vrepchr.16b, chrin\r
    // Work with aligned 32-byte chunks\r
    bic     src, srcin, #31\r
    dup     vrepmask.4s, wtmp2\r
    ands    soff, srcin, #31\r
    and     cntrem, cntin, #31\r
    b.eq    .Lloop\r
\r
    //\r
    // Input string is not 32-byte aligned. We calculate the syndrome\r
    // value for the aligned 32 bytes block containing the first bytes\r
    // and mask the irrelevant part.\r
    //\r
\r
    ld1     {vdata1.16b, vdata2.16b}, [src], #32\r
    sub     tmp, soff, #32\r
    adds    cntin, cntin, tmp\r
    cmeq    vhas_chr1.16b, vdata1.16b, vrepchr.16b\r
    cmeq    vhas_chr2.16b, vdata2.16b, vrepchr.16b\r
    and     vhas_chr1.16b, vhas_chr1.16b, vrepmask.16b\r
    and     vhas_chr2.16b, vhas_chr2.16b, vrepmask.16b\r
    addp    vend.16b, vhas_chr1.16b, vhas_chr2.16b        // 256->128\r
    addp    vend.16b, vend.16b, vend.16b                  // 128->64\r
    mov     synd, vend.d[0]\r
    // Clear the soff*2 lower bits\r
    lsl     tmp, soff, #1\r
    lsr     synd, synd, tmp\r
    lsl     synd, synd, tmp\r
    // The first block can also be the last\r
    b.ls    .Lmasklast\r
    // Have we found something already?\r
    cbnz    synd, .Ltail\r
\r
.Lloop:\r
    ld1     {vdata1.16b, vdata2.16b}, [src], #32\r
    subs    cntin, cntin, #32\r
    cmeq    vhas_chr1.16b, vdata1.16b, vrepchr.16b\r
    cmeq    vhas_chr2.16b, vdata2.16b, vrepchr.16b\r
    // If we're out of data we finish regardless of the result\r
    b.ls    .Lend\r
    // Use a fast check for the termination condition\r
    orr     vend.16b, vhas_chr1.16b, vhas_chr2.16b\r
    addp    vend.2d, vend.2d, vend.2d\r
    mov     synd, vend.d[0]\r
    // We're not out of data, loop if we haven't found the character\r
    cbz     synd, .Lloop\r
\r
.Lend:\r
    // Termination condition found, let's calculate the syndrome value\r
    and     vhas_chr1.16b, vhas_chr1.16b, vrepmask.16b\r
    and     vhas_chr2.16b, vhas_chr2.16b, vrepmask.16b\r
    addp    vend.16b, vhas_chr1.16b, vhas_chr2.16b      // 256->128\r
    addp    vend.16b, vend.16b, vend.16b                // 128->64\r
    mov     synd, vend.d[0]\r
    // Only do the clear for the last possible block\r
    b.hi    .Ltail\r
\r
.Lmasklast:\r
    // Clear the (32 - ((cntrem + soff) % 32)) * 2 upper bits\r
    add     tmp, cntrem, soff\r
    and     tmp, tmp, #31\r
    sub     tmp, tmp, #32\r
    neg     tmp, tmp, lsl #1\r
    lsl     synd, synd, tmp\r
    lsr     synd, synd, tmp\r
\r
.Ltail:\r
    // Count the trailing zeros using bit reversing\r
    rbit    synd, synd\r
    // Compensate the last post-increment\r
    sub     src, src, #32\r
    // Check that we have found a character\r
    cmp     synd, #0\r
    // And count the leading zeros\r
    clz     synd, synd\r
    // Compute the potential result\r
    add     result, src, synd, lsr #1\r
    // Select result or NULL\r
    csel    result, xzr, result, eq\r
    ret\r
\r
.Lzero_length:\r
    mov   result, #0\r
    ret\r