MdePkg/Library/BaseMemoryLibOptDxe/Arm/ScanMem.asm

   1 ; Copyright (c) 2010-2011, Linaro Limited
   2 ; All rights reserved.
   3 ; SPDX-License-Identifier: BSD-2-Clause-Patent
   4 ;
   5
   6 ;
   7 ; Written by Dave Gilbert <david.gilbert@linaro.org>
   8 ;
   9 ; This memchr routine is optimised on a Cortex-A9 and should work on
  10 ; all ARMv7 processors.   It has a fast past for short sizes, and has
  11 ; an optimised path for large data sets; the worst case is finding the
  12 ; match early in a large data set.
  13 ;
  14
  15
  16 ; 2011-02-07 david.gilbert@linaro.org
  17 ;    Extracted from local git a5b438d861
  18 ; 2011-07-14 david.gilbert@linaro.org
  19 ;    Import endianness fix from local git ea786f1b
  20 ; 2011-12-07 david.gilbert@linaro.org
  21 ;    Removed unneeded cbz from align loop
  22
  23 ; this lets us check a flag in a 00/ff byte easily in either endianness
  24 #define CHARTSTMASK(c) 1<<(c*8)
  25
  26     EXPORT  InternalMemScanMem8
  27     AREA    ScanMem, CODE, READONLY
  28     THUMB
  29
  30 InternalMemScanMem8
  31     ; r0 = start of memory to scan
  32     ; r1 = length
  33     ; r2 = character to look for
  34     ; returns r0 = pointer to character or NULL if not found
  35     uxtb    r2, r2        ; Don't think we can trust the caller to actually pass a char
  36
  37     cmp     r1, #16       ; If it's short don't bother with anything clever
  38     blt     L20
  39
  40     tst     r0, #7        ; If it's already aligned skip the next bit
  41     beq     L10
  42
  43     ; Work up to an aligned point
  44 L5
  45     ldrb    r3, [r0],#1
  46     subs    r1, r1, #1
  47     cmp     r3, r2
  48     beq     L50           ; If it matches exit found
  49     tst     r0, #7
  50     bne     L5            ; If not aligned yet then do next byte
  51
  52 L10
  53     ; At this point, we are aligned, we know we have at least 8 bytes to work with
  54     push    {r4-r7}
  55     orr     r2, r2, r2, lsl #8  ; expand the match word across to all bytes
  56     orr     r2, r2, r2, lsl #16
  57     bic     r4, r1, #7    ; Number of double words to work with
  58     mvns    r7, #0        ; all F's
  59     movs    r3, #0
  60
  61 L15
  62     ldmia   r0!, {r5,r6}
  63     subs    r4, r4, #8
  64     eor     r5, r5, r2    ; Get it so that r5,r6 have 00's where the bytes match the target
  65     eor     r6, r6, r2
  66     uadd8   r5, r5, r7    ; Parallel add 0xff - sets the GE bits for anything that wasn't 0
  67     sel     r5, r3, r7    ; bytes are 00 for none-00 bytes, or ff for 00 bytes - NOTE INVERSION
  68     uadd8   r6, r6, r7    ; Parallel add 0xff - sets the GE bits for anything that wasn't 0
  69     sel     r6, r5, r7    ; chained....bytes are 00 for none-00 bytes, or ff for 00 bytes - NOTE INVERSION
  70     cbnz    r6, L60
  71     bne     L15           ; (Flags from the subs above) If not run out of bytes then go around again
  72
  73     pop     {r4-r7}
  74     and     r2, r2, #0xff ; Get r2 back to a single character from the expansion above
  75     and     r1, r1, #7    ; Leave the count remaining as the number after the double words have been done
  76
  77 L20
  78     cbz     r1, L40       ; 0 length or hit the end already then not found
  79
  80 L21 ; Post aligned section, or just a short call
  81     ldrb    r3, [r0], #1
  82     subs    r1, r1, #1
  83     eor     r3, r3, r2    ; r3 = 0 if match - doesn't break flags from sub
  84     cbz     r3, L50
  85     bne     L21           ; on r1 flags
  86
  87 L40
  88     movs    r0, #0        ; not found
  89     bx      lr
  90
  91 L50
  92     subs    r0, r0, #1    ; found
  93     bx      lr
  94
  95 L60 ; We're here because the fast path found a hit - now we have to track down exactly which word it was
  96     ; r0 points to the start of the double word after the one that was tested
  97     ; r5 has the 00/ff pattern for the first word, r6 has the chained value
  98     cmp     r5, #0
  99     itte    eq
 100     moveq   r5, r6        ; the end is in the 2nd word
 101     subeq   r0, r0, #3    ; Points to 2nd byte of 2nd word
 102     subne   r0, r0, #7    ; or 2nd byte of 1st word
 103
 104     ; r0 currently points to the 3rd byte of the word containing the hit
 105     tst     r5, #CHARTSTMASK(0)     ; 1st character
 106     bne     L61
 107     adds    r0, r0, #1
 108     tst     r5, #CHARTSTMASK(1)     ; 2nd character
 109     ittt    eq
 110     addeq   r0, r0 ,#1
 111     tsteq   r5, #(3 << 15)          ; 2nd & 3rd character
 112     ; If not the 3rd must be the last one
 113     addeq   r0, r0, #1
 114
 115 L61
 116     pop     {r4-r7}
 117     subs    r0, r0, #1
 118     bx      lr
 119
 120     END
 121