[ceph.git] / ceph / src / Beast / test / zlib / zlib-1.2.8 / contrib / asm686 / match.S

/* match.S -- x86 assembly version of the zlib longest_match() function.
 * Optimized for the Intel 686 chips (PPro and later).
 *
 * Copyright (C) 1998, 2007 Brian Raiter <breadbox@muppetlabs.com>
 *
 * This software is provided 'as-is', without any express or implied
 * warranty.  In no event will the author be held liable for any damages
 * arising from the use of this software.
 *
 * Permission is granted to anyone to use this software for any purpose,
 * including commercial applications, and to alter it and redistribute it
 * freely, subject to the following restrictions:
 *
 * 1. The origin of this software must not be misrepresented; you must not
 *    claim that you wrote the original software. If you use this software
 *    in a product, an acknowledgment in the product documentation would be
 *    appreciated but is not required.
 * 2. Altered source versions must be plainly marked as such, and must not be
 *    misrepresented as being the original software.
 * 3. This notice may not be removed or altered from any source distribution.
 */

#ifndef NO_UNDERLINE
#define	match_init	_match_init
#define	longest_match	_longest_match
#endif

#define	MAX_MATCH	(258)
#define	MIN_MATCH	(3)
#define	MIN_LOOKAHEAD	(MAX_MATCH + MIN_MATCH + 1)
#define	MAX_MATCH_8	((MAX_MATCH + 7) & ~7)

/* stack frame offsets */

#define	chainlenwmask		0	/* high word: current chain len	*/
					/* low word: s->wmask		*/
#define	window			4	/* local copy of s->window	*/
#define	windowbestlen		8	/* s->window + bestlen		*/
#define	scanstart		16	/* first two bytes of string	*/
#define	scanend			12	/* last two bytes of string	*/
#define	scanalign		20	/* dword-misalignment of string	*/
#define	nicematch		24	/* a good enough match size	*/
#define	bestlen			28	/* size of best match so far	*/
#define	scan			32	/* ptr to string wanting match	*/

#define	LocalVarsSize		(36)
/*	saved ebx		36 */
/*	saved edi		40 */
/*	saved esi		44 */
/*	saved ebp		48 */
/*	return address		52 */
#define	deflatestate		56	/* the function arguments	*/
#define	curmatch		60

/* All the +zlib1222add offsets are due to the addition of fields
 *  in zlib in the deflate_state structure since the asm code was first written
 * (if you compile with zlib 1.0.4 or older, use "zlib1222add equ (-4)").
 * (if you compile with zlib between 1.0.5 and 1.2.2.1, use "zlib1222add equ 0").
 * if you compile with zlib 1.2.2.2 or later , use "zlib1222add equ 8").
 */

#define zlib1222add		(8)

#define	dsWSize			(36+zlib1222add)
#define	dsWMask			(44+zlib1222add)
#define	dsWindow		(48+zlib1222add)
#define	dsPrev			(56+zlib1222add)
#define	dsMatchLen		(88+zlib1222add)
#define	dsPrevMatch		(92+zlib1222add)
#define	dsStrStart		(100+zlib1222add)
#define	dsMatchStart		(104+zlib1222add)
#define	dsLookahead		(108+zlib1222add)
#define	dsPrevLen		(112+zlib1222add)
#define	dsMaxChainLen		(116+zlib1222add)
#define	dsGoodMatch		(132+zlib1222add)
#define	dsNiceMatch		(136+zlib1222add)


.file "match.S"

.globl	match_init, longest_match

.text

/* uInt longest_match(deflate_state *deflatestate, IPos curmatch) */
.cfi_sections	.debug_frame

longest_match:

.cfi_startproc
/* Save registers that the compiler may be using, and adjust %esp to	*/
/* make room for our stack frame.					*/

		pushl	%ebp
		.cfi_def_cfa_offset 8
		.cfi_offset ebp, -8
		pushl	%edi
		.cfi_def_cfa_offset 12
		pushl	%esi
		.cfi_def_cfa_offset 16
		pushl	%ebx
		.cfi_def_cfa_offset 20
		subl	$LocalVarsSize, %esp
		.cfi_def_cfa_offset LocalVarsSize+20

