update ceph source to reef 18.1.2

[ceph.git] / ceph / src / jaegertracing / opentelemetry-cpp / tools / vcpkg / ports / portable-snippets / CMakeLists.txt

cmake_minimum_required(VERSION 3.14)\r
\r
project(portable-snippets LANGUAGES C)\r
\r
include(GNUInstallDirs)\r
\r
option(PSNIP_INSTALL_HEADERS "Install header files" ON)\r
\r
# https://stackoverflow.com/questions/7787823/cmake-how-to-get-the-name-of-all-subdirectories-of-a-directory\r
function (list_subdir output_variable path)\r
    file(GLOB sub_entries RELATIVE ${path} ${path}/*)\r
\r
    set(dirlist "")\r
\r
    foreach (entry ${sub_entries})\r
        if (IS_DIRECTORY ${path}/${entry})\r
            list(APPEND dirlist ${entry})\r
        endif ()\r
    endforeach ()\r
\r
    set(${output_variable} ${dirlist} PARENT_SCOPE)\r
endfunction ()\r
\r
function (check_if_header_only output_variable files)\r
    set(is_header_only 1)\r
\r
    foreach (entry ${files})\r
        get_filename_component(file_ext ${entry} EXT)\r
        if (file_ext STREQUAL .c)\r
            set(is_header_only 0)\r
        endif ()\r
    endforeach ()\r
\r
    set(${output_variable} ${is_header_only} PARENT_SCOPE)\r
endfunction ()\r
\r
list_subdir(subdirs ${CMAKE_CURRENT_LIST_DIR})\r
list(REMOVE_ITEM subdirs tests)\r
\r
set(namespace unofficial::portable-snippets)\r
\r
foreach (subdir ${subdirs})\r
    set(module ${subdir})\r
    set(module_path "${CMAKE_CURRENT_LIST_DIR}/${subdir}")\r
\r
    file(GLOB entries\r
        LIST_DIRECTORIES false\r
        ${module_path}/*.h\r
        ${module_path}/*.c\r
    )\r
\r
    check_if_header_only(header_only "${entries}")\r
\r
    if (header_only)\r
        add_library(${module} INTERFACE)\r
\r
        target_include_directories(\r
            ${module}\r
            INTERFACE\r
                $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>\r
        )\r
    else ()\r
        add_library(${module} STATIC ${entries})\r
\r
        set_target_properties(\r
            ${module}\r
            PROPERTIES\r
                PREFIX ""\r
                OUTPUT_NAME "psnip-${module}"\r
        )\r
\r
        target_include_directories(\r
            ${module}\r
            PUBLIC\r
                $<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}>\r
                $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>\r
        )\r
\r
        list(FILTER entries EXCLUDE REGEX "\.c$")\r
    endif ()\r
\r
    add_library(${namespace}::${module} ALIAS ${module})\r
\r
    if (PSNIP_INSTALL_HEADERS)\r
        install(FILES ${entries} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${subdir})\r
    endif ()\r
\r
    install(TARGETS ${module} EXPORT unofficial-portable-snippets-config)\r
endforeach ()\r
\r
install(\r
    EXPORT unofficial-portable-snippets-config\r
    NAMESPACE ${namespace}::\r
    DESTINATION share/unofficial-portable-snippets\r
    PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ\r
)\r