[ceph.git] / ceph / src / jaegertracing / opentelemetry-cpp / tools / vcpkg / scripts / cmake / vcpkg_configure_make.cmake

#[===[.md:\r
# vcpkg_configure_make\r
\r
Configure configure for Debug and Release builds of a project.\r
\r
## Usage\r
```cmake\r
vcpkg_configure_make(\r
    SOURCE_PATH <${SOURCE_PATH}>\r
    [AUTOCONFIG]\r
    [USE_WRAPPERS]\r
    [DETERMINE_BUILD_TRIPLET]\r
    [BUILD_TRIPLET "--host=x64 --build=i686-unknown-pc"]\r
    [NO_ADDITIONAL_PATHS]\r
    [CONFIG_DEPENDENT_ENVIRONMENT <SOME_VAR>...]\r
    [CONFIGURE_ENVIRONMENT_VARIABLES <SOME_ENVVAR>...]\r
    [ADD_BIN_TO_PATH]\r
    [NO_DEBUG]\r
    [SKIP_CONFIGURE]\r
    [PROJECT_SUBPATH <${PROJ_SUBPATH}>]\r
    [PRERUN_SHELL <${SHELL_PATH}>]\r
    [OPTIONS <-DUSE_THIS_IN_ALL_BUILDS=1>...]\r
    [OPTIONS_RELEASE <-DOPTIMIZE=1>...]\r
    [OPTIONS_DEBUG <-DDEBUGGABLE=1>...]\r
)\r
```\r
\r
## Parameters\r
### SOURCE_PATH\r
Specifies the directory containing the `configure`/`configure.ac`.\r
By convention, this is usually set in the portfile as the variable `SOURCE_PATH`.\r
\r
### PROJECT_SUBPATH\r
Specifies the directory containing the ``configure`/`configure.ac`.\r
By convention, this is usually set in the portfile as the variable `SOURCE_PATH`.\r
\r
### SKIP_CONFIGURE\r
Skip configure process\r
\r
### USE_WRAPPERS\r
Use autotools ar-lib and compile wrappers (only applies to windows cl and lib)\r
\r
### BUILD_TRIPLET\r
Used to pass custom --build/--target/--host to configure. Can be globally overwritten by VCPKG_MAKE_BUILD_TRIPLET\r
\r
### DETERMINE_BUILD_TRIPLET\r
For ports having a configure script following the autotools rules for selecting the triplet\r
\r
### NO_ADDITIONAL_PATHS\r
Don't pass any additional paths except for --prefix to the configure call\r
\r
### AUTOCONFIG\r
Need to use autoconfig to generate configure file.\r
\r
### PRERUN_SHELL\r
Script that needs to be called before configuration (do not use for batch files which simply call autoconf or configure)\r
\r
### ADD_BIN_TO_PATH\r
Adds the appropriate Release and Debug `bin\` directories to the path during configure such that executables can run against the in-tree DLLs.\r
\r
## DISABLE_VERBOSE_FLAGS\r
do not pass '--disable-silent-rules --verbose' to configure\r
\r
### OPTIONS\r
Additional options passed to configure during the configuration.\r
\r
### OPTIONS_RELEASE\r
Additional options passed to configure during the Release configuration. These are in addition to `OPTIONS`.\r
\r
### OPTIONS_DEBUG\r
Additional options passed to configure during the Debug configuration. These are in addition to `OPTIONS`.\r
\r
### CONFIG_DEPENDENT_ENVIRONMENT\r
List of additional configuration dependent environment variables to set. \r
Pass SOMEVAR to set the environment and have SOMEVAR_(DEBUG|RELEASE) set in the portfile to the appropriate values\r
General environment variables can be set from within the portfile itself. \r
\r
### CONFIGURE_ENVIRONMENT_VARIABLES\r
List of additional environment variables to pass via the configure call. \r
\r
## Notes\r
This command supplies many common arguments to configure. To see the full list, examine the source.\r
\r
## Examples\r
\r
* [x264](https://github.com/Microsoft/vcpkg/blob/master/ports/x264/portfile.cmake)\r
* [tcl](https://github.com/Microsoft/vcpkg/blob/master/ports/tcl/portfile.cmake)\r
* [freexl](https://github.com/Microsoft/vcpkg/blob/master/ports/freexl/portfile.cmake)\r
* [libosip2](https://github.com/Microsoft/vcpkg/blob/master/ports/libosip2/portfile.cmake)\r
#]===]\r
\r
macro(_vcpkg_determine_host_mingw out_var)\r
    if(DEFINED ENV{PROCESSOR_ARCHITEW6432})\r
        set(HOST_ARCH $ENV{PROCESSOR_ARCHITEW6432})\r
    else()\r
        set(HOST_ARCH $ENV{PROCESSOR_ARCHITECTURE})\r
    endif()\r
    if(HOST_ARCH MATCHES "(amd|AMD)64")\r
        set(${out_var} mingw64)\r
    elseif(HOST_ARCH MATCHES "(x|X)86")\r
        set(${out_var} mingw32)\r
    else()\r
        message(FATAL_ERROR "Unsupported mingw architecture ${HOST_ARCH} in _vcpkg_determine_autotools_host_cpu!" )\r
    endif()\r
    unset(HOST_ARCH)\r
endmacro()\r
\r
macro(_vcpkg_determine_autotools_host_cpu out_var)\r
    # TODO: the host system processor architecture can differ from the host triplet target architecture\r
    if(DEFINED ENV{PROCESSOR_ARCHITEW6432})\r
        set(HOST_ARCH $ENV{PROCESSOR_ARCHITEW6432})\r
    elseif(DEFINED ENV{PROCESSOR_ARCHITECTURE})\r
        set(HOST_ARCH $ENV{PROCESSOR_ARCHITECTURE})\r
    else()\r
        set(HOST_ARCH "${VCPKG_DETECTED_CMAKE_HOST_SYSTEM_PROCESSOR}")\r
    endif()\r
    if(HOST_ARCH MATCHES "(amd|AMD)64")\r
        set(${out_var} x86_64)\r
    elseif(HOST_ARCH MATCHES "(x|X)86")\r
        set(${out_var} i686)\r
    elseif(HOST_ARCH MATCHES "^(ARM|arm)64$")\r
        set(${out_var} aarch64)\r
    elseif(HOST_ARCH MATCHES "^(ARM|arm)$")\r
        set(${out_var} arm)\r
    else()\r
        message(FATAL_ERROR "Unsupported host architecture ${HOST_ARCH} in _vcpkg_determine_autotools_host_cpu!" )\r
    endif()\r
    unset(HOST_ARCH)\r
endmacro()\r
\r
macro(_vcpkg_determine_autotools_target_cpu out_var)\r
    if(VCPKG_TARGET_ARCHITECTURE MATCHES "(x|X)64")\r
        set(${out_var} x86_64)\r
    elseif(VCPKG_TARGET_ARCHITECTURE MATCHES "(x|X)86")\r
        set(${out_var} i686)\r
    elseif(VCPKG_TARGET_ARCHITECTURE MATCHES "^(ARM|arm)64$")\r
        set(${out_var} aarch64)\r
    elseif(VCPKG_TARGET_ARCHITECTURE MATCHES "^(ARM|arm)$")\r
        set(${out_var} arm)\r
    else()\r
        message(FATAL_ERROR "Unsupported VCPKG_TARGET_ARCHITECTURE architecture ${VCPKG_TARGET_ARCHITECTURE} in _vcpkg_determine_autotools_target_cpu!" )\r
    endif()\r
endmacro()\r
\r
macro(_vcpkg_determine_autotools_host_arch_mac out_var)\r
    set(${out_var} "${VCPKG_DETECTED_CMAKE_HOST_SYSTEM_PROCESSOR}")\r
endmacro()\r
\r
macro(_vcpkg_determine_autotools_target_arch_mac out_var)\r
    list(LENGTH VCPKG_OSX_ARCHITECTURES _num_osx_archs)\r
    if(_num_osx_archs GREATER_EQUAL 2)\r
        set(${out_var} "universal")\r
    else()\r
        # Better match the arch behavior of config.guess\r
        # See: https://git.savannah.gnu.org/gitweb/?p=config.git;a=blob_plain;f=config.guess;hb=HEAD\r
        if(VCPKG_OSX_ARCHITECTURES MATCHES "^(ARM|arm)64$")\r
            set(${out_var} "aarch64")\r
        else()\r
            set(${out_var} "${VCPKG_OSX_ARCHITECTURES}")\r
        endif()\r
    endif()\r
    unset(_num_osx_archs)\r
endmacro()\r
\r
macro(_vcpkg_backup_env_variable envvar)\r
    if(DEFINED ENV{${envvar}})\r
        set(${envvar}_BACKUP "$ENV{${envvar}}")\r
        set(${envvar}_PATHLIKE_CONCAT "${VCPKG_HOST_PATH_SEPARATOR}$ENV{${envvar}}")\r
    else()\r
        set(${envvar}_BACKUP)\r
        set(${envvar}_PATHLIKE_CONCAT)\r
    endif()\r
endmacro()\r
\r
macro(_vcpkg_backup_env_variables)\r
    foreach(_var ${ARGV})\r
        _vcpkg_backup_env_variable(${_var})\r
    endforeach()\r
endmacro()\r
\r
macro(_vcpkg_restore_env_variable envvar)\r
    if(${envvar}_BACKUP)\r
        set(ENV{${envvar}} "${${envvar}_BACKUP}")\r
    else()\r
        unset(ENV{${envvar}})\r
    endif()\r
endmacro()\r
\r
macro(_vcpkg_restore_env_variables)\r
    foreach(_var ${ARGV})\r
        _vcpkg_restore_env_variable(${_var})\r
    endforeach()\r
endmacro()\r
\r
macro(_vcpkg_extract_cpp_flags_and_set_cflags_and_cxxflags _SUFFIX)\r
    string(REGEX MATCHALL "( |^)-D[^ ]+" CPPFLAGS_${_SUFFIX} "${VCPKG_DETECTED_CMAKE_C_FLAGS_${_SUFFIX}}")\r
    string(REGEX MATCHALL "( |^)-D[^ ]+" CXXPPFLAGS_${_SUFFIX} "${VCPKG_DETECTED_CMAKE_CXX_FLAGS_${_SUFFIX}}")\r
    list(JOIN CXXPPFLAGS_${_SUFFIX} "|" CXXREGEX)\r
    if(CXXREGEX)\r
        list(FILTER CPPFLAGS_${_SUFFIX} INCLUDE REGEX "(${CXXREGEX})")\r
    else()\r
        set(CPPFLAGS_${_SUFFIX})\r
    endif()\r
    list(JOIN CPPFLAGS_${_SUFFIX} "|" CPPREGEX)\r
    list(JOIN CPPFLAGS_${_SUFFIX} " " CPPFLAGS_${_SUFFIX})\r
    set(CPPFLAGS_${_SUFFIX} "${CPPFLAGS_${_SUFFIX}}")\r
    if(CPPREGEX)\r
        string(REGEX REPLACE "(${CPPREGEX})" "" CFLAGS_${_SUFFIX} "${VCPKG_DETECTED_CMAKE_C_FLAGS_${_SUFFIX}}")\r
        string(REGEX REPLACE "(${CPPREGEX})" "" CXXFLAGS_${_SUFFIX} "${VCPKG_DETECTED_CMAKE_CXX_FLAGS_${_SUFFIX}}")\r
    else()\r
        set(CFLAGS_${_SUFFIX} "${VCPKG_DETECTED_CMAKE_C_FLAGS_${_SUFFIX}}")\r
        set(CXXFLAGS_${_SUFFIX} "${VCPKG_DETECTED_CMAKE_CXX_FLAGS_${_SUFFIX}}")\r
    endif()\r
    string(REGEX REPLACE " +" " " CPPFLAGS_${_SUFFIX} "${CPPFLAGS_${_SUFFIX}}")\r
    string(REGEX REPLACE " +" " " CFLAGS_${_SUFFIX} "${CFLAGS_${_SUFFIX}}")\r
    string(REGEX REPLACE " +" " " CXXFLAGS_${_SUFFIX} "${CXXFLAGS_${_SUFFIX}}")\r
    # libtool has and -R option so we need to guard against -RTC by using -Xcompiler\r
    # while configuring there might be a lot of unknown compiler option warnings due to that\r
    # just ignore them. \r
    string(REGEX REPLACE "((-|/)RTC[^ ]+)" "-Xcompiler \\1" CFLAGS_${_SUFFIX} "${CFLAGS_${_SUFFIX}}")\r
    string(REGEX REPLACE "((-|/)RTC[^ ]+)" "-Xcompiler \\1" CXXFLAGS_${_SUFFIX} "${CXXFLAGS_${_SUFFIX}}")\r
    string(STRIP "${CPPFLAGS_${_SUFFIX}}" CPPFLAGS_${_SUFFIX})\r
    string(STRIP "${CFLAGS_${_SUFFIX}}" CFLAGS_${_SUFFIX})\r
    string(STRIP "${CXXFLAGS_${_SUFFIX}}" CXXFLAGS_${_SUFFIX})\r
    debug_message("CPPFLAGS_${_SUFFIX}: ${CPPFLAGS_${_SUFFIX}}")\r
    debug_message("CFLAGS_${_SUFFIX}: ${CFLAGS_${_SUFFIX}}")\r
    debug_message("CXXFLAGS_${_SUFFIX}: ${CXXFLAGS_${_SUFFIX}}")\r
endmacro()\r
\r
function(vcpkg_configure_make)\r
    # parse parameters such that semicolons in options arguments to COMMAND don't get erased\r
    cmake_parse_arguments(PARSE_ARGV 0 _csc\r
        "AUTOCONFIG;SKIP_CONFIGURE;COPY_SOURCE;DISABLE_VERBOSE_FLAGS;NO_ADDITIONAL_PATHS;ADD_BIN_TO_PATH;USE_WRAPPERS;DETERMINE_BUILD_TRIPLET"\r
        "SOURCE_PATH;PROJECT_SUBPATH;PRERUN_SHELL;BUILD_TRIPLET"\r
        "OPTIONS;OPTIONS_DEBUG;OPTIONS_RELEASE;CONFIGURE_ENVIRONMENT_VARIABLES;CONFIG_DEPENDENT_ENVIRONMENT;ADDITIONAL_MSYS_PACKAGES"\r
    )\r
    vcpkg_internal_get_cmake_vars(OUTPUT_FILE _VCPKG_CMAKE_VARS_FILE)\r
    set(_VCPKG_CMAKE_VARS_FILE "${_VCPKG_CMAKE_VARS_FILE}" PARENT_SCOPE)\r
    debug_message("Including cmake vars from: ${_VCPKG_CMAKE_VARS_FILE}")\r
    include("${_VCPKG_CMAKE_VARS_FILE}")\r
    if(DEFINED VCPKG_MAKE_BUILD_TRIPLET)\r
        set(_csc_BUILD_TRIPLET ${VCPKG_MAKE_BUILD_TRIPLET}) # Triplet overwrite for crosscompiling\r
    endif()\r
\r
    set(SRC_DIR "${_csc_SOURCE_PATH}/${_csc_PROJECT_SUBPATH}")\r
\r
    set(REQUIRES_AUTOGEN FALSE) # use autogen.sh\r
    set(REQUIRES_AUTOCONFIG FALSE) # use autotools and configure.ac\r
    if(EXISTS "${SRC_DIR}/configure" AND "${SRC_DIR}/configure.ac") # remove configure; rerun autoconf\r
        if(NOT VCPKG_MAINTAINER_SKIP_AUTOCONFIG) # If fixing bugs skipping autoconfig saves a lot of time\r
            set(REQUIRES_AUTOCONFIG TRUE)\r
            file(REMOVE "${SRC_DIR}/configure") # remove possible autodated configure scripts\r
            set(_csc_AUTOCONFIG ON)\r
        endif()\r
    elseif(EXISTS "${SRC_DIR}/configure" AND NOT _csc_SKIP_CONFIGURE) # run normally; no autoconf or autgen required\r
    elseif(EXISTS "${SRC_DIR}/configure.ac") # Run autoconfig\r
        set(REQUIRES_AUTOCONFIG TRUE)\r
        set(_csc_AUTOCONFIG ON)\r
    elseif(EXISTS "${SRC_DIR}/autogen.sh") # Run autogen\r
        set(REQUIRES_AUTOGEN TRUE)\r
    else()\r
        message(FATAL_ERROR "Could not determine method to configure make")\r
    endif()\r
\r
    debug_message("REQUIRES_AUTOGEN:${REQUIRES_AUTOGEN}")\r
    debug_message("REQUIRES_AUTOCONFIG:${REQUIRES_AUTOCONFIG}")\r
    # Backup environment variables\r
    # CCAS CC C CPP CXX FC FF GC LD LF LIBTOOL OBJC OBJCXX R UPC Y \r
    set(_cm_FLAGS AS CCAS CC C CPP CXX FC FF GC LD LF LIBTOOL OBJC OBJXX R UPC Y RC)\r
    list(TRANSFORM _cm_FLAGS APPEND "FLAGS")\r
    _vcpkg_backup_env_variables(${_cm_FLAGS})\r
\r
\r
    # FC fotran compiler | FF Fortran 77 compiler \r
    # LDFLAGS -> pass -L flags\r
    # LIBS -> pass -l flags\r
\r
    #Used by gcc/linux\r
    _vcpkg_backup_env_variables(C_INCLUDE_PATH CPLUS_INCLUDE_PATH LIBRARY_PATH LD_LIBRARY_PATH)\r
\r
    #Used by cl\r
    _vcpkg_backup_env_variables(INCLUDE LIB LIBPATH)\r
\r
    set(_vcm_paths_with_spaces FALSE)\r
    if(CURRENT_PACKAGES_DIR MATCHES " " OR CURRENT_INSTALLED_DIR MATCHES " ")\r
        # Don't bother with whitespace. The tools will probably fail and I tried very hard trying to make it work (no success so far)!\r
        message(WARNING "Detected whitespace in root directory. Please move the path to one without whitespaces! The required tools do not handle whitespaces correctly and the build will most likely fail")\r
        set(_vcm_paths_with_spaces TRUE)\r
    endif()\r
\r
    # Pre-processing windows configure requirements\r
    if (VCPKG_TARGET_IS_WINDOWS)\r
        if(CMAKE_HOST_WIN32)\r
            list(APPEND MSYS_REQUIRE_PACKAGES binutils libtool autoconf automake-wrapper automake1.16 m4)\r
            vcpkg_acquire_msys(MSYS_ROOT PACKAGES ${MSYS_REQUIRE_PACKAGES} ${_csc_ADDITIONAL_MSYS_PACKAGES})\r
        endif()\r
        if (_csc_AUTOCONFIG AND NOT _csc_BUILD_TRIPLET OR _csc_DETERMINE_BUILD_TRIPLET OR VCPKG_CROSSCOMPILING AND NOT _csc_BUILD_TRIPLET)\r
            _vcpkg_determine_autotools_host_cpu(BUILD_ARCH) # VCPKG_HOST => machine you are building on => --build=\r
            _vcpkg_determine_autotools_target_cpu(TARGET_ARCH)\r
            # --build: the machine you are building on\r
            # --host: the machine you are building for\r
            # --target: the machine that CC will produce binaries for\r
            # https://stackoverflow.com/questions/21990021/how-to-determine-host-value-for-configure-when-using-cross-compiler\r
            # Only for ports using autotools so we can assume that they follow the common conventions for build/target/host\r
            if(CMAKE_HOST_WIN32)\r
                set(_csc_BUILD_TRIPLET "--build=${BUILD_ARCH}-pc-mingw32")  # This is required since we are running in a msys\r
                                                                            # shell which will be otherwise identified as ${BUILD_ARCH}-pc-msys\r
            endif()\r
            if(NOT TARGET_ARCH MATCHES "${BUILD_ARCH}" OR NOT CMAKE_HOST_WIN32) # we don't need to specify the additional flags if we build nativly, this does not hold when we are not on windows\r
                string(APPEND _csc_BUILD_TRIPLET " --host=${TARGET_ARCH}-pc-mingw32") # (Host activates crosscompilation; The name given here is just the prefix of the host tools for the target)\r
            endif()\r
            if(VCPKG_TARGET_IS_UWP AND NOT _csc_BUILD_TRIPLET MATCHES "--host")\r
                # Needs to be different from --build to enable cross builds.\r
                string(APPEND _csc_BUILD_TRIPLET " --host=${TARGET_ARCH}-unknown-mingw32")\r
            endif()\r
            debug_message("Using make triplet: ${_csc_BUILD_TRIPLET}")\r
        endif()\r
        if(CMAKE_HOST_WIN32)\r
            set(APPEND_ENV)\r
            if(_csc_AUTOCONFIG OR _csc_USE_WRAPPERS)\r
                set(APPEND_ENV ";${MSYS_ROOT}/usr/share/automake-1.16")\r
                string(APPEND APPEND_ENV ";${SCRIPTS}/buildsystems/make_wrapper") # Other required wrappers are also located there\r
            endif()\r
            # This inserts msys before system32 (which masks sort.exe and find.exe) but after MSVC (which avoids masking link.exe)\r
            string(REPLACE ";$ENV{SystemRoot}\\System32;" "${APPEND_ENV};${MSYS_ROOT}/usr/bin;$ENV{SystemRoot}\\System32;" NEWPATH "$ENV{PATH}")\r
            string(REPLACE ";$ENV{SystemRoot}\\system32;" "${APPEND_ENV};${MSYS_ROOT}/usr/bin;$ENV{SystemRoot}\\system32;" NEWPATH "$ENV{PATH}")\r
            set(ENV{PATH} "${NEWPATH}")\r
            set(BASH "${MSYS_ROOT}/usr/bin/bash.exe")\r
        endif()\r
\r
        macro(_vcpkg_append_to_configure_environment inoutstring var defaultval)\r
            # Allows to overwrite settings in custom triplets via the environment on windows\r
            if(CMAKE_HOST_WIN32 AND DEFINED ENV{${var}})\r
                string(APPEND ${inoutstring} " ${var}='$ENV{${var}}'")\r
            else()\r
                string(APPEND ${inoutstring} " ${var}='${defaultval}'")\r
            endif()\r
        endmacro()\r
\r
        set(CONFIGURE_ENV "V=1")\r
        # Remove full filepaths due to spaces and prepend filepaths to PATH (cross-compiling tools are unlikely on path by default)\r
        set(progs VCPKG_DETECTED_CMAKE_C_COMPILER VCPKG_DETECTED_CMAKE_CXX_COMPILER VCPKG_DETECTED_CMAKE_AR\r
                  VCPKG_DETECTED_CMAKE_LINKER VCPKG_DETECTED_CMAKE_RANLIB VCPKG_DETECTED_CMAKE_OBJDUMP\r
                  VCPKG_DETECTED_CMAKE_STRIP VCPKG_DETECTED_CMAKE_NM VCPKG_DETECTED_CMAKE_DLLTOOL VCPKG_DETECTED_CMAKE_RC_COMPILER)\r
        foreach(prog IN LISTS progs)\r
            if(${prog})\r
                set(path "${${prog}}")\r
                unset(prog_found CACHE)\r
                get_filename_component(${prog} "${${prog}}" NAME)\r
                find_program(prog_found ${${prog}} PATHS ENV PATH NO_DEFAULT_PATH)\r
                if(NOT path STREQUAL prog_found)\r
                    get_filename_component(path "${path}" DIRECTORY)\r
                    vcpkg_add_to_path(PREPEND ${path})\r
                endif()\r
            endif()\r
        endforeach()\r
        if (_csc_AUTOCONFIG OR _csc_USE_WRAPPERS) # without autotools we assume a custom configure script which correctly handles cl and lib. Otherwise the port needs to set CC|CXX|AR and probably CPP\r
            _vcpkg_append_to_configure_environment(CONFIGURE_ENV CPP "compile ${VCPKG_DETECTED_CMAKE_C_COMPILER} -E")\r
\r
            _vcpkg_append_to_configure_environment(CONFIGURE_ENV CC "compile ${VCPKG_DETECTED_CMAKE_C_COMPILER}")\r
            _vcpkg_append_to_configure_environment(CONFIGURE_ENV CC_FOR_BUILD "compile ${VCPKG_DETECTED_CMAKE_C_COMPILER}")\r
            _vcpkg_append_to_configure_environment(CONFIGURE_ENV CXX "compile ${VCPKG_DETECTED_CMAKE_CXX_COMPILER}")\r
            _vcpkg_append_to_configure_environment(CONFIGURE_ENV RC "windres-rc ${VCPKG_DETECTED_CMAKE_RC_COMPILER}")\r
            _vcpkg_append_to_configure_environment(CONFIGURE_ENV WINDRES "windres-rc ${VCPKG_DETECTED_CMAKE_RC_COMPILER}")\r
            if(VCPKG_DETECTED_CMAKE_AR)\r
                _vcpkg_append_to_configure_environment(CONFIGURE_ENV AR "ar-lib ${VCPKG_DETECTED_CMAKE_AR}")\r
            else()\r
                _vcpkg_append_to_configure_environment(CONFIGURE_ENV AR "ar-lib lib.exe -verbose")\r
            endif()\r
        else()\r
            _vcpkg_append_to_configure_environment(CONFIGURE_ENV CPP "${VCPKG_DETECTED_CMAKE_C_COMPILER} -E")\r
            _vcpkg_append_to_configure_environment(CONFIGURE_ENV CC "${VCPKG_DETECTED_CMAKE_C_COMPILER}")\r
            _vcpkg_append_to_configure_environment(CONFIGURE_ENV CC_FOR_BUILD "${VCPKG_DETECTED_CMAKE_C_COMPILER}")\r
            _vcpkg_append_to_configure_environment(CONFIGURE_ENV CXX "${VCPKG_DETECTED_CMAKE_CXX_COMPILER}")\r
            if(VCPKG_DETECTED_CMAKE_AR)\r
                _vcpkg_append_to_configure_environment(CONFIGURE_ENV AR "${VCPKG_DETECTED_CMAKE_AR}")\r
            else()\r
                _vcpkg_append_to_configure_environment(CONFIGURE_ENV AR "lib.exe -verbose")\r
            endif()\r
        endif()\r
        _vcpkg_append_to_configure_environment(CONFIGURE_ENV LD "${VCPKG_DETECTED_CMAKE_LINKER} -verbose")\r
        if(VCPKG_DETECTED_CMAKE_RANLIB)\r
            _vcpkg_append_to_configure_environment(CONFIGURE_ENV RANLIB "${VCPKG_DETECTED_CMAKE_RANLIB}") # Trick to ignore the RANLIB call\r
        else()\r
            _vcpkg_append_to_configure_environment(CONFIGURE_ENV RANLIB ":")\r
        endif()\r
        if(VCPKG_DETECTED_CMAKE_OBJDUMP) #Objdump is required to make shared libraries. Otherwise define lt_cv_deplibs_check_method=pass_all\r
            _vcpkg_append_to_configure_environment(CONFIGURE_ENV OBJDUMP "${VCPKG_DETECTED_CMAKE_OBJDUMP}") # Trick to ignore the RANLIB call\r
        endif()\r
        if(VCPKG_DETECTED_CMAKE_STRIP) # If required set the ENV variable STRIP in the portfile correctly\r
            _vcpkg_append_to_configure_environment(CONFIGURE_ENV STRIP "${VCPKG_DETECTED_CMAKE_STRIP}") \r
        else()\r
            _vcpkg_append_to_configure_environment(CONFIGURE_ENV STRIP ":")\r
            list(APPEND _csc_OPTIONS ac_cv_prog_ac_ct_STRIP=:)\r
        endif()\r
        if(VCPKG_DETECTED_CMAKE_NM) # If required set the ENV variable NM in the portfile correctly\r
            _vcpkg_append_to_configure_environment(CONFIGURE_ENV NM "${VCPKG_DETECTED_CMAKE_NM}") \r
        else()\r
            # Would be better to have a true nm here! Some symbols (mainly exported variables) get not properly imported with dumpbin as nm \r
            # and require __declspec(dllimport) for some reason (same problem CMake has with WINDOWS_EXPORT_ALL_SYMBOLS)\r
            _vcpkg_append_to_configure_environment(CONFIGURE_ENV NM "dumpbin.exe -symbols -headers")\r
        endif()\r
        if(VCPKG_DETECTED_CMAKE_DLLTOOL) # If required set the ENV variable DLLTOOL in the portfile correctly\r
            _vcpkg_append_to_configure_environment(CONFIGURE_ENV DLLTOOL "${VCPKG_DETECTED_CMAKE_DLLTOOL}") \r
        else()\r
            _vcpkg_append_to_configure_environment(CONFIGURE_ENV DLLTOOL "link.exe -verbose -dll")\r
        endif()\r
        _vcpkg_append_to_configure_environment(CONFIGURE_ENV CCAS ":")   # If required set the ENV variable CCAS in the portfile correctly\r
        _vcpkg_append_to_configure_environment(CONFIGURE_ENV AS ":")   # If required set the ENV variable AS in the portfile correctly\r
\r
        foreach(_env IN LISTS _csc_CONFIGURE_ENVIRONMENT_VARIABLES)\r
            _vcpkg_append_to_configure_environment(CONFIGURE_ENV ${_env} "${${_env}}")\r
        endforeach()\r
        debug_message("CONFIGURE_ENV: '${CONFIGURE_ENV}'")\r
        # Other maybe interesting variables to control\r
        # COMPILE This is the command used to actually compile a C source file. The file name is appended to form the complete command line. \r
        # LINK This is the command used to actually link a C program.\r
        # CXXCOMPILE The command used to actually compile a C++ source file. The file name is appended to form the complete command line. \r
        # CXXLINK  The command used to actually link a C++ program. \r
\r
        # Variables not correctly detected by configure. In release builds.\r
        list(APPEND _csc_OPTIONS gl_cv_double_slash_root=yes\r
                                 ac_cv_func_memmove=yes)\r
        #list(APPEND _csc_OPTIONS lt_cv_deplibs_check_method=pass_all) # Just ignore libtool checks \r
        if(VCPKG_TARGET_ARCHITECTURE MATCHES "^[Aa][Rr][Mm]64$")\r
            list(APPEND _csc_OPTIONS gl_cv_host_cpu_c_abi=no)\r
            # Currently needed for arm64 because objdump yields: "unrecognised machine type (0xaa64) in Import Library Format archive"\r
            list(APPEND _csc_OPTIONS lt_cv_deplibs_check_method=pass_all)\r
        elseif(VCPKG_TARGET_ARCHITECTURE MATCHES "^[Aa][Rr][Mm]$")\r
            # Currently needed for arm because objdump yields: "unrecognised machine type (0x1c4) in Import Library Format archive"\r
            list(APPEND _csc_OPTIONS lt_cv_deplibs_check_method=pass_all)\r
        endif()\r
    endif()\r
\r
    if(CMAKE_HOST_WIN32)\r
        #Some PATH handling for dealing with spaces....some tools will still fail with that!\r
        string(REPLACE " " "\\\ " _VCPKG_PREFIX ${CURRENT_INSTALLED_DIR})\r
        string(REGEX REPLACE "([a-zA-Z]):/" "/\\1/" _VCPKG_PREFIX "${_VCPKG_PREFIX}")\r
        set(_VCPKG_INSTALLED ${CURRENT_INSTALLED_DIR})\r
        set(prefix_var "'\${prefix}'") # Windows needs extra quotes or else the variable gets expanded in the makefile!\r
    else()\r
        string(REPLACE " " "\ " _VCPKG_PREFIX ${CURRENT_INSTALLED_DIR})\r
        string(REPLACE " " "\ " _VCPKG_INSTALLED ${CURRENT_INSTALLED_DIR})\r
        set(EXTRA_QUOTES)\r
        set(prefix_var "\${prefix}")\r
    endif()\r
\r
    # macOS - cross-compiling support\r
    if(VCPKG_TARGET_IS_OSX)\r
        if (_csc_AUTOCONFIG AND NOT _csc_BUILD_TRIPLET OR _csc_DETERMINE_BUILD_TRIPLET)\r
            _vcpkg_determine_autotools_host_arch_mac(BUILD_ARCH) # machine you are building on => --build=\r
            _vcpkg_determine_autotools_target_arch_mac(TARGET_ARCH)\r
            # --build: the machine you are building on\r
            # --host: the machine you are building for\r
            # --target: the machine that CC will produce binaries for\r
            # https://stackoverflow.com/questions/21990021/how-to-determine-host-value-for-configure-when-using-cross-compiler\r
            # Only for ports using autotools so we can assume that they follow the common conventions for build/target/host\r
            if(NOT "${TARGET_ARCH}" STREQUAL "${BUILD_ARCH}") # we don't need to specify the additional flags if we build natively.\r
                set(_csc_BUILD_TRIPLET "--host=${TARGET_ARCH}-apple-darwin") # (Host activates crosscompilation; The name given here is just the prefix of the host tools for the target)\r
            endif()\r
            debug_message("Using make triplet: ${_csc_BUILD_TRIPLET}")\r
        endif()\r
    endif()\r
\r
    # Cleanup previous build dirs\r
    file(REMOVE_RECURSE "${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-rel"\r
                        "${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-dbg"\r
                        "${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}")\r
\r
    # Set configure paths\r
    set(_csc_OPTIONS_RELEASE ${_csc_OPTIONS_RELEASE} "--prefix=${EXTRA_QUOTES}${_VCPKG_PREFIX}${EXTRA_QUOTES}")\r
    set(_csc_OPTIONS_DEBUG ${_csc_OPTIONS_DEBUG} "--prefix=${EXTRA_QUOTES}${_VCPKG_PREFIX}/debug${EXTRA_QUOTES}")\r
    if(NOT _csc_NO_ADDITIONAL_PATHS)\r
        set(_csc_OPTIONS_RELEASE ${_csc_OPTIONS_RELEASE}\r
                            # Important: These should all be relative to prefix!\r
                            "--bindir=${prefix_var}/tools/${PORT}/bin"\r
                            "--sbindir=${prefix_var}/tools/${PORT}/sbin"\r
                            #"--libdir='\${prefix}'/lib" # already the default!\r
                            #"--includedir='\${prefix}'/include" # already the default!\r
                            "--mandir=${prefix_var}/share/${PORT}"\r
                            "--docdir=${prefix_var}/share/${PORT}"\r
                            "--datarootdir=${prefix_var}/share/${PORT}")\r
        set(_csc_OPTIONS_DEBUG ${_csc_OPTIONS_DEBUG}\r
                            # Important: These should all be relative to prefix!\r
                            "--bindir=${prefix_var}/../tools/${PORT}/debug/bin"\r
                            "--sbindir=${prefix_var}/../tools/${PORT}/debug/sbin"\r
                            #"--libdir='\${prefix}'/lib" # already the default!\r
                            "--includedir=${prefix_var}/../include"\r
                            "--datarootdir=${prefix_var}/share/${PORT}")\r
    endif()\r
    # Setup common options\r
    if(NOT DISABLE_VERBOSE_FLAGS)\r
        list(APPEND _csc_OPTIONS --disable-silent-rules --verbose)\r
    endif()\r
\r
    if(VCPKG_LIBRARY_LINKAGE STREQUAL dynamic)\r
        list(APPEND _csc_OPTIONS --enable-shared --disable-static)\r
    else()\r
        list(APPEND _csc_OPTIONS --disable-shared --enable-static)\r
    endif()\r
\r
    file(RELATIVE_PATH RELATIVE_BUILD_PATH "${CURRENT_BUILDTREES_DIR}" "${_csc_SOURCE_PATH}/${_csc_PROJECT_SUBPATH}")\r
\r
    set(base_cmd)\r
    if(CMAKE_HOST_WIN32)\r
        set(base_cmd ${BASH} --noprofile --norc --debug)\r
    else()\r
        find_program(base_cmd bash REQUIRED)\r
    endif()\r
    if(VCPKG_TARGET_IS_WINDOWS)\r
        list(JOIN _csc_OPTIONS " " _csc_OPTIONS)\r
        list(JOIN _csc_OPTIONS_RELEASE " " _csc_OPTIONS_RELEASE)\r
        list(JOIN _csc_OPTIONS_DEBUG " " _csc_OPTIONS_DEBUG)\r
    endif()\r
    \r
    # Setup include environment (since these are buildtype independent restoring them is unnecessary)\r
    # Used by CL \r
    set(ENV{INCLUDE} "${_VCPKG_INSTALLED}/include${VCPKG_HOST_PATH_SEPARATOR}${INCLUDE_BACKUP}")\r
    # Used by GCC\r
    set(ENV{C_INCLUDE_PATH} "${_VCPKG_INSTALLED}/include${VCPKG_HOST_PATH_SEPARATOR}${C_INCLUDE_PATH_BACKUP}")\r
    set(ENV{CPLUS_INCLUDE_PATH} "${_VCPKG_INSTALLED}/include${VCPKG_HOST_PATH_SEPARATOR}${CPLUS_INCLUDE_PATH_BACKUP}")\r
\r
    # Flags should be set in the toolchain instead (Setting this up correctly requires a function named vcpkg_determined_cmake_compiler_flags which can also be used to setup CC and CXX etc.)\r
    if(VCPKG_TARGET_IS_WINDOWS)\r
        _vcpkg_backup_env_variables(_CL_ _LINK_)\r
        # TODO: Should be CPP flags instead -> rewrite when vcpkg_determined_cmake_compiler_flags defined\r
        if(VCPKG_TARGET_IS_UWP)\r
            # Be aware that configure thinks it is crosscompiling due to: \r
            # error while loading shared libraries: VCRUNTIME140D_APP.dll: \r
            # cannot open shared object file: No such file or directory\r
            # IMPORTANT: The only way to pass linker flags through libtool AND the compile wrapper \r
            # is to use the CL and LINK environment variables !!!\r
            # (This is due to libtool and compiler wrapper using the same set of options to pass those variables around)\r
            string(REPLACE "\\" "/" VCToolsInstallDir "$ENV{VCToolsInstallDir}")\r
            # Can somebody please check if CMake's compiler flags for UWP are correct?\r
            set(ENV{_CL_} "$ENV{_CL_} /D_UNICODE /DUNICODE /DWINAPI_FAMILY=WINAPI_FAMILY_APP /D__WRL_NO_DEFAULT_LIB_ -FU\"${VCToolsInstallDir}/lib/x86/store/references/platform.winmd\"")\r
            string(APPEND VCPKG_DETECTED_CMAKE_CXX_FLAGS_RELEASE " -ZW:nostdlib")\r
            string(APPEND VCPKG_DETECTED_CMAKE_CXX_FLAGS_DEBUG " -ZW:nostdlib")\r
            set(ENV{_LINK_} "$ENV{_LINK_} ${VCPKG_DETECTED_CMAKE_C_STANDARD_LIBRARIES} ${VCPKG_DETECTED_CMAKE_CXX_STANDARD_LIBRARIES} /MANIFEST /DYNAMICBASE /WINMD:NO /APPCONTAINER") \r
        endif()\r
    endif()\r
\r
    macro(convert_to_list input output)\r
        string(REGEX MATCHALL "(( +|^ *)[^ ]+)" ${output} "${${input}}")\r
    endmacro()\r
    convert_to_list(VCPKG_DETECTED_CMAKE_C_STANDARD_LIBRARIES C_LIBS_LIST)\r
    convert_to_list(VCPKG_DETECTED_CMAKE_CXX_STANDARD_LIBRARIES CXX_LIBS_LIST)\r
    set(ALL_LIBS_LIST ${C_LIBS_LIST} ${CXX_LIBS_LIST})\r
    list(REMOVE_DUPLICATES ALL_LIBS_LIST)\r
    list(TRANSFORM ALL_LIBS_LIST STRIP)\r
    #Do lib list transformation from name.lib to -lname if necessary\r
    set(_VCPKG_TRANSFORM_LIBS TRUE)\r
    if(VCPKG_TARGET_IS_UWP)\r
        set(_VCPKG_TRANSFORM_LIBS FALSE)\r
        # Avoid libtool choke: "Warning: linker path does not have real file for library -lWindowsApp."\r
        # The problem with the choke is that libtool always falls back to built a static library even if a dynamic was requested. \r
        # Note: Env LIBPATH;LIB are on the search path for libtool by default on windows. \r
        # It even does unix/dos-short/unix transformation with the path to get rid of spaces. \r
    endif()\r
    set(_lprefix)\r
    if(_VCPKG_TRANSFORM_LIBS)\r
        set(_lprefix "-l")\r
        list(TRANSFORM ALL_LIBS_LIST REPLACE "(.dll.lib|.lib|.a|.so)$" "")\r
        if(VCPKG_TARGET_IS_WINDOWS)\r
            list(REMOVE_ITEM ALL_LIBS_LIST "uuid")\r
        endif()\r
        list(TRANSFORM ALL_LIBS_LIST REPLACE "^(${_lprefix})" "")\r
    endif()\r
    list(JOIN ALL_LIBS_LIST " ${_lprefix}" ALL_LIBS_STRING)\r
\r
    if(ALL_LIBS_STRING)\r
        set(ALL_LIBS_STRING "${_lprefix}${ALL_LIBS_STRING}")\r
        if(DEFINED ENV{LIBS})\r
            set(ENV{LIBS} "$ENV{LIBS} ${ALL_LIBS_STRING}")\r
        else()\r
            set(ENV{LIBS} "${ALL_LIBS_STRING}")\r
        endif()\r
    endif()\r
    debug_message(STATUS "ENV{LIBS}:$ENV{LIBS}")\r
    vcpkg_find_acquire_program(PKGCONFIG)\r
    if(VCPKG_LIBRARY_LINKAGE STREQUAL "static" AND NOT PKGCONFIG STREQUAL "--static")\r
        set(PKGCONFIG "${PKGCONFIG} --static") # Is this still required or was the PR changing the pc files accordingly merged?\r
    endif()\r
\r
    # Run autoconf if necessary\r
    set(_GENERATED_CONFIGURE FALSE)\r
    if (_csc_AUTOCONFIG OR REQUIRES_AUTOCONFIG)\r
        find_program(AUTORECONF autoreconf)\r
        if(NOT AUTORECONF)\r
            message(FATAL_ERROR "${PORT} requires autoconf from the system package manager (example: \"sudo apt-get install autoconf\")")\r
        endif()\r
        message(STATUS "Generating configure for ${TARGET_TRIPLET}")\r
        if (CMAKE_HOST_WIN32)\r
            vcpkg_execute_required_process(\r
                COMMAND ${base_cmd} -c "autoreconf -vfi"\r
                WORKING_DIRECTORY "${SRC_DIR}"\r
                LOGNAME autoconf-${TARGET_TRIPLET}\r
            )\r
        else()\r
            vcpkg_execute_required_process(\r
                COMMAND ${AUTORECONF} -vfi\r
                WORKING_DIRECTORY "${SRC_DIR}"\r
                LOGNAME autoconf-${TARGET_TRIPLET}\r
            )\r
        endif()\r
        message(STATUS "Finished generating configure for ${TARGET_TRIPLET}")\r
    endif()\r
    if(REQUIRES_AUTOGEN)\r
        message(STATUS "Generating configure for ${TARGET_TRIPLET} via autogen.sh")\r
        if (CMAKE_HOST_WIN32)\r
            vcpkg_execute_required_process(\r
                COMMAND ${base_cmd} -c "./autogen.sh"\r
                WORKING_DIRECTORY "${SRC_DIR}"\r
                LOGNAME autoconf-${TARGET_TRIPLET}\r
            )\r
        else()\r
            vcpkg_execute_required_process(\r
                COMMAND "./autogen.sh"\r
                WORKING_DIRECTORY "${SRC_DIR}"\r
                LOGNAME autoconf-${TARGET_TRIPLET}\r
            )\r
        endif()\r
        message(STATUS "Finished generating configure for ${TARGET_TRIPLET}")\r
    endif()\r
\r
    if (_csc_PRERUN_SHELL)\r
        message(STATUS "Prerun shell with ${TARGET_TRIPLET}")\r
        vcpkg_execute_required_process(\r
            COMMAND ${base_cmd} -c "${_csc_PRERUN_SHELL}"\r
            WORKING_DIRECTORY "${SRC_DIR}"\r
            LOGNAME prerun-${TARGET_TRIPLET}\r
        )\r
    endif()\r
\r
    if(NOT DEFINED VCPKG_BUILD_TYPE OR VCPKG_BUILD_TYPE STREQUAL "debug" AND NOT _csc_NO_DEBUG)\r
        set(_VAR_SUFFIX DEBUG)\r
        set(PATH_SUFFIX_${_VAR_SUFFIX} "/debug")\r
        set(SHORT_NAME_${_VAR_SUFFIX} "dbg")\r
        list(APPEND _buildtypes ${_VAR_SUFFIX})\r
        if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")\r
            set(LINKER_FLAGS_${_VAR_SUFFIX} "${VCPKG_DETECTED_CMAKE_STATIC_LINKERFLAGS_${_VAR_SUFFIX}}")\r
        else() # dynamic\r
            set(LINKER_FLAGS_${_VAR_SUFFIX} "${VCPKG_DETECTED_CMAKE_SHARED_LINKERFLAGS_${_VAR_SUFFIX}}")\r
        endif()\r
        _vcpkg_extract_cpp_flags_and_set_cflags_and_cxxflags(${_VAR_SUFFIX})\r
        if (CMAKE_HOST_WIN32 AND VCPKG_DETECTED_CMAKE_C_COMPILER MATCHES "cl.exe")\r
            if(NOT _vcm_paths_with_spaces)\r
                set(LDFLAGS_${_VAR_SUFFIX} "-L${_VCPKG_INSTALLED}${PATH_SUFFIX_${_VAR_SUFFIX}}/lib -L${_VCPKG_INSTALLED}${PATH_SUFFIX_${_VAR_SUFFIX}}/lib/manual-link")\r
            endif()\r
            if(DEFINED ENV{_LINK_})\r
                set(LINK_ENV_${_VAR_SUFFIX} "$ENV{_LINK_} ${LINKER_FLAGS_${_VAR_SUFFIX}}")\r
            else()\r
                set(LINK_ENV_${_VAR_SUFFIX} "${LINKER_FLAGS_${_VAR_SUFFIX}}")\r
            endif()\r
        else()\r
            set(_link_dirs)\r
            if(EXISTS "${_VCPKG_INSTALLED}${PATH_SUFFIX_${_VAR_SUFFIX}}/lib")\r
                set(_link_dirs "-L${_VCPKG_INSTALLED}${PATH_SUFFIX_${_VAR_SUFFIX}}/lib")\r
            endif()\r
            if(EXISTS "{_VCPKG_INSTALLED}${PATH_SUFFIX_${_VAR_SUFFIX}}/lib/manual-link")\r
                set(_link_dirs "${_link_dirs} -L${_VCPKG_INSTALLED}${PATH_SUFFIX_${_VAR_SUFFIX}}/lib/manual-link")\r
            endif()\r
            string(STRIP "${_link_dirs}" _link_dirs)\r
            set(LDFLAGS_${_VAR_SUFFIX} "${_link_dirs} ${LINKER_FLAGS_${_VAR_SUFFIX}}")\r
        endif()\r
        unset(_VAR_SUFFIX)\r
    endif()\r
    if(NOT DEFINED VCPKG_BUILD_TYPE OR VCPKG_BUILD_TYPE STREQUAL "release")\r
        set(_VAR_SUFFIX RELEASE)\r
        set(PATH_SUFFIX_${_VAR_SUFFIX} "")\r
        set(SHORT_NAME_${_VAR_SUFFIX} "rel")\r
        list(APPEND _buildtypes ${_VAR_SUFFIX})\r
        if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")\r
            set(LINKER_FLAGS_${_VAR_SUFFIX} "${VCPKG_DETECTED_CMAKE_STATIC_LINKERFLAGS_${_VAR_SUFFIX}}")\r
        else() # dynamic\r
            set(LINKER_FLAGS_${_VAR_SUFFIX} "${VCPKG_DETECTED_CMAKE_SHARED_LINKERFLAGS_${_VAR_SUFFIX}}")\r
        endif()\r
        _vcpkg_extract_cpp_flags_and_set_cflags_and_cxxflags(${_VAR_SUFFIX})\r
        if (CMAKE_HOST_WIN32 AND VCPKG_DETECTED_CMAKE_C_COMPILER MATCHES "cl.exe")\r
            if(NOT _vcm_paths_with_spaces)\r
                set(LDFLAGS_${_VAR_SUFFIX} "-L${_VCPKG_INSTALLED}${PATH_SUFFIX_${_VAR_SUFFIX}}/lib -L${_VCPKG_INSTALLED}${PATH_SUFFIX_${_VAR_SUFFIX}}/lib/manual-link")\r
            endif()\r
            if(DEFINED ENV{_LINK_})\r
                set(LINK_ENV_${_VAR_SUFFIX} "$ENV{_LINK_} ${LINKER_FLAGS_${_VAR_SUFFIX}}")\r
            else()\r
                set(LINK_ENV_${_VAR_SUFFIX} "${LINKER_FLAGS_${_VAR_SUFFIX}}")\r
            endif()\r
        else()\r
            set(_link_dirs)\r
            if(EXISTS "${_VCPKG_INSTALLED}${PATH_SUFFIX_${_VAR_SUFFIX}}/lib")\r
                set(_link_dirs "-L${_VCPKG_INSTALLED}${PATH_SUFFIX_${_VAR_SUFFIX}}/lib")\r
            endif()\r
            if(EXISTS "{_VCPKG_INSTALLED}${PATH_SUFFIX_${_VAR_SUFFIX}}/lib/manual-link")\r
                set(_link_dirs "${_link_dirs} -L${_VCPKG_INSTALLED}${PATH_SUFFIX_${_VAR_SUFFIX}}/lib/manual-link")\r
            endif()\r
            string(STRIP "${_link_dirs}" _link_dirs)\r
            set(LDFLAGS_${_VAR_SUFFIX} "${_link_dirs} ${LINKER_FLAGS_${_VAR_SUFFIX}}")\r
        endif()\r
        unset(_VAR_SUFFIX)\r
    endif()\r
\r
    foreach(_buildtype IN LISTS _buildtypes)\r
        foreach(ENV_VAR ${_csc_CONFIG_DEPENDENT_ENVIRONMENT})\r
            if(DEFINED ENV{${ENV_VAR}})\r
                set(BACKUP_CONFIG_${ENV_VAR} "$ENV{${ENV_VAR}}")\r
            endif()\r
            set(ENV{${ENV_VAR}} "${${ENV_VAR}_${_buildtype}}")\r
        endforeach()\r
\r
        set(TAR_DIR "${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-${SHORT_NAME_${_buildtype}}")\r
        file(MAKE_DIRECTORY "${TAR_DIR}")\r
        file(RELATIVE_PATH RELATIVE_BUILD_PATH "${TAR_DIR}" "${SRC_DIR}")\r
\r
        if(_csc_COPY_SOURCE)\r
            file(COPY "${SRC_DIR}/" DESTINATION "${TAR_DIR}")\r
            set(RELATIVE_BUILD_PATH .)\r
        endif()\r
\r
        # Setup PKG_CONFIG_PATH\r
        set(PKGCONFIG_INSTALLED_DIR "${CURRENT_INSTALLED_DIR}${PATH_SUFFIX_${_buildtype}}/lib/pkgconfig")\r
        set(PKGCONFIG_INSTALLED_SHARE_DIR "${CURRENT_INSTALLED_DIR}/share/pkgconfig")\r
        if(ENV{PKG_CONFIG_PATH})\r
            set(BACKUP_ENV_PKG_CONFIG_PATH_${_buildtype} $ENV{PKG_CONFIG_PATH})\r
            set(ENV{PKG_CONFIG_PATH} "${PKGCONFIG_INSTALLED_DIR}${VCPKG_HOST_PATH_SEPARATOR}${PKGCONFIG_INSTALLED_SHARE_DIR}${VCPKG_HOST_PATH_SEPARATOR}$ENV{PKG_CONFIG_PATH}")\r
        else()\r
            set(ENV{PKG_CONFIG_PATH} "${PKGCONFIG_INSTALLED_DIR}${VCPKG_HOST_PATH_SEPARATOR}${PKGCONFIG_INSTALLED_SHARE_DIR}")\r
        endif()\r
\r
        # Setup environment\r
        set(ENV{CPPFLAGS} "${CPPFLAGS_${_buildtype}}")\r
        set(ENV{CFLAGS} "${CFLAGS_${_buildtype}}")\r
        set(ENV{CXXFLAGS} "${CXXFLAGS_${_buildtype}}")\r
        set(ENV{RCFLAGS} "${VCPKG_DETECTED_CMAKE_RC_FLAGS_${_buildtype}}")\r
        set(ENV{LDFLAGS} "${LDFLAGS_${_buildtype}}")\r
        if(LINK_ENV_${_VAR_SUFFIX})\r
            set(_LINK_CONFIG_BACKUP "$ENV{_LINK_}")\r
            set(ENV{_LINK_} "${LINK_ENV_${_VAR_SUFFIX}}")\r
        endif()\r
        set(ENV{PKG_CONFIG} "${PKGCONFIG} --define-variable=prefix=${_VCPKG_INSTALLED}${PATH_SUFFIX_${_buildtype}}")\r
\r
        set(_lib_env_vars LIB LIBPATH LIBRARY_PATH LD_LIBRARY_PATH)\r
        foreach(_lib_env_var IN LISTS _lib_env_vars)\r
            set(_link_path)\r
            if(EXISTS "${_VCPKG_INSTALLED}${PATH_SUFFIX_${_buildtype}}/lib")\r
                set(_link_path "${_VCPKG_INSTALLED}${PATH_SUFFIX_${_buildtype}}/lib")\r
            endif()\r
            if(EXISTS "${_VCPKG_INSTALLED}${PATH_SUFFIX_${_buildtype}}/lib/manual-link")\r
                if(_link_path)\r
                    set(_link_path "${_link_path}${VCPKG_HOST_PATH_SEPARATOR}")\r
                endif()\r
                set(_link_path "${_link_path}${_VCPKG_INSTALLED}${PATH_SUFFIX_${_buildtype}}/lib/manual-link")\r
            endif()\r
            set(ENV{${_lib_env_var}} "${_link_path}${${_lib_env_var}_PATHLIKE_CONCAT}")\r
        endforeach()\r
        unset(_link_path)\r
        unset(_lib_env_vars)\r
\r
        if(VCPKG_TARGET_IS_WINDOWS)\r
            set(command "${base_cmd}" -c "${CONFIGURE_ENV} ./${RELATIVE_BUILD_PATH}/configure ${_csc_BUILD_TRIPLET} ${_csc_OPTIONS} ${_csc_OPTIONS_${_buildtype}}")\r
        else()\r
            set(command "${base_cmd}" "./${RELATIVE_BUILD_PATH}/configure" ${_csc_BUILD_TRIPLET} ${_csc_OPTIONS} ${_csc_OPTIONS_${_buildtype}})\r
        endif()\r
        \r
        if(_csc_ADD_BIN_TO_PATH)\r
            set(PATH_BACKUP $ENV{PATH})\r
            vcpkg_add_to_path("${CURRENT_INSTALLED_DIR}${PATH_SUFFIX_${_buildtype}}/bin")\r
        endif()\r
        debug_message("Configure command:'${command}'")\r
        if (NOT _csc_SKIP_CONFIGURE)\r
            message(STATUS "Configuring ${TARGET_TRIPLET}-${SHORT_NAME_${_buildtype}}")\r
            vcpkg_execute_required_process(\r
                COMMAND ${command}\r
                WORKING_DIRECTORY "${TAR_DIR}"\r
                LOGNAME config-${TARGET_TRIPLET}-${SHORT_NAME_${_buildtype}}\r
            )\r
            if(VCPKG_TARGET_IS_WINDOWS AND NOT VCPKG_TARGET_IS_MINGW AND VCPKG_LIBRARY_LINKAGE STREQUAL dynamic)\r
                file(GLOB_RECURSE LIBTOOL_FILES "${TAR_DIR}*/libtool")\r
                foreach(lt_file IN LISTS LIBTOOL_FILES)\r
                    file(READ "${lt_file}" _contents)\r
                    string(REPLACE ".dll.lib" ".lib" _contents "${_contents}")\r
                    file(WRITE "${lt_file}" "${_contents}")\r
                endforeach()\r
            endif()\r
            \r
            if(EXISTS "${TAR_DIR}/config.log")\r
                file(RENAME "${TAR_DIR}/config.log" "${CURRENT_BUILDTREES_DIR}/config.log-${TARGET_TRIPLET}-${SHORT_NAME_${_buildtype}}.log")\r
            endif()\r
        endif()\r
\r
        if(BACKUP_ENV_PKG_CONFIG_PATH_${_buildtype})\r
            set(ENV{PKG_CONFIG_PATH} "${BACKUP_ENV_PKG_CONFIG_PATH_${_buildtype}}")\r
        else()\r
            unset(ENV{PKG_CONFIG_PATH})\r
        endif()\r
        unset(BACKUP_ENV_PKG_CONFIG_PATH_${_buildtype})\r
        \r
        if(_LINK_CONFIG_BACKUP)\r
            set(ENV{_LINK_} "${_LINK_CONFIG_BACKUP}")\r
            unset(_LINK_CONFIG_BACKUP)\r
        endif()\r
        \r
        if(_csc_ADD_BIN_TO_PATH)\r
            set(ENV{PATH} "${PATH_BACKUP}")\r
        endif()\r
        # Restore environment (config dependent)\r
        foreach(ENV_VAR ${_csc_CONFIG_DEPENDENT_ENVIRONMENT})\r
            if(BACKUP_CONFIG_${ENV_VAR})\r
                set(ENV{${ENV_VAR}} "${BACKUP_CONFIG_${ENV_VAR}}")\r
            else()\r
                unset(ENV{${ENV_VAR}})\r
            endif()\r
        endforeach()\r
    endforeach()\r
\r
    # Restore environment\r
    _vcpkg_restore_env_variables(${_cm_FLAGS} LIB LIBPATH LIBRARY_PATH LD_LIBRARY_PATH)\r
\r
    SET(_VCPKG_PROJECT_SOURCE_PATH ${_csc_SOURCE_PATH} PARENT_SCOPE)\r
    set(_VCPKG_PROJECT_SUBPATH ${_csc_PROJECT_SUBPATH} PARENT_SCOPE)\r
endfunction()\r