ArmPlatformPkg/PrePi/ModuleEntryPoint.asm

   1 //
   2 //  Copyright (c) 2011-2012, ARM Limited. All rights reserved.
   3 //
   4 //  This program and the accompanying materials
   5 //  are licensed and made available under the terms and conditions of the BSD License
   6 //  which accompanies this distribution.  The full text of the license may be found at
   7 //  http://opensource.org/licenses/bsd-license.php
   8 //
   9 //  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 //  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 //
  12 //
  13
  14 #include <AsmMacroIoLib.h>
  15 #include <Base.h>
  16 #include <Library/PcdLib.h>
  17 #include <AutoGen.h>
  18
  19   INCLUDE AsmMacroIoLib.inc
  20
  21   IMPORT  CEntryPoint
  22   IMPORT  ArmReadMpidr
  23   IMPORT  ArmPlatformStackSet
  24
  25   EXPORT  _ModuleEntryPoint
  26
  27   PRESERVE8
  28   AREA    PrePiCoreEntryPoint, CODE, READONLY
  29
  30 StartupAddr        DCD      CEntryPoint
  31
  32 _ModuleEntryPoint
  33   // Get ID of this CPU in Multicore system
  34   bl    ArmReadMpidr
  35   LoadConstantToReg (FixedPcdGet32(PcdArmPrimaryCoreMask), r1)
  36   and   r6, r0, r1
  37
  38 _SetSVCMode
  39   // Enter SVC mode, Disable FIQ and IRQ
  40   //TODO: remove hardcoded values
  41   mov     r1, #0x13 :OR: 0x80 :OR: 0x40
  42   msr     CPSR_c, r1
  43
  44 // Check if we can install the stack at the top of the System Memory or if we need
  45 // to install the stacks at the bottom of the Firmware Device (case the FD is located
  46 // at the top of the DRAM)
  47 _SetupStackPosition
  48   // Compute Top of System Memory
  49   LoadConstantToReg (FixedPcdGet32(PcdSystemMemoryBase), r1)
  50   LoadConstantToReg (FixedPcdGet32(PcdSystemMemorySize), r2)
  51   sub   r2, r2, #1
  52   add   r1, r1, r2      // r1 = SystemMemoryTop = PcdSystemMemoryBase + PcdSystemMemorySize
  53
  54   // Calculate Top of the Firmware Device
  55   LoadConstantToReg (FixedPcdGet32(PcdFdBaseAddress), r2)
  56   LoadConstantToReg (FixedPcdGet32(PcdFdSize), r3)
  57   sub   r3, r3, #1
  58   add   r3, r3, r2      // r3 = FdTop = PcdFdBaseAddress + PcdFdSize
  59
  60   // UEFI Memory Size (stacks are allocated in this region)
  61   LoadConstantToReg (FixedPcdGet32(PcdSystemMemoryUefiRegionSize), r4)
  62
  63   //
  64   // Reserve the memory for the UEFI region (contain stacks on its top)
  65   //
  66
  67   // Calculate how much space there is between the top of the Firmware and the Top of the System Memory
  68   subs  r0, r1, r3      // r0 = SystemMemoryTop - FdTop
  69   bmi   _SetupStack     // Jump if negative (FdTop > SystemMemoryTop). Case when the PrePi is in XIP memory outside of the DRAM
  70   cmp   r0, r4
  71   bge   _SetupStack
  72
  73   // Case the top of stacks is the FdBaseAddress
  74   mov   r1, r2
  75
  76 _SetupStack
  77   // r1 contains the top of the stack (and the UEFI Memory)
  78
  79   // Because the 'push' instruction is equivalent to 'stmdb' (decrement before), we need to increment
  80   // one to the top of the stack. We check if incrementing one does not overflow (case of DRAM at the
  81   // top of the memory space)
  82   adds  r7, r1, #1
  83   bcs   _SetupOverflowStack
  84
  85 _SetupAlignedStack
  86   mov   r1, r7
  87   b     _GetBaseUefiMemory
  88
  89 _SetupOverflowStack
  90   // Case memory at the top of the address space. Ensure the top of the stack is EFI_PAGE_SIZE
  91   // aligned (4KB)
  92   LoadConstantToReg (EFI_PAGE_MASK, r7)
  93   and   r7, r7, r1
  94   sub   r1, r1, r7
  95
  96 _GetBaseUefiMemory
  97   // Calculate the Base of the UEFI Memory
  98   sub   r7, r1, r4
  99
 100 _GetStackBase
 101   // r1 = The top of the Mpcore Stacks
 102   // Stack for the primary core = PrimaryCoreStack
 103   LoadConstantToReg (FixedPcdGet32(PcdCPUCorePrimaryStackSize), r2)
 104   sub   r8, r1, r2
 105
 106   // Stack for the secondary core = Number of Cores - 1
 107   LoadConstantToReg (FixedPcdGet32(PcdCoreCount), r0)
 108   sub   r0, r0, #1
 109   LoadConstantToReg (FixedPcdGet32(PcdCPUCoreSecondaryStackSize), r1)
 110   mul   r1, r1, r0
 111   sub   r8, r8, r1
 112
 113   // r8 = The base of the MpCore Stacks (primary stack & secondary stacks)
 114   mov   r0, r8
 115   mov   r1, r6
 116   //ArmPlatformStackSet(StackBase, MpId, PrimaryStackSize, SecondaryStackSize)
 117   LoadConstantToReg (FixedPcdGet32(PcdCPUCorePrimaryStackSize), r2)
 118   LoadConstantToReg (FixedPcdGet32(PcdCPUCoreSecondaryStackSize), r3)
 119   bl    ArmPlatformStackSet
 120
 121   // Is it the Primary Core ?
 122   LoadConstantToReg (FixedPcdGet32(PcdArmPrimaryCore), r4)
 123   cmp   r6, r4
 124   bne   _PrepareArguments
 125
 126 _ReserveGlobalVariable
 127   LoadConstantToReg (FixedPcdGet32(PcdPeiGlobalVariableSize), r0)
 128   // InitializePrimaryStack($GlobalVariableSize, $Tmp1)
 129   InitializePrimaryStack r0, r1
 130
 131 _PrepareArguments
 132   mov   r0, r6
 133   mov   r1, r7
 134   mov   r2, r8
 135   mov   r3, sp
 136
 137   // Move sec startup address into a data register
 138   // Ensure we're jumping to FV version of the code (not boot remapped alias)
 139   ldr   r4, StartupAddr
 140
 141   // Jump to PrePiCore C code
 142   //    r0 = MpId
 143   //    r1 = UefiMemoryBase
 144   //    r2 = StacksBase
 145   //    r3 = GlobalVariableBase
 146   blx   r4
 147
 148 _NeverReturn
 149   b _NeverReturn
 150
 151   END