/* Retrieve the function arguments. %ecx will hold cur_match		*/
/* throughout the entire function. %edx will hold the pointer to the	*/
/* deflate_state structure during the function's setup (before		*/
/* entering the main loop).						*/

		movl	deflatestate(%esp), %edx
		movl	curmatch(%esp), %ecx

/* uInt wmask = s->w_mask;						*/
/* unsigned chain_length = s->max_chain_length;				*/
/* if (s->prev_length >= s->good_match) {				*/
/*     chain_length >>= 2;						*/
/* }									*/
 
		movl	dsPrevLen(%edx), %eax
		movl	dsGoodMatch(%edx), %ebx
		cmpl	%ebx, %eax
		movl	dsWMask(%edx), %eax
		movl	dsMaxChainLen(%edx), %ebx
		jl	LastMatchGood
		shrl	$2, %ebx
LastMatchGood:

/* chainlen is decremented once beforehand so that the function can	*/
/* use the sign flag instead of the zero flag for the exit test.	*/
/* It is then shifted into the high word, to make room for the wmask	*/
/* value, which it will always accompany.				*/

		decl	%ebx
		shll	$16, %ebx
		orl	%eax, %ebx
		movl	%ebx, chainlenwmask(%esp)

/* if ((uInt)nice_match > s->lookahead) nice_match = s->lookahead;	*/

		movl	dsNiceMatch(%edx), %eax
		movl	dsLookahead(%edx), %ebx
		cmpl	%eax, %ebx
		jl	LookaheadLess
		movl	%eax, %ebx
LookaheadLess:	movl	%ebx, nicematch(%esp)

/* register Bytef *scan = s->window + s->strstart;			*/

		movl	dsWindow(%edx), %esi
		movl	%esi, window(%esp)
		movl	dsStrStart(%edx), %ebp
		lea	(%esi,%ebp), %edi
		movl	%edi, scan(%esp)

/* Determine how many bytes the scan ptr is off from being		*/
/* dword-aligned.							*/

		movl	%edi, %eax
		negl	%eax
		andl	$3, %eax
		movl	%eax, scanalign(%esp)

/* IPos limit = s->strstart > (IPos)MAX_DIST(s) ?			*/
/*     s->strstart - (IPos)MAX_DIST(s) : NIL;				*/

		movl	dsWSize(%edx), %eax
		subl	$MIN_LOOKAHEAD, %eax
		subl	%eax, %ebp
		jg	LimitPositive
		xorl	%ebp, %ebp
LimitPositive:

/* int best_len = s->prev_length;					*/

		movl	dsPrevLen(%edx), %eax
		movl	%eax, bestlen(%esp)

/* Store the sum of s->window + best_len in %esi locally, and in %esi.	*/

		addl	%eax, %esi
		movl	%esi, windowbestlen(%esp)

/* register ush scan_start = *(ushf*)scan;				*/
/* register ush scan_end   = *(ushf*)(scan+best_len-1);			*/
/* Posf *prev = s->prev;						*/

		movzwl	(%edi), %ebx
		movl	%ebx, scanstart(%esp)
		movzwl	-1(%edi,%eax), %ebx
		movl	%ebx, scanend(%esp)
		movl	dsPrev(%edx), %edi

/* Jump into the main loop.						*/

		movl	chainlenwmask(%esp), %edx
		jmp	LoopEntry

.balign 16

