UefiCpuPkg: Move AsmRelocateApLoopStart from Mpfuncs.nasm to AmdSev.nasm

[mirror_edk2.git] / MdePkg / Library / BaseMemoryLibSse2 / X64 / ZeroMem.nasm

;------------------------------------------------------------------------------\r
;\r
; Copyright (c) 2006, Intel Corporation. All rights reserved.<BR>\r
; SPDX-License-Identifier: BSD-2-Clause-Patent\r
;\r
; Module Name:\r
;\r
;   ZeroMem.nasm\r
;\r
; Abstract:\r
;\r
;   ZeroMem function\r
;\r
; Notes:\r
;\r
;------------------------------------------------------------------------------\r
\r
    DEFAULT REL\r
    SECTION .text\r
\r
;------------------------------------------------------------------------------\r
;  VOID *\r
;  InternalMemZeroMem (\r
;    IN VOID   *Buffer,\r
;    IN UINTN  Count\r
;    )\r
;------------------------------------------------------------------------------\r
global ASM_PFX(InternalMemZeroMem)\r
ASM_PFX(InternalMemZeroMem):\r
    push    rdi\r
    mov     rdi, rcx\r
    xor     rcx, rcx\r
    xor     eax, eax\r
    sub     rcx, rdi\r
    and     rcx, 63\r
    mov     r8, rdi\r
    jz      .0\r
    cmp     rcx, rdx\r
    cmova   rcx, rdx\r
    sub     rdx, rcx\r
    rep     stosb\r
.0:\r
    mov     rcx, rdx\r
    and     edx, 63\r
    shr     rcx, 6\r
    jz      @ZeroBytes\r
    pxor    xmm0, xmm0\r
.1:\r
    movntdq [rdi], xmm0\r
    movntdq [rdi + 16], xmm0\r
    movntdq [rdi + 32], xmm0\r
    movntdq [rdi + 48], xmm0\r
    add     rdi, 64\r
    loop    .1\r
    mfence\r
@ZeroBytes:\r
    mov     ecx, edx\r
    rep     stosb\r
    mov     rax, r8\r
    pop     rdi\r
    ret\r
\r