update ceph source to reef 18.1.2

[ceph.git] / ceph / src / jaegertracing / opentelemetry-cpp / tools / vcpkg / scripts / cmake / vcpkg_copy_tools.cmake

#[===[.md:\r
# vcpkg_copy_tools\r
\r
Copy tools and all their DLL dependencies into the `tools` folder.\r
\r
## Usage\r
```cmake\r
vcpkg_copy_tools(\r
    TOOL_NAMES <tool1>...\r
    [SEARCH_DIR <${CURRENT_PACKAGES_DIR}/bin>]\r
    [DESTINATION <${CURRENT_PACKAGES_DIR}/tools/${PORT}>]\r
    [AUTO_CLEAN]\r
)\r
```\r
## Parameters\r
### TOOL_NAMES\r
A list of tool filenames without extension.\r
\r
### SEARCH_DIR\r
The path to the directory containing the tools. This will be set to `${CURRENT_PACKAGES_DIR}/bin` if omitted.\r
\r
### DESTINATION\r
Destination to copy the tools to. This will be set to `${CURRENT_PACKAGES_DIR}/tools/${PORT}` if omitted.\r
\r
### AUTO_CLEAN\r
Auto clean executables in `${CURRENT_PACKAGES_DIR}/bin` and `${CURRENT_PACKAGES_DIR}/debug/bin`.\r
\r
## Examples\r
\r
* [cpuinfo](https://github.com/microsoft/vcpkg/blob/master/ports/cpuinfo/portfile.cmake)\r
* [nanomsg](https://github.com/microsoft/vcpkg/blob/master/ports/nanomsg/portfile.cmake)\r
* [uriparser](https://github.com/microsoft/vcpkg/blob/master/ports/uriparser/portfile.cmake)\r
#]===]\r
\r
function(vcpkg_copy_tools)\r
    # parse parameters such that semicolons in options arguments to COMMAND don't get erased\r
    cmake_parse_arguments(PARSE_ARGV 0 _vct "AUTO_CLEAN" "SEARCH_DIR;DESTINATION" "TOOL_NAMES")\r
\r
    if(NOT DEFINED _vct_TOOL_NAMES)\r
        message(FATAL_ERROR "TOOL_NAMES must be specified.")\r
    endif()\r
\r
    if(NOT DEFINED _vct_DESTINATION)\r
        set(_vct_DESTINATION "${CURRENT_PACKAGES_DIR}/tools/${PORT}")\r
    endif()\r
\r
    if(NOT DEFINED _vct_SEARCH_DIR)\r
        set(_vct_SEARCH_DIR "${CURRENT_PACKAGES_DIR}/bin")\r
    elseif(NOT IS_DIRECTORY ${_vct_SEARCH_DIR})\r
        message(FATAL_ERROR "SEARCH_DIR ${_vct_SEARCH_DIR} is supposed to be a directory.")\r
    endif()\r
\r
    foreach(tool_name IN LISTS _vct_TOOL_NAMES)\r
        set(tool_path "${_vct_SEARCH_DIR}/${tool_name}${VCPKG_TARGET_EXECUTABLE_SUFFIX}")\r
        set(tool_pdb "${_vct_SEARCH_DIR}/${tool_name}.pdb")\r
        if(EXISTS "${tool_path}")\r
            file(COPY "${tool_path}" DESTINATION "${_vct_DESTINATION}")\r
        else()\r
            message(FATAL_ERROR "Couldn't find this tool: ${tool_path}.")\r
        endif()\r
        if(EXISTS "${tool_pdb}")\r
            file(COPY "${tool_pdb}" DESTINATION "${_vct_DESTINATION}")\r
        endif()\r
    endforeach()\r
\r
    if(_vct_AUTO_CLEAN)\r
        vcpkg_clean_executables_in_bin(FILE_NAMES ${_vct_TOOL_NAMES})\r
    endif()\r
\r
    vcpkg_copy_tool_dependencies("${_vct_DESTINATION}")\r
endfunction()\r