/* do {
 *     match = s->window + cur_match;
 *     if (*(ushf*)(match+best_len-1) != scan_end ||
 *         *(ushf*)match != scan_start) continue;
 *     [...]
 * } while ((cur_match = prev[cur_match & wmask]) > limit
 *          && --chain_length != 0);
 *
 * Here is the inner loop of the function. The function will spend the
 * majority of its time in this loop, and majority of that time will
 * be spent in the first ten instructions.
 *
 * Within this loop:
 * %ebx = scanend
 * %ecx = curmatch
 * %edx = chainlenwmask - i.e., ((chainlen << 16) | wmask)
 * %esi = windowbestlen - i.e., (window + bestlen)
 * %edi = prev
 * %ebp = limit
 */
LookupLoop:
		andl	%edx, %ecx
		movzwl	(%edi,%ecx,2), %ecx
		cmpl	%ebp, %ecx
		jbe	LeaveNow
		subl	$0x00010000, %edx
		js	LeaveNow
LoopEntry:	movzwl	-1(%esi,%ecx), %eax
		cmpl	%ebx, %eax
		jnz	LookupLoop
		movl	window(%esp), %eax
		movzwl	(%eax,%ecx), %eax
		cmpl	scanstart(%esp), %eax
		jnz	LookupLoop

/* Store the current value of chainlen.					*/

		movl	%edx, chainlenwmask(%esp)

/* Point %edi to the string under scrutiny, and %esi to the string we	*/
/* are hoping to match it up with. In actuality, %esi and %edi are	*/
/* both pointed (MAX_MATCH_8 - scanalign) bytes ahead, and %edx is	*/
/* initialized to -(MAX_MATCH_8 - scanalign).				*/

		movl	window(%esp), %esi
		movl	scan(%esp), %edi
		addl	%ecx, %esi
		movl	scanalign(%esp), %eax
		movl	$(-MAX_MATCH_8), %edx
		lea	MAX_MATCH_8(%edi,%eax), %edi
		lea	MAX_MATCH_8(%esi,%eax), %esi

/* Test the strings for equality, 8 bytes at a time. At the end,
 * adjust %edx so that it is offset to the exact byte that mismatched.
 *
 * We already know at this point that the first three bytes of the
 * strings match each other, and they can be safely passed over before
 * starting the compare loop. So what this code does is skip over 0-3
 * bytes, as much as necessary in order to dword-align the %edi
 * pointer. (%esi will still be misaligned three times out of four.)
 *
 * It should be confessed that this loop usually does not represent
 * much of the total running time. Replacing it with a more
 * straightforward "rep cmpsb" would not drastically degrade
 * performance.
 */
LoopCmps:
		movl	(%esi,%edx), %eax
		xorl	(%edi,%edx), %eax
		jnz	LeaveLoopCmps
		movl	4(%esi,%edx), %eax
		xorl	4(%edi,%edx), %eax
		jnz	LeaveLoopCmps4
		addl	$8, %edx
		jnz	LoopCmps
		jmp	LenMaximum
LeaveLoopCmps4:	addl	$4, %edx
LeaveLoopCmps:	testl	$0x0000FFFF, %eax
		jnz	LenLower
		addl	$2, %edx
		shrl	$16, %eax
LenLower:	subb	$1, %al
		adcl	$0, %edx

/* Calculate the length of the match. If it is longer than MAX_MATCH,	*/
/* then automatically accept it as the best possible match and leave.	*/

		lea	(%edi,%edx), %eax
		movl	scan(%esp), %edi
		subl	%edi, %eax
		cmpl	$MAX_MATCH, %eax
		jge	LenMaximum

/* If the length of the match is not longer than the best match we	*/
/* have so far, then forget it and return to the lookup loop.		*/

		movl	deflatestate(%esp), %edx
		movl	bestlen(%esp), %ebx
		cmpl	%ebx, %eax
		jg	LongerMatch
		movl	windowbestlen(%esp), %esi
		movl	dsPrev(%edx), %edi
		movl	scanend(%esp), %ebx
		movl	chainlenwmask(%esp), %edx
		jmp	LookupLoop

/*         s->match_start = cur_match;					*/
/*         best_len = len;						*/
/*         if (len >= nice_match) break;				*/
/*         scan_end = *(ushf*)(scan+best_len-1);			*/

