[ceph.git] / ceph / src / boost / libs / context / src / asm / jump_arm64_aapcs_macho_gas.S

/*
         Copyright Edward Nevill + Oliver Kowalke 2015
   Distributed under the Boost Software License, Version 1.0.
      (See accompanying file LICENSE_1_0.txt or copy at
          http://www.boost.org/LICENSE_1_0.txt)
*/
/*******************************************************
 *                                                     *
 *  -------------------------------------------------  *
 *  |  0  |  1  |  2  |  3  |  4  |  5  |  6  |  7  |  *
 *  -------------------------------------------------  *
 *  | 0x0 | 0x4 | 0x8 | 0xc | 0x10| 0x14| 0x18| 0x1c|  *
 *  -------------------------------------------------  *
 *  |    d8     |    d9     |    d10    |    d11    |  *
 *  -------------------------------------------------  *
 *  -------------------------------------------------  *
 *  |  8  |  9  |  10 |  11 |  12 |  13 |  14 |  15 |  *
 *  -------------------------------------------------  *
 *  | 0x20| 0x24| 0x28| 0x2c| 0x30| 0x34| 0x38| 0x3c|  *
 *  -------------------------------------------------  *
 *  |    d12    |    d13    |    d14    |    d15    |  *
 *  -------------------------------------------------  *
 *  -------------------------------------------------  *
 *  |  16 |  17 |  18 |  19 |  20 |  21 |  22 |  23 |  *
 *  -------------------------------------------------  *
 *  | 0x40| 0x44| 0x48| 0x4c| 0x50| 0x54| 0x58| 0x5c|  *
 *  -------------------------------------------------  *
 *  |    x19    |    x20    |    x21    |    x22    |  *
 *  -------------------------------------------------  *
 *  -------------------------------------------------  *
 *  |  24 |  25 |  26 |  27 |  28 |  29 |  30 |  31 |  *
 *  -------------------------------------------------  *
 *  | 0x60| 0x64| 0x68| 0x6c| 0x70| 0x74| 0x78| 0x7c|  *
 *  -------------------------------------------------  *
 *  |    x23    |    x24    |    x25    |    x26    |  *
 *  -------------------------------------------------  *
 *  -------------------------------------------------  *
 *  |  32 |  33 |  34 |  35 |  36 |  37 |  38 |  39 |  *
 *  -------------------------------------------------  *
 *  | 0x80| 0x84| 0x88| 0x8c| 0x90| 0x94| 0x98| 0x9c|  *
 *  -------------------------------------------------  *
 *  |    x27    |    x28    |    FP     |     LR    |  *
 *  -------------------------------------------------  *
 *  -------------------------------------------------  *
 *  |  40 |  41 |  42 | 43  |           |           |  *
 *  -------------------------------------------------  *
 *  | 0xa0| 0xa4| 0xa8| 0xac|           |           |  *
 *  -------------------------------------------------  *
 *  |     PC    |   align   |           |           |  *
 *  -------------------------------------------------  *
 *                                                     *
 *******************************************************/

