Initial import.

[mirror_edk2.git] / MdePkg / Library / BaseMemoryLibRepStr / x64 / CopyMem.asm

;------------------------------------------------------------------------------\r
;\r
; Copyright (c) 2006, Intel Corporation\r
; All rights reserved. This program and the accompanying materials\r
; are licensed and made available under the terms and conditions of the BSD License\r
; which accompanies this distribution.  The full text of the license may be found at\r
; http://opensource.org/licenses/bsd-license.php\r
;\r
; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
;\r
; Module Name:\r
;\r
;   CopyMem.Asm\r
;\r
; Abstract:\r
;\r
;   CopyMem function\r
;\r
; Notes:\r
;\r
;------------------------------------------------------------------------------\r
\r
    .code\r
\r
InternalMemCopyMem  PROC    USES    rsi rdi\r
    mov     rsi, rdx                    ; rsi <- Source\r
    mov     rdi, rcx                    ; rdi <- Destination\r
    lea     r9, [rdi + r8 - 1]          ; r9 <- End of Destination\r
    cmp     rsi, rdi\r
    mov     rax, rdi                    ; rax <- Destination as return value\r
    jae     @F\r
    cmp     r9, rsi\r
    jae     @CopyBackward               ; Copy backward if overlapped\r
@@:\r
    mov     rcx, r8\r
    and     r8, 7\r
    shr     rcx, 3\r
    rep     movsq                       ; Copy as many Qwords as possible\r
    jmp     @CopyBytes\r
@CopyBackward:\r
    mov     rdi, r9                     ; rdi <- End of Destination\r
    lea     rsi, [rsi + r8 - 1]         ; esi <- End of Source\r
    std                                 ; set direction flag\r
@CopyBytes:\r
    mov     rcx, r8\r
    rep     movsb                       ; Copy bytes backward\r
    cld\r
    ret\r
InternalMemCopyMem  ENDP\r
\r
    END\r