LongerMatch:	movl	nicematch(%esp), %ebx
		movl	%eax, bestlen(%esp)
		movl	%ecx, dsMatchStart(%edx)
		cmpl	%ebx, %eax
		jge	LeaveNow
		movl	window(%esp), %esi
		addl	%eax, %esi
		movl	%esi, windowbestlen(%esp)
		movzwl	-1(%edi,%eax), %ebx
		movl	dsPrev(%edx), %edi
		movl	%ebx, scanend(%esp)
		movl	chainlenwmask(%esp), %edx
		jmp	LookupLoop

/* Accept the current string, with the maximum possible length.		*/

LenMaximum:	movl	deflatestate(%esp), %edx
		movl	$MAX_MATCH, bestlen(%esp)
		movl	%ecx, dsMatchStart(%edx)

/* if ((uInt)best_len <= s->lookahead) return (uInt)best_len;		*/
/* return s->lookahead;							*/

LeaveNow:
		movl	deflatestate(%esp), %edx
		movl	bestlen(%esp), %ebx
		movl	dsLookahead(%edx), %eax
		cmpl	%eax, %ebx
		jg	LookaheadRet
		movl	%ebx, %eax
LookaheadRet:

/* Restore the stack and return from whence we came.			*/

		addl	$LocalVarsSize, %esp
		.cfi_def_cfa_offset 20
		popl	%ebx
		.cfi_def_cfa_offset 16
		popl	%esi
		.cfi_def_cfa_offset 12
		popl	%edi
		.cfi_def_cfa_offset 8
		popl	%ebp
		.cfi_def_cfa_offset 4
.cfi_endproc
match_init:	ret
Commit	Line	Data
7c673cae FG	1	/* match.S -- x86 assembly version of the zlib longest_match() function.
	2	* Optimized for the Intel 686 chips (PPro and later).
	3	*
	4	* Copyright (C) 1998, 2007 Brian Raiter <breadbox@muppetlabs.com>
	5	*
	6	* This software is provided 'as-is', without any express or implied
	7	* warranty. In no event will the author be held liable for any damages
	8	* arising from the use of this software.
	9	*
	10	* Permission is granted to anyone to use this software for any purpose,
	11	* including commercial applications, and to alter it and redistribute it
	12	* freely, subject to the following restrictions:
	13	*
	14	* 1. The origin of this software must not be misrepresented; you must not
	15	* claim that you wrote the original software. If you use this software
	16	* in a product, an acknowledgment in the product documentation would be
	17	* appreciated but is not required.
	18	* 2. Altered source versions must be plainly marked as such, and must not be
	19	* misrepresented as being the original software.
	20	* 3. This notice may not be removed or altered from any source distribution.
	21	*/
	22
	23	#ifndef NO_UNDERLINE
	24	#define match_init _match_init
	25	#define longest_match _longest_match
	26	#endif
	27
	28	#define MAX_MATCH (258)
	29	#define MIN_MATCH (3)
	30	#define MIN_LOOKAHEAD (MAX_MATCH + MIN_MATCH + 1)
	31	#define MAX_MATCH_8 ((MAX_MATCH + 7) & ~7)
	32
	33	/* stack frame offsets */
	34
	35	#define chainlenwmask 0 /* high word: current chain len */
	36	/* low word: s->wmask */
	37	#define window 4 /* local copy of s->window */
	38	#define windowbestlen 8 /* s->window + bestlen */
	39	#define scanstart 16 /* first two bytes of string */
	40	#define scanend 12 /* last two bytes of string */
	41	#define scanalign 20 /* dword-misalignment of string */
	42	#define nicematch 24 /* a good enough match size */
	43	#define bestlen 28 /* size of best match so far */
	44	#define scan 32 /* ptr to string wanting match */
	45
	46	#define LocalVarsSize (36)
	47	/* saved ebx 36 */
	48	/* saved edi 40 */
	49	/* saved esi 44 */
	50	/* saved ebp 48 */
	51	/* return address 52 */
	52	#define deflatestate 56 /* the function arguments */
	53	#define curmatch 60
	54
	55	/* All the +zlib1222add offsets are due to the addition of fields
	56	* in zlib in the deflate_state structure since the asm code was first written
	57	* (if you compile with zlib 1.0.4 or older, use "zlib1222add equ (-4)").
	58	* (if you compile with zlib between 1.0.5 and 1.2.2.1, use "zlib1222add equ 0").
	59	* if you compile with zlib 1.2.2.2 or later , use "zlib1222add equ 8").
	60	*/
	61
	62	#define zlib1222add (8)
	63
	64	#define dsWSize (36+zlib1222add)
