MdePkg/BaseLib: Add Base64Encode() and Base64Decode()

[mirror_edk2.git] / edksetup.bat

@REM @file\r
@REM   Windows batch file to setup a WORKSPACE environment\r
@REM\r
@REM Copyright (c) 2006 - 2016, Intel Corporation. All rights reserved.<BR>\r
@REM (C) Copyright 2016 Hewlett Packard Enterprise Development LP<BR>\r
@REM This program and the accompanying materials\r
@REM are licensed and made available under the terms and conditions of the BSD License\r
@REM which accompanies this distribution.  The full text of the license may be found at\r
@REM http://opensource.org/licenses/bsd-license.php\r
@REM\r
@REM THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
@REM WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
@REM\r
\r
@REM set CYGWIN_HOME=C:\cygwin\r
\r
@REM usage:\r
@REM   edksetup.bat [--nt32] [AntBuild] [Rebuild] [ForceRebuild] [Reconfig]\r
@REM if the argument, skip is present, only the paths and the\r
@REM test and set of environment settings are performed.\r
\r
@REM ##############################################################\r
@REM # You should not have to modify anything below this line\r
@REM #\r
\r
@echo off\r
\r
@REM\r
@REM Set the WORKSPACE to the current working directory\r
@REM\r
pushd .\r
cd %~dp0\r
\r
if not defined WORKSPACE (\r
  goto SetWorkSpace\r
)\r
\r
if %WORKSPACE% == %CD% (\r
  @REM Workspace is not changed.\r
  goto ParseArgs\r
)\r
\r
:SetWorkSpace\r
@REM set new workspace\r
if not defined WORKSPACE (\r
  set WORKSPACE=%CD%\r
)\r
\r
:ParseArgs\r
if /I "%1"=="-h" goto Usage\r
if /I "%1"=="-help" goto Usage\r
if /I "%1"=="--help" goto Usage\r
if /I "%1"=="/h" goto Usage\r
if /I "%1"=="/?" goto Usage\r
if /I "%1"=="/help" goto Usage\r
\r
if /I "%1"=="NewBuild" shift\r
if not defined EDK_TOOLS_PATH (\r
  goto SetEdkToolsPath\r
) else (\r
  goto checkNt32Flag\r
)\r
\r
:SetEdkToolsPath\r
if %WORKSPACE:~-1% EQU \ (\r
  @set EDK_BASETOOLS=%WORKSPACE%BaseTools\r
) else (\r
  @set EDK_BASETOOLS=%WORKSPACE%\BaseTools\r
)\r
if exist %EDK_BASETOOLS% (\r
  set EDK_TOOLS_PATH=%EDK_BASETOOLS%\r
  set EDK_BASETOOLS=\r
) else (\r
  if defined PACKAGES_PATH (\r
    for %%i IN (%PACKAGES_PATH%) DO (\r
      if exist %%~fi\BaseTools (\r
        set EDK_TOOLS_PATH=%%~fi\BaseTools\r
        goto checkNt32Flag\r
      )\r
    )\r
  ) else (\r
    echo.\r
    echo !!! ERROR !!! Cannot find BaseTools !!!\r
    echo.\r
    goto BadBaseTools\r
  )\r
)\r
\r
:checkNt32Flag\r
if exist %EDK_TOOLS_PATH%\Source set BASE_TOOLS_PATH=%EDK_TOOLS_PATH%\r
\r
@REM The Nt32 Emluation Platform requires Microsoft Libraries\r
@REM and headers to interface with Windows.\r
if /I "%1"=="--nt32" (\r
  if /I "%2"=="X64" (\r
    shift\r
    call "%BASE_TOOLS_PATH%\Scripts\SetVisualStudio.bat"\r
  ) else (\r
    call "%BASE_TOOLS_PATH%\get_vsvars.bat"\r
  )\r
  shift\r
)\r
\r
:checkBaseTools\r
IF NOT EXIST "%EDK_TOOLS_PATH%\toolsetup.bat" goto BadBaseTools\r
call %EDK_TOOLS_PATH%\toolsetup.bat %*\r
if /I "%1"=="Reconfig" shift\r
goto check_NASM\r
goto check_cygwin\r
\r
:BadBaseTools\r
  @REM\r
  REM Need the BaseTools Package in order to build\r
  @REM\r
  @echo.\r
  @echo !!! ERROR !!! The BaseTools Package was not found !!!\r
  @echo.\r
  @echo Set the system environment variable, EDK_TOOLS_PATH to the BaseTools,\r
  @echo For example,\r
  @echo   set EDK_TOOLS_PATH=C:\MyTools\BaseTools\r
  @echo The setup script, toolsetup.bat must reside in this folder.\r
  @echo.\r
  goto end\r
\r
:check_NASM\r
if not defined NASM_PREFIX (\r
    @echo.\r
    @echo !!! WARNING !!! NASM_PREFIX environment variable is not set\r
    @if exist "C:\nasm\nasm.exe" @set "NASM_PREFIX=C:\nasm\"\r
    @if exist "C:\nasm\nasm.exe" @echo   Found nasm.exe, setting the environment variable to C:\nasm\\r
    @if not exist "C:\nasm\nasm.exe" echo   Attempting to build modules that require NASM will fail.\r
)\r
\r
:check_cygwin\r
if defined CYGWIN_HOME (\r
  if not exist "%CYGWIN_HOME%" (\r
    @echo.\r
    @echo !!! WARNING !!! CYGWIN_HOME not found, gcc build may not be used !!!\r
    @echo.\r
  )\r
) else (\r
  if exist c:\cygwin (\r
    set CYGWIN_HOME=c:\cygwin\r
  ) else (\r
    @echo.\r
    @echo !!! WARNING !!! No CYGWIN_HOME set, gcc build may not be used !!!\r
    @echo.\r
  )\r
)\r
\r
:cygwin_done\r
if /I "%1"=="Rebuild" shift\r
if /I "%1"=="ForceRebuild" shift\r
if "%1"=="" goto end\r
\r
:Usage\r
  @echo.\r
  @echo  Usage: "%0 [-h | -help | --help | /h | /help | /?] [--nt32 [X64]] [Reconfig] [Rebuild] [ForceRebuild]"\r
  @echo         --nt32 [X64]   If a compiler tool chain is not available in the\r
  @echo                        environment, call a script to attempt to set one up.\r
  @echo                        This flag is only required if building the\r
  @echo                        Nt32Pkg/Nt32Pkg.dsc system emulator.\r
  @echo                        If the X64 argument is set, and a compiler tool chain is\r
  @echo                        not available, attempt to set up a tool chain that will\r
  @echo                        create X64 binaries. Setting these two options have the\r
  @echo                        potential side effect of changing tool chains used for a\r
  @echo                        rebuild.\r
  @echo.\r
  @echo         Reconfig       Reinstall target.txt, tools_def.txt and build_rule.txt.\r
  @echo         Rebuild        Perform incremental rebuild of BaseTools binaries.\r
  @echo         ForceRebuild   Force a full rebuild of BaseTools binaries.\r
  @echo.\r
  @echo  Note that target.template, tools_def.template and build_rules.template\r
  @echo  will only be copied to target.txt, tools_def.txt and build_rule.txt\r
  @echo  respectively if they do not exist. Use option [Reconfig] to force the copy.\r
  @echo.\r
  goto end\r
\r
:end\r
  popd\r