.text
.globl _jump_fcontext
.balign 16
_jump_fcontext:
    ; prepare stack for GP + FPU
    sub  sp, sp, #0xb0

    ; save d8 - d15
    stp  d8,  d9,  [sp, #0x00]
    stp  d10, d11, [sp, #0x10]
    stp  d12, d13, [sp, #0x20]
    stp  d14, d15, [sp, #0x30]

    ; save x19-x30
    stp  x19, x20, [sp, #0x40]
    stp  x21, x22, [sp, #0x50]
    stp  x23, x24, [sp, #0x60]
    stp  x25, x26, [sp, #0x70]
    stp  x27, x28, [sp, #0x80]
    stp  fp,  lr,  [sp, #0x90]

    ; save LR as PC
    str  lr, [sp, #0xa0]

    ; store RSP (pointing to context-data) in X0
    mov  x4, sp

    ; restore RSP (pointing to context-data) from X1
    mov  sp, x0

    ; load d8 - d15
    ldp  d8,  d9,  [sp, #0x00]
    ldp  d10, d11, [sp, #0x10]
    ldp  d12, d13, [sp, #0x20]
    ldp  d14, d15, [sp, #0x30]

    ; load x19-x30
    ldp  x19, x20, [sp, #0x40]
    ldp  x21, x22, [sp, #0x50]
    ldp  x23, x24, [sp, #0x60]
    ldp  x25, x26, [sp, #0x70]
    ldp  x27, x28, [sp, #0x80]
    ldp  fp,  lr,  [sp, #0x90]

    ; return transfer_t from jump
    ; pass transfer_t as first arg in context function
    ; X0 == FCTX, X1 == DATA
    mov x0, x4

    ; load pc
    ldr  x4, [sp, #0xa0]

    ; restore stack from GP + FPU
    add  sp, sp, #0xb0

    ret x4
Commit	Line	Data
b32b8144 FG	1	/*
	2	Copyright Edward Nevill + Oliver Kowalke 2015
	3	Distributed under the Boost Software License, Version 1.0.
	4	(See accompanying file LICENSE_1_0.txt or copy at
	5	http://www.boost.org/LICENSE_1_0.txt)
	6	*/
7c673cae FG	7	/*******************************************************
	8	* *
	9	* ------------------------------------------------- *
	10	* \| 0 \| 1 \| 2 \| 3 \| 4 \| 5 \| 6 \| 7 \| *
	11	* ------------------------------------------------- *
	12	* \| 0x0 \| 0x4 \| 0x8 \| 0xc \| 0x10\| 0x14\| 0x18\| 0x1c\| *
	13	* ------------------------------------------------- *
b32b8144	14	* \| d8 \| d9 \| d10 \| d11 \| *
7c673cae FG	15	* ------------------------------------------------- *
	16	* ------------------------------------------------- *
	17	* \| 8 \| 9 \| 10 \| 11 \| 12 \| 13 \| 14 \| 15 \| *
	18	* ------------------------------------------------- *
	19	* \| 0x20\| 0x24\| 0x28\| 0x2c\| 0x30\| 0x34\| 0x38\| 0x3c\| *
	20	* ------------------------------------------------- *
b32b8144	21	* \| d12 \| d13 \| d14 \| d15 \| *
7c673cae FG	22	* ------------------------------------------------- *
	23	* ------------------------------------------------- *
	24	* \| 16 \| 17 \| 18 \| 19 \| 20 \| 21 \| 22 \| 23 \| *
	25	* ------------------------------------------------- *
	26	* \| 0x40\| 0x44\| 0x48\| 0x4c\| 0x50\| 0x54\| 0x58\| 0x5c\| *
	27	* ------------------------------------------------- *
b32b8144	28	* \| x19 \| x20 \| x21 \| x22 \| *
7c673cae FG	29	* ------------------------------------------------- *
	30	* ------------------------------------------------- *
	31	* \| 24 \| 25 \| 26 \| 27 \| 28 \| 29 \| 30 \| 31 \| *
	32	* ------------------------------------------------- *
	33	* \| 0x60\| 0x64\| 0x68\| 0x6c\| 0x70\| 0x74\| 0x78\| 0x7c\| *
	34	* ------------------------------------------------- *
b32b8144 FG	35	* \| x23 \| x24 \| x25 \| x26 \| *
	36	* ------------------------------------------------- *
	37	* ------------------------------------------------- *
	38	* \| 32 \| 33 \| 34 \| 35 \| 36 \| 37 \| 38 \| 39 \| *
	39	* ------------------------------------------------- *
	40	* \| 0x80\| 0x84\| 0x88\| 0x8c\| 0x90\| 0x94\| 0x98\| 0x9c\| *
	41	* ------------------------------------------------- *
	42	* \| x27 \| x28 \| FP \| LR \| *
	43	* ------------------------------------------------- *
	44	* ------------------------------------------------- *
	45	* \| 40 \| 41 \| 42 \| 43 \| \| \| *
	46	* ------------------------------------------------- *
	47	* \| 0xa0\| 0xa4\| 0xa8\| 0xac\| \| \| *
	48	* ------------------------------------------------- *
7c673cae FG	49	* \| PC \| align \| \| \| *
	50	* ------------------------------------------------- *
	51	* *
	52	*******************************************************/
	53
	54	.text
	55	.globl _jump_fcontext
	56	.balign 16
	57	_jump_fcontext:
	58	; prepare stack for GP + FPU
b32b8144 FG	59	sub sp, sp, #0xb0
	60
	61	; save d8 - d15
	62	stp d8, d9, [sp, #0x00]
	63	stp d10, d11, [sp, #0x10]
	64	stp d12, d13, [sp, #0x20]
	65	stp d14, d15, [sp, #0x30]
7c673cae FG	66
7c673cae FG	67	; save x19-x30
b32b8144 FG	68	stp x19, x20, [sp, #0x40]
	69	stp x21, x22, [sp, #0x50]
	70	stp x23, x24, [sp, #0x60]
	71	stp x25, x26, [sp, #0x70]
	72	stp x27, x28, [sp, #0x80]
	73	stp fp, lr, [sp, #0x90]
7c673cae FG	74
7c673cae FG	75	; save LR as PC
b32b8144	76	str lr, [sp, #0xa0]
7c673cae FG	77
	78	; store RSP (pointing to context-data) in X0
	79	mov x4, sp
	80
	81	; restore RSP (pointing to context-data) from X1
	82	mov sp, x0
	83
b32b8144 FG	84	; load d8 - d15
	85	ldp d8, d9, [sp, #0x00]
	86	ldp d10, d11, [sp, #0x10]
	87	ldp d12, d13, [sp, #0x20]
	88	ldp d14, d15, [sp, #0x30]
	89
7c673cae	90	; load x19-x30
b32b8144 FG	91	ldp x19, x20, [sp, #0x40]
	92	ldp x21, x22, [sp, #0x50]
	93	ldp x23, x24, [sp, #0x60]
	94	ldp x25, x26, [sp, #0x70]
	95	ldp x27, x28, [sp, #0x80]
	96	ldp fp, lr, [sp, #0x90]
7c673cae FG	97
	98	; return transfer_t from jump
	99	; pass transfer_t as first arg in context function
	100	; X0 == FCTX, X1 == DATA
	101	mov x0, x4
	102
	103	; load pc
b32b8144	104	ldr x4, [sp, #0xa0]
7c673cae FG	105
7c673cae FG	106	; restore stack from GP + FPU
b32b8144	107	add sp, sp, #0xb0
7c673cae FG	108
7c673cae FG	109	ret x4