BaseMemoryLibSse2: Take advantage of write combining buffers

[mirror_edk2.git] / MdePkg / Library / BaseMemoryLibSse2 / Ia32 / SetMem64.nasm

;------------------------------------------------------------------------------\r
;\r
; Copyright (c) 2006, Intel Corporation. All rights reserved.<BR>\r
; SPDX-License-Identifier: BSD-2-Clause-Patent\r
;\r
; Module Name:\r
;\r
;   SetMem64.nasm\r
;\r
; Abstract:\r
;\r
;   SetMem64 function\r
;\r
; Notes:\r
;\r
;------------------------------------------------------------------------------\r
\r
    SECTION .text\r
\r
;------------------------------------------------------------------------------\r
;  VOID *\r
;  EFIAPI\r
;  InternalMemSetMem64 (\r
;    IN VOID   *Buffer,\r
;    IN UINTN  Count,\r
;    IN UINT64 Value\r
;    )\r
;------------------------------------------------------------------------------\r
global ASM_PFX(InternalMemSetMem64)\r
ASM_PFX(InternalMemSetMem64):\r
    mov     eax, [esp + 4]              ; eax <- Buffer\r
    mov     ecx, [esp + 8]              ; ecx <- Count\r
    test    al, 8\r
    mov     edx, eax\r
    movq    xmm0, qword [esp + 12]\r
    jz      .0\r
    movq    qword [edx], xmm0\r
    add     edx, 8\r
    dec     ecx\r
.0:\r
    push    ebx\r
    mov     ebx, ecx\r
    and     ebx, 7\r
    shr     ecx, 3\r
    jz      @SetQwords\r
    movlhps xmm0, xmm0\r
.1:\r
    movntdq [edx], xmm0\r
    movntdq [edx + 16], xmm0\r
    movntdq [edx + 32], xmm0\r
    movntdq [edx + 48], xmm0\r
    lea     edx, [edx + 64]\r
    loop    .1\r
    mfence\r
@SetQwords:\r
    test    ebx, ebx\r
    jz .3\r
    mov     ecx, ebx\r
.2\r
    movq    qword [edx], xmm0\r
    lea     edx, [edx + 8]\r
    loop    .2\r
.3:\r
    pop ebx\r
    ret\r
\r