65	#define dsWMask (44+zlib1222add)
66	#define dsWindow (48+zlib1222add)
67	#define dsPrev (56+zlib1222add)
68	#define dsMatchLen (88+zlib1222add)
69	#define dsPrevMatch (92+zlib1222add)
70	#define dsStrStart (100+zlib1222add)
71	#define dsMatchStart (104+zlib1222add)
72	#define dsLookahead (108+zlib1222add)
73	#define dsPrevLen (112+zlib1222add)
74	#define dsMaxChainLen (116+zlib1222add)
75	#define dsGoodMatch (132+zlib1222add)
76	#define dsNiceMatch (136+zlib1222add)
77
78
79	.file "match.S"
80
81	.globl match_init, longest_match
82
83	.text
84
85	/* uInt longest_match(deflate_state deflatestate, IPos curmatch) /
86	.cfi_sections .debug_frame
87
88	longest_match:
89
90	.cfi_startproc
91	/* Save registers that the compiler may be using, and adjust %esp to */
92	/* make room for our stack frame. */
93
94	pushl %ebp
95	.cfi_def_cfa_offset 8
96	.cfi_offset ebp, -8
97	pushl %edi
98	.cfi_def_cfa_offset 12
99	pushl %esi
100	.cfi_def_cfa_offset 16
101	pushl %ebx
102	.cfi_def_cfa_offset 20
103	subl $LocalVarsSize, %esp
104	.cfi_def_cfa_offset LocalVarsSize+20
105
106	/* Retrieve the function arguments. %ecx will hold cur_match */
107	/* throughout the entire function. %edx will hold the pointer to the */
108	/* deflate_state structure during the function's setup (before */
109	/* entering the main loop). */
110
111	movl deflatestate(%esp), %edx
112	movl curmatch(%esp), %ecx
113
114	/* uInt wmask = s->w_mask; */
115	/* unsigned chain_length = s->max_chain_length; */
116	/* if (s->prev_length >= s->good_match) { */
117	/* chain_length >>= 2; */
118	/* } */
119
120	movl dsPrevLen(%edx), %eax
121	movl dsGoodMatch(%edx), %ebx
122	cmpl %ebx, %eax
123	movl dsWMask(%edx), %eax
124	movl dsMaxChainLen(%edx), %ebx
125	jl LastMatchGood
126	shrl $2, %ebx
127	LastMatchGood:
128
129	/* chainlen is decremented once beforehand so that the function can */
130	/* use the sign flag instead of the zero flag for the exit test. */
131	/* It is then shifted into the high word, to make room for the wmask */
132	/* value, which it will always accompany. */
133
134	decl %ebx
135	shll $16, %ebx
136	orl %eax, %ebx
137	movl %ebx, chainlenwmask(%esp)
138
139	/* if ((uInt)nice_match > s->lookahead) nice_match = s->lookahead; */
140
141	movl dsNiceMatch(%edx), %eax
142	movl dsLookahead(%edx), %ebx
143	cmpl %eax, %ebx
144	jl LookaheadLess
145	movl %eax, %ebx
146	LookaheadLess: movl %ebx, nicematch(%esp)
147
148	/* register Bytef scan = s->window + s->strstart; /
149
150	movl dsWindow(%edx), %esi
151	movl %esi, window(%esp)
152	movl dsStrStart(%edx), %ebp
153	lea (%esi,%ebp), %edi
154	movl %edi, scan(%esp)
155
156	/* Determine how many bytes the scan ptr is off from being */
157	/* dword-aligned. */
158
159	movl %edi, %eax
160	negl %eax
161	andl $3, %eax
162	movl %eax, scanalign(%esp)
163
164	/* IPos limit = s->strstart > (IPos)MAX_DIST(s) ? */
165	/* s->strstart - (IPos)MAX_DIST(s) : NIL; */
166
167	movl dsWSize(%edx), %eax
168	subl $MIN_LOOKAHEAD, %eax
169	subl %eax, %ebp
170	jg LimitPositive
171	xorl %ebp, %ebp
172	LimitPositive:
173
174	/* int best_len = s->prev_length; */
175
176	movl dsPrevLen(%edx), %eax
177	movl %eax, bestlen(%esp)
178
179	/* Store the sum of s->window + best_len in %esi locally, and in %esi. */
180
181	addl %eax, %esi
182	movl %esi, windowbestlen(%esp)
183
184	/* register ush scan_start = (ushf)scan; */
185	/* register ush scan_end = (ushf)(scan+best_len-1); */
186	/* Posf prev = s->prev; /
187
188	movzwl (%edi), %ebx
189	movl %ebx, scanstart(%esp)
190	movzwl -1(%edi,%eax), %ebx
191	movl %ebx, scanend(%esp)
192	movl dsPrev(%edx), %edi
193
194	/* Jump into the main loop. */
195
196	movl chainlenwmask(%esp), %edx
197	jmp LoopEntry
198
199	.balign 16
200
201	/* do {
202	* match = s->window + cur_match;
203	* if ((ushf)(match+best_len-1) != scan_end \|\|
204	* (ushf)match != scan_start) continue;
205	* [...]
206	* } while ((cur_match = prev[cur_match & wmask]) > limit
207	* && --chain_length != 0);
208	*
209	* Here is the inner loop of the function. The function will spend the
210	* majority of its time in this loop, and majority of that time will
211	* be spent in the first ten instructions.
212	*
213	* Within this loop:
214	* %ebx = scanend
215	* %ecx = curmatch
216	* %edx = chainlenwmask - i.e., ((chainlen << 16) \| wmask)
217	* %esi = windowbestlen - i.e., (window + bestlen)
218	* %edi = prev
219	* %ebp = limit
220	*/
221	LookupLoop:
222	andl %edx, %ecx
223	movzwl (%edi,%ecx,2), %ecx
224	cmpl %ebp, %ecx
225	jbe LeaveNow
226	subl $0x00010000, %edx
227	js LeaveNow
228	LoopEntry: movzwl -1(%esi,%ecx), %eax
229	cmpl %ebx, %eax
230	jnz LookupLoop
231	movl window(%esp), %eax
232	movzwl (%eax,%ecx), %eax
233	cmpl scanstart(%esp), %eax
234	jnz LookupLoop
235
236	/* Store the current value of chainlen. */
237
238	movl %edx, chainlenwmask(%esp)
239
240	/* Point %edi to the string under scrutiny, and %esi to the string we */
241	/* are hoping to match it up with. In actuality, %esi and %edi are */
242	/* both pointed (MAX_MATCH_8 - scanalign) bytes ahead, and %edx is */
243	/* initialized to -(MAX_MATCH_8 - scanalign). */
244
245	movl window(%esp), %esi
246	movl scan(%esp), %edi
247	addl %ecx, %esi
248	movl scanalign(%esp), %eax
249	movl $(-MAX_MATCH_8), %edx
250	lea MAX_MATCH_8(%edi,%eax), %edi
251	lea MAX_MATCH_8(%esi,%eax), %esi
252
253	/* Test the strings for equality, 8 bytes at a time. At the end,
254	* adjust %edx so that it is offset to the exact byte that mismatched.
255	*
256	* We already know at this point that the first three bytes of the
257	* strings match each other, and they can be safely passed over before
258	* starting the compare loop. So what this code does is skip over 0-3
259	* bytes, as much as necessary in order to dword-align the %edi
260	* pointer. (%esi will still be misaligned three times out of four.)
261	*
262	* It should be confessed that this loop usually does not represent
263	* much of the total running time. Replacing it with a more
264	* straightforward "rep cmpsb" would not drastically degrade
265	* performance.
266	*/
267	LoopCmps:
268	movl (%esi,%edx), %eax
269	xorl (%edi,%edx), %eax
270	jnz LeaveLoopCmps
271	movl 4(%esi,%edx), %eax
272	xorl 4(%edi,%edx), %eax
273	jnz LeaveLoopCmps4
274	addl $8, %edx
275	jnz LoopCmps
276	jmp LenMaximum
277	LeaveLoopCmps4: addl $4, %edx
278	LeaveLoopCmps: testl $0x0000FFFF, %eax
279	jnz LenLower
280	addl $2, %edx
281	shrl $16, %eax
282	LenLower: subb $1, %al
283	adcl $0, %edx
284
285	/* Calculate the length of the match. If it is longer than MAX_MATCH, */
286	/* then automatically accept it as the best possible match and leave. */
287
288	lea (%edi,%edx), %eax
289	movl scan(%esp), %edi
290	subl %edi, %eax
291	cmpl $MAX_MATCH, %eax
292	jge LenMaximum
293
294	/* If the length of the match is not longer than the best match we */
295	/* have so far, then forget it and return to the lookup loop. */
296
297	movl deflatestate(%esp), %edx
298	movl bestlen(%esp), %ebx
299	cmpl %ebx, %eax
300	jg LongerMatch
301	movl windowbestlen(%esp), %esi
302	movl dsPrev(%edx), %edi
303	movl scanend(%esp), %ebx
304	movl chainlenwmask(%esp), %edx
305	jmp LookupLoop
306
307	/* s->match_start = cur_match; */
308	/* best_len = len; */
309	/* if (len >= nice_match) break; */
310	/* scan_end = (ushf)(scan+best_len-1); */
311
312	LongerMatch: movl nicematch(%esp), %ebx
313	movl %eax, bestlen(%esp)
314	movl %ecx, dsMatchStart(%edx)
315	cmpl %ebx, %eax
316	jge LeaveNow
317	movl window(%esp), %esi
318	addl %eax, %esi
319	movl %esi, windowbestlen(%esp)
320	movzwl -1(%edi,%eax), %ebx
321	movl dsPrev(%edx), %edi
322	movl %ebx, scanend(%esp)
323	movl chainlenwmask(%esp), %edx
324	jmp LookupLoop
325
326	/* Accept the current string, with the maximum possible length. */
327
328	LenMaximum: movl deflatestate(%esp), %edx
329	movl $MAX_MATCH, bestlen(%esp)
330	movl %ecx, dsMatchStart(%edx)
331
332	/* if ((uInt)best_len <= s->lookahead) return (uInt)best_len; */
333	/* return s->lookahead; */
334
335	LeaveNow:
336	movl deflatestate(%esp), %edx
337	movl bestlen(%esp), %ebx
338	movl dsLookahead(%edx), %eax
339	cmpl %eax, %ebx
340	jg LookaheadRet
341	movl %ebx, %eax
342	LookaheadRet:
343
344	/* Restore the stack and return from whence we came. */
345
346	addl $LocalVarsSize, %esp
347	.cfi_def_cfa_offset 20
348	popl %ebx
349	.cfi_def_cfa_offset 16
350	popl %esi
351	.cfi_def_cfa_offset 12
352	popl %edi
353	.cfi_def_cfa_offset 8
354	popl %ebp
355	.cfi_def_cfa_offset 4
356	.cfi_endproc
357	match_init: ret