]>
Commit | Line | Data |
---|---|---|
1 | //\r | |
2 | // Copyright (c) 2011-2013, ARM Limited. All rights reserved.\r | |
3 | //\r | |
4 | // This program and the accompanying materials\r | |
5 | // are licensed and made available under the terms and conditions of the BSD License\r | |
6 | // which accompanies this distribution. The full text of the license may be found at\r | |
7 | // http://opensource.org/licenses/bsd-license.php\r | |
8 | //\r | |
9 | // THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r | |
10 | // WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r | |
11 | //\r | |
12 | //\r | |
13 | \r | |
14 | #include <AsmMacroIoLib.h>\r | |
15 | #include <Base.h>\r | |
16 | #include <Library/PcdLib.h>\r | |
17 | #include <AutoGen.h>\r | |
18 | \r | |
19 | #include <Chipset/ArmV7.h>\r | |
20 | \r | |
21 | .text\r | |
22 | .align 3\r | |
23 | \r | |
24 | GCC_ASM_IMPORT(CEntryPoint)\r | |
25 | GCC_ASM_IMPORT(ArmPlatformIsPrimaryCore)\r | |
26 | GCC_ASM_IMPORT(ArmReadMpidr)\r | |
27 | GCC_ASM_IMPORT(ArmPlatformStackSet)\r | |
28 | GCC_ASM_EXPORT(_ModuleEntryPoint)\r | |
29 | \r | |
30 | StartupAddr: .word CEntryPoint\r | |
31 | \r | |
32 | \r | |
33 | ASM_PFX(_ModuleEntryPoint):\r | |
34 | // Get ID of this CPU in Multicore system\r | |
35 | bl ASM_PFX(ArmReadMpidr)\r | |
36 | // Keep a copy of the MpId register value\r | |
37 | mov r6, r0\r | |
38 | \r | |
39 | _SetSVCMode:\r | |
40 | // Enter SVC mode, Disable FIQ and IRQ\r | |
41 | mov r1, #(CPSR_MODE_SVC | CPSR_IRQ | CPSR_FIQ)\r | |
42 | msr CPSR_c, r1\r | |
43 | \r | |
44 | // Check if we can install the stack at the top of the System Memory or if we need\r | |
45 | // to install the stacks at the bottom of the Firmware Device (case the FD is located\r | |
46 | // at the top of the DRAM)\r | |
47 | _SetupStackPosition:\r | |
48 | // Compute Top of System Memory\r | |
49 | LoadConstantToReg (FixedPcdGet32(PcdSystemMemoryBase), r1)\r | |
50 | LoadConstantToReg (FixedPcdGet32(PcdSystemMemorySize), r2)\r | |
51 | sub r2, r2, #1\r | |
52 | add r1, r1, r2 // r1 = SystemMemoryTop = PcdSystemMemoryBase + PcdSystemMemorySize\r | |
53 | \r | |
54 | // Calculate Top of the Firmware Device\r | |
55 | LoadConstantToReg (FixedPcdGet32(PcdFdBaseAddress), r2)\r | |
56 | LoadConstantToReg (FixedPcdGet32(PcdFdSize), r3)\r | |
57 | sub r3, r3, #1\r | |
58 | add r3, r3, r2 // r3 = FdTop = PcdFdBaseAddress + PcdFdSize\r | |
59 | \r | |
60 | // UEFI Memory Size (stacks are allocated in this region)\r | |
61 | LoadConstantToReg (FixedPcdGet32(PcdSystemMemoryUefiRegionSize), r4)\r | |
62 | \r | |
63 | //\r | |
64 | // Reserve the memory for the UEFI region (contain stacks on its top)\r | |
65 | //\r | |
66 | \r | |
67 | // Calculate how much space there is between the top of the Firmware and the Top of the System Memory\r | |
68 | subs r0, r1, r3 // r0 = SystemMemoryTop - FdTop\r | |
69 | bmi _SetupStack // Jump if negative (FdTop > SystemMemoryTop). Case when the PrePi is in XIP memory outside of the DRAM\r | |
70 | cmp r0, r4\r | |
71 | bge _SetupStack\r | |
72 | \r | |
73 | // Case the top of stacks is the FdBaseAddress\r | |
74 | mov r1, r2\r | |
75 | \r | |
76 | _SetupStack:\r | |
77 | // r1 contains the top of the stack (and the UEFI Memory)\r | |
78 | \r | |
79 | // Because the 'push' instruction is equivalent to 'stmdb' (decrement before), we need to increment\r | |
80 | // one to the top of the stack. We check if incrementing one does not overflow (case of DRAM at the\r | |
81 | // top of the memory space)\r | |
82 | adds r7, r1, #1\r | |
83 | bcs _SetupOverflowStack\r | |
84 | \r | |
85 | _SetupAlignedStack:\r | |
86 | mov r1, r7\r | |
87 | b _GetBaseUefiMemory\r | |
88 | \r | |
89 | _SetupOverflowStack:\r | |
90 | // Case memory at the top of the address space. Ensure the top of the stack is EFI_PAGE_SIZE\r | |
91 | // aligned (4KB)\r | |
92 | LoadConstantToReg (EFI_PAGE_MASK, r7)\r | |
93 | and r7, r7, r1\r | |
94 | sub r1, r1, r7\r | |
95 | \r | |
96 | _GetBaseUefiMemory:\r | |
97 | // Calculate the Base of the UEFI Memory\r | |
98 | sub r7, r1, r4\r | |
99 | \r | |
100 | _GetStackBase:\r | |
101 | // r1 = The top of the Mpcore Stacks\r | |
102 | // Stack for the primary core = PrimaryCoreStack\r | |
103 | LoadConstantToReg (FixedPcdGet32(PcdCPUCorePrimaryStackSize), r2)\r | |
104 | sub r8, r1, r2\r | |
105 | \r | |
106 | // Stack for the secondary core = Number of Cores - 1\r | |
107 | LoadConstantToReg (FixedPcdGet32(PcdCoreCount), r0)\r | |
108 | sub r0, r0, #1\r | |
109 | LoadConstantToReg (FixedPcdGet32(PcdCPUCoreSecondaryStackSize), r1)\r | |
110 | mul r1, r1, r0\r | |
111 | sub r8, r8, r1\r | |
112 | \r | |
113 | // r8 = The base of the MpCore Stacks (primary stack & secondary stacks)\r | |
114 | mov r0, r8\r | |
115 | mov r1, r6\r | |
116 | //ArmPlatformStackSet(StackBase, MpId, PrimaryStackSize, SecondaryStackSize)\r | |
117 | LoadConstantToReg (FixedPcdGet32(PcdCPUCorePrimaryStackSize), r2)\r | |
118 | LoadConstantToReg (FixedPcdGet32(PcdCPUCoreSecondaryStackSize), r3)\r | |
119 | bl ASM_PFX(ArmPlatformStackSet)\r | |
120 | \r | |
121 | // Is it the Primary Core ?\r | |
122 | mov r0, r6\r | |
123 | bl ASM_PFX(ArmPlatformIsPrimaryCore)\r | |
124 | cmp r0, #1\r | |
125 | bne _PrepareArguments\r | |
126 | \r | |
127 | _ReserveGlobalVariable:\r | |
128 | LoadConstantToReg (FixedPcdGet32(PcdPeiGlobalVariableSize), r0)\r | |
129 | // InitializePrimaryStack($GlobalVariableSize, $Tmp1)\r | |
130 | InitializePrimaryStack(r0, r1)\r | |
131 | \r | |
132 | _PrepareArguments:\r | |
133 | mov r0, r6\r | |
134 | mov r1, r7\r | |
135 | mov r2, r8\r | |
136 | mov r3, sp\r | |
137 | \r | |
138 | // Move sec startup address into a data register\r | |
139 | // Ensure we're jumping to FV version of the code (not boot remapped alias)\r | |
140 | ldr r4, StartupAddr\r | |
141 | \r | |
142 | // Jump to PrePiCore C code\r | |
143 | // r0 = MpId\r | |
144 | // r1 = UefiMemoryBase\r | |
145 | // r2 = StacksBase\r | |
146 | // r3 = GlobalVariableBase\r | |
147 | blx r4\r | |
148 | \r | |
149 | _NeverReturn:\r | |
150 | b _NeverReturn\r | |
151 | \r |