ceph/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.5.1)
   2
   3 project(ceph CXX C ASM)
   4 set(VERSION 14.2.1)
   5
   6 if(POLICY CMP0028)
   7   cmake_policy(SET CMP0028 NEW)
   8 endif()
   9 if(POLICY CMP0046)
  10   cmake_policy(SET CMP0046 NEW)
  11 endif()
  12 if(POLICY CMP0054)
  13   cmake_policy(SET CMP0054 NEW)
  14 endif()
  15 if(POLICY CMP0056)
  16   cmake_policy(SET CMP0056 NEW)
  17 endif()
  18 if(POLICY CMP0065)
  19   cmake_policy(SET CMP0065 NEW)
  20 endif()
  21 if(POLICY CMP0051)
  22   cmake_policy(SET CMP0051 NEW)
  23 endif()
  24 if(POLICY CMP0075)
  25   cmake_policy(SET CMP0075 NEW)
  26 endif()
  27 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules/")
  28
  29 if(CMAKE_SYSTEM_NAME MATCHES "Linux")
  30   set(LINUX ON)
  31   FIND_PACKAGE(Threads)
  32 elseif(CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
  33   set(FREEBSD ON)
  34   FIND_PACKAGE(Threads)
  35 endif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  36
  37 if(CMAKE_CXX_COMPILER_ID STREQUAL GNU)
  38   if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 7)
  39     message(FATAL_ERROR "GCC 7+ required due to C++17 requirements")
  40   endif()
  41 endif()
  42
  43 option(WITH_CCACHE "Build with ccache.")
  44 if(WITH_CCACHE)
  45   find_program(CCACHE_FOUND ccache)
  46   if(CCACHE_FOUND)
  47     message(STATUS "Building with ccache: ${CCACHE_FOUND}, CCACHE_DIR=$ENV{CCACHE_DIR}")
  48     set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
  49     # ccache does not accelerate link (ld), but let it handle it. by passing it
  50     # along with cc to python's distutils, we are able to workaround
  51     # https://bugs.python.org/issue8027.
  52     set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ccache)
  53   else(CCACHE_FOUND)
  54     message(FATAL_ERROR "Can't find ccache. Is it installed?")
  55   endif(CCACHE_FOUND)
  56 endif(WITH_CCACHE)
  57
  58 option(WITH_MANPAGE "Build man pages." ON)
  59 if(WITH_MANPAGE)
  60   find_program(SPHINX_BUILD
  61     NAMES sphinx-build sphinx-build-3)
  62   if(NOT SPHINX_BUILD)
  63     message(FATAL_ERROR "Can't find sphinx-build.")
  64   endif(NOT SPHINX_BUILD)
  65 endif(WITH_MANPAGE)
  66
  67 include_directories(
  68   ${PROJECT_BINARY_DIR}/src/include
  69   ${PROJECT_SOURCE_DIR}/src)
  70
  71 if(OFED_PREFIX)
  72   include_directories(SYSTEM ${OFED_PREFIX}/include)
  73   link_directories(${OFED_PREFIX}/lib)
  74 endif()
  75
  76 if(FREEBSD)
  77   include_directories(SYSTEM /usr/local/include)
  78   link_directories(/usr/local/lib)
  79   list(APPEND CMAKE_REQUIRED_INCLUDES /usr/local/include)
  80 endif(FREEBSD)
  81
  82 #Check Includes
  83 include(CheckIncludeFiles)
  84 include(CheckIncludeFileCXX)
  85 include(CheckFunctionExists)
  86
  87 #put all the libs and binaries in one place
  88 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  89 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  90 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  91
  92
  93 CHECK_FUNCTION_EXISTS(fallocate CEPH_HAVE_FALLOCATE)
  94 CHECK_FUNCTION_EXISTS(posix_fadvise HAVE_POSIX_FADVISE)
  95 CHECK_FUNCTION_EXISTS(posix_fallocate HAVE_POSIX_FALLOCATE)
  96 CHECK_FUNCTION_EXISTS(syncfs HAVE_SYS_SYNCFS)
  97 CHECK_FUNCTION_EXISTS(sync_file_range HAVE_SYNC_FILE_RANGE)
  98 CHECK_FUNCTION_EXISTS(pwritev HAVE_PWRITEV)
  99 CHECK_FUNCTION_EXISTS(splice CEPH_HAVE_SPLICE)
 100 CHECK_FUNCTION_EXISTS(getgrouplist HAVE_GETGROUPLIST)
 101 if(NOT APPLE)
 102   CHECK_FUNCTION_EXISTS(fdatasync HAVE_FDATASYNC)
 103 endif()
 104 CHECK_FUNCTION_EXISTS(strerror_r HAVE_Strerror_R)
 105 CHECK_FUNCTION_EXISTS(name_to_handle_at HAVE_NAME_TO_HANDLE_AT)
 106 CHECK_FUNCTION_EXISTS(pipe2 HAVE_PIPE2)
 107 CHECK_FUNCTION_EXISTS(accept4 HAVE_ACCEPT4)
 108
 109 include(CMakePushCheckState)
 110 cmake_push_check_state(RESET)
 111 set(CMAKE_REQUIRED_LIBRARIES pthread)
 112 CHECK_FUNCTION_EXISTS(pthread_spin_init HAVE_PTHREAD_SPINLOCK)
 113 CHECK_FUNCTION_EXISTS(pthread_set_name_np HAVE_PTHREAD_SET_NAME_NP)
 114 CHECK_FUNCTION_EXISTS(pthread_get_name_np HAVE_PTHREAD_GET_NAME_NP)
 115 CHECK_FUNCTION_EXISTS(pthread_setname_np HAVE_PTHREAD_SETNAME_NP)
 116 CHECK_FUNCTION_EXISTS(pthread_getname_np HAVE_PTHREAD_GETNAME_NP)
 117 CHECK_FUNCTION_EXISTS(pthread_rwlockattr_setkind_np HAVE_PTHREAD_RWLOCKATTR_SETKIND_NP)
 118 cmake_pop_check_state()
 119
 120 CHECK_FUNCTION_EXISTS(eventfd HAVE_EVENTFD)
 121 CHECK_FUNCTION_EXISTS(getprogname HAVE_GETPROGNAME)
 122
 123 CHECK_INCLUDE_FILES("linux/types.h" HAVE_LINUX_TYPES_H)
 124 CHECK_INCLUDE_FILES("linux/version.h" HAVE_LINUX_VERSION_H)
 125 CHECK_INCLUDE_FILES("arpa/nameser_compat.h" HAVE_ARPA_NAMESER_COMPAT_H)
 126 CHECK_INCLUDE_FILES("sys/mount.h" HAVE_SYS_MOUNT_H)
 127 CHECK_INCLUDE_FILES("sys/param.h" HAVE_SYS_PARAM_H)
 128 CHECK_INCLUDE_FILES("sys/types.h" HAVE_SYS_TYPES_H)
 129 CHECK_INCLUDE_FILES("sys/vfs.h" HAVE_SYS_VFS_H)
 130 CHECK_INCLUDE_FILES("sys/prctl.h" HAVE_SYS_PRCTL_H)
 131 CHECK_INCLUDE_FILES("execinfo.h" HAVE_EXECINFO_H)
 132 if(LINUX)
 133   CHECK_INCLUDE_FILES("sched.h" HAVE_SCHED)
 134 endif(LINUX)
 135 CHECK_INCLUDE_FILES("valgrind/helgrind.h" HAVE_VALGRIND_HELGRIND_H)
 136
 137 include(CheckTypeSize)
 138 set(CMAKE_EXTRA_INCLUDE_FILES "linux/types.h")
 139 CHECK_TYPE_SIZE(__be16 __BE16)
 140 CHECK_TYPE_SIZE(__be32 __BE32)
 141 CHECK_TYPE_SIZE(__be64 __BE64)
 142 CHECK_TYPE_SIZE(__le16 __LE16)
 143 CHECK_TYPE_SIZE(__le32 __LE32)
 144 CHECK_TYPE_SIZE(__le64 __LE64)
 145 CHECK_TYPE_SIZE(__u8 __U8)
 146 CHECK_TYPE_SIZE(__u16 __U16)
 147 CHECK_TYPE_SIZE(__u32 __U32)
 148 CHECK_TYPE_SIZE(__u64 __U64)
 149 CHECK_TYPE_SIZE(__s8 __S8)
 150 CHECK_TYPE_SIZE(__s16 __S16)
 151 CHECK_TYPE_SIZE(__s32 __S32)
 152 CHECK_TYPE_SIZE(__s64 __S64)
 153 unset(CMAKE_EXTRA_INCLUDE_FILES)
 154
 155 include(CheckSymbolExists)
 156 CHECK_SYMBOL_EXISTS(res_nquery "resolv.h" HAVE_RES_NQUERY)
 157 CHECK_SYMBOL_EXISTS(F_SETPIPE_SZ "linux/fcntl.h" CEPH_HAVE_SETPIPE_SZ)
 158 CHECK_SYMBOL_EXISTS(__func__ "" HAVE_FUNC)
 159 CHECK_SYMBOL_EXISTS(__PRETTY_FUNCTION__ "" HAVE_PRETTY_FUNC)
 160 CHECK_SYMBOL_EXISTS(getentropy "unistd.h" HAVE_GETENTROPY)
 161
 162 include(CheckCXXSourceCompiles)
 163 CHECK_CXX_SOURCE_COMPILES("
 164   #include <string.h>
 165   int main() { char x = *strerror_r(0, &x, sizeof(x)); return 0; }
 166   " STRERROR_R_CHAR_P)
 167
 168 include(CheckStructHasMember)
 169 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtim.tv_nsec sys/stat.h
 170   HAVE_STAT_ST_MTIM_TV_NSEC LANGUAGE C)
 171 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtimespec.tv_nsec sys/stat.h
 172   HAVE_STAT_ST_MTIMESPEC_TV_NSEC LANGUAGE C)
 173
 174 set(CEPH_MAN_DIR "share/man" CACHE STRING "Install location for man pages (relative to prefix).")
 175
 176 option(ENABLE_SHARED "build shared libraries" ON)
 177 if(ENABLE_SHARED)
 178   set(CEPH_SHARED SHARED)
 179 else(ENABLE_SHARED)
 180   set(CEPH_SHARED STATIC)
 181 endif(ENABLE_SHARED)
 182 set(CMAKE_POSITION_INDEPENDENT_CODE ${ENABLE_SHARED})
 183
 184 option(WITH_STATIC_LIBSTDCXX "Link against libstdc++ statically" OFF)
 185 if(WITH_STATIC_LIBSTDCXX)
 186   if(CMAKE_COMPILER_IS_GNUCXX)
 187     set(static_linker_flags "-static-libstdc++ -static-libgcc")
 188     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${static_linker_flags}")
 189     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${static_linker_flags}")
 190     unset(static_linker_flags)
 191     set(GPERFTOOLS_USE_STATIC_LIBS TRUE)
 192   else()
 193     message(FATAL_ERROR "Please use GCC to enable WITH_STATIC_LIBSTDCXX")
 194   endif()
 195 endif()
 196 include(CheckCxxAtomic)
 197 if(NOT HAVE_CXX11_ATOMIC)
 198   set(CMAKE_CXX_STANDARD_LIBRARIES
 199     "${CMAKE_CXX_STANDARD_LIBRARIES} ${LIBATOMIC_LINK_FLAGS}")
 200 endif()
 201
 202 option(WITH_RDMA "Enable RDMA in async messenger" ON)
 203 if(WITH_RDMA)
 204   find_package(verbs REQUIRED)
 205   set(HAVE_VERBS ${VERBS_FOUND})
 206   find_package(rdmacm REQUIRED)
 207   set(HAVE_RDMACM ${RDMACM_FOUND})
 208   set(HAVE_RDMA TRUE)
 209 endif()
 210
 211 find_package(Backtrace)
 212
 213 if(LINUX)
 214   find_package(udev REQUIRED)
 215   set(HAVE_UDEV ${UDEV_FOUND})
 216   find_package(blkid REQUIRED)
 217   set(HAVE_BLKID ${BLKID_FOUND})
 218 elseif(FREEBSD)
 219   set(HAVE_UDEV OFF)
 220   set(HAVE_LIBAIO OFF)
 221   set(HAVE_BLKID OFF)
 222 else()
 223   set(HAVE_UDEV OFF)
 224   message(STATUS "Not using udev")
 225   set(HAVE_BLKID OFF)
 226   message(STATUS "Not using BLKID")
 227 endif(LINUX)
 228
 229 option(WITH_OPENLDAP "OPENLDAP is here" ON)
 230 if(WITH_OPENLDAP)
 231   find_package(OpenLdap REQUIRED)
 232   set(HAVE_OPENLDAP ${OPENLDAP_FOUND})
 233 endif()
 234
 235 option(WITH_GSSAPI "GSSAPI/KRB5 is here" OFF)
 236 if(WITH_GSSAPI)
 237   find_package(GSSApi REQUIRED)
 238   set(HAVE_GSSAPI ${GSSApi_FOUND})
 239 endif()
 240
 241 option(WITH_FUSE "Fuse is here" ON)
 242 if(WITH_FUSE)
 243   find_package(fuse)
 244   set(HAVE_LIBFUSE ${FUSE_FOUND})
 245 endif()
 246
 247 option(WITH_XFS "XFS is here" ON)
 248 if(WITH_XFS)
 249   find_package(xfs)
 250   set(HAVE_LIBXFS ${XFS_FOUND})
 251 endif()
 252
 253 option(WITH_ZFS "enable LibZFS if found" OFF)
 254 if(WITH_ZFS)
 255   find_package(zfs)
 256   set(HAVE_LIBZFS ${ZFS_FOUND})
 257 endif()
 258
 259 option(WITH_BLUESTORE "Bluestore OSD backend" ON)
 260 if(WITH_BLUESTORE)
 261   if(LINUX)
 262     find_package(aio)
 263     set(HAVE_LIBAIO ${AIO_FOUND})
 264   elseif(FREEBSD)
 265     # POSIX AIO is integrated into FreeBSD kernel, and exposed by libc.
 266     set(HAVE_POSIXAIO ON)
 267   endif()
 268 endif()
 269
 270 if(CMAKE_SYSTEM_PROCESSOR MATCHES "i386|i686|amd64|x86_64|AMD64|aarch64")
 271   option(WITH_SPDK "Enable SPDK" ON)
 272 else()
 273   option(WITH_SPDK "Enable SPDK" OFF)
 274 endif()
 275 if(WITH_SPDK)
 276   if(NOT WITH_BLUESTORE)
 277     message(SEND_ERROR "Please enable WITH_BLUESTORE for using SPDK")
 278   endif()
 279   include(BuildSPDK)
 280   build_spdk()
 281   set(HAVE_SPDK TRUE)
 282 endif(WITH_SPDK)
 283
 284 option(WITH_PMEM "Enable PMEM" OFF)
 285 if(WITH_PMEM)
 286   set(HAVE_PMEM ON)
 287   if(NOT WITH_BLUESTORE)
 288     message(SEND_ERROR "Please enable WITH_BLUESTORE for using PMEM")
 289   endif()
 290 endif()
 291
 292 if(WITH_BLUESTORE)
 293   if(NOT AIO_FOUND AND NOT HAVE_POSIXAIO AND NOT WITH_SPDK AND NOT WITH_PMEM)
 294     message(SEND_ERROR "WITH_BLUESTORE is ON, "
 295       "but none of the bluestore backends is enabled. "
 296       "Please install libaio, or enable WITH_SPDK or WITH_PMEM (experimental)")
 297   endif()
 298 endif()
 299
 300 option(WITH_BLUEFS "libbluefs library" OFF)
 301
 302 option(WITH_QATZIP "Enable QATZIP" OFF)
 303 if(WITH_QATZIP)
 304   find_package(qatzip REQUIRED)
 305   set(HAVE_QATZIP ${QATZIP_FOUND})
 306 endif(WITH_QATZIP)
 307
 308 # needs mds and? XXX
 309 option(WITH_LIBCEPHFS "libcephfs client library" ON)
 310
 311 # key-value store
 312 option(WITH_KVS "Key value store is here" ON)
 313
 314 # remote block storage
 315 option(WITH_RBD "Remote block storage is here" ON)
 316
 317 # KERNEL remote block storage
 318 option(WITH_KRBD "Kernel Remote block storage is here" ON)
 319
 320 if(WITH_KRBD AND WITHOUT_RBD)
 321   message(FATAL_ERROR "Cannot have WITH_KRBD with WITH_RBD.")
 322 endif()
 323
 324 option(WITH_LEVELDB "LevelDB is here" ON)
 325 if(WITH_LEVELDB)
 326   if(LEVELDB_PREFIX)
 327     include_directories(SYSTEM ${LEVELDB_PREFIX}/include)
 328     link_directories(${LEVELDB_PREFIX}/lib)
 329   endif()
 330   find_package(leveldb REQUIRED)
 331   find_file(HAVE_LEVELDB_FILTER_POLICY leveldb/filter_policy.h PATHS ${LEVELDB_INCLUDE_DIR})
 332 endif(WITH_LEVELDB)
 333
 334 find_package(snappy REQUIRED)
 335
 336 option(WITH_BROTLI "Brotli compression support" OFF)
 337 if(WITH_BROTLI)
 338   set(HAVE_BROTLI TRUE)
 339 endif()
 340
 341 option(WITH_LZ4 "LZ4 compression support" ON)
 342 if(WITH_LZ4)
 343   find_package(LZ4 1.7 REQUIRED)
 344   set(HAVE_LZ4 ${LZ4_FOUND})
 345 endif(WITH_LZ4)
 346
 347 option(WITH_CEPH_DEBUG_MUTEX "Use debug ceph::mutex with lockdep" OFF)
 348
 349 #if allocator is set on command line make sure it matches below strings
 350 set(ALLOCATOR "" CACHE STRING
 351   "specify memory allocator to use. currently tcmalloc, tcmalloc_minimal, \
 352 jemalloc, and libc is supported. if not specified, will try to find tcmalloc, \
 353 and then jemalloc. If neither of then is found. use the one in libc.")
 354 if(ALLOCATOR)
 355   if(${ALLOCATOR} MATCHES "tcmalloc(_minimal)?")
 356     find_package(gperftools REQUIRED)
 357     set(HAVE_LIBTCMALLOC ON)
 358   elseif(${ALLOCATOR} STREQUAL "jemalloc")
 359     find_package(JeMalloc REQUIRED)
 360     set(HAVE_JEMALLOC 1)
 361   elseif(NOT ALLOCATOR STREQUAL "libc")
 362     message(FATAL_ERROR "Unsupported allocator selected: ${ALLOCATOR}")
 363   endif()
 364 else(ALLOCATOR)
 365   find_package(gperftools)
 366   set(HAVE_LIBTCMALLOC ${gperftools_FOUND})
 367   if(NOT gperftools_FOUND)
 368     find_package(JeMalloc)
 369   endif()
 370   if(gperftools_FOUND)
 371     set(ALLOCATOR tcmalloc)
 372   elseif(JeMalloc_FOUND)
 373     set(ALLOCATOR jemalloc)
 374   else()
 375     if(NOT FREEBSD)
 376       # FreeBSD already has jemalloc as its default allocator
 377       message(WARNING "tcmalloc and jemalloc not found, falling back to libc")
 378     endif()
 379     set(ALLOCATOR "libc")
 380   endif(gperftools_FOUND)
 381 endif(ALLOCATOR)
 382
 383 if(HAVE_LIBTCMALLOC AND WITH_STATIC_LIBSTDCXX)
 384   set(EXE_LINKER_USE_PIE FALSE)
 385 else()
 386   set(EXE_LINKER_USE_PIE ${ENABLE_SHARED})
 387 endif()
 388
 389 if(WITH_LIBCEPHFS OR WITH_KRBD)
 390   find_package(keyutils REQUIRED)
 391 endif()
 392
 393 find_package(CURL REQUIRED)
 394 set(CMAKE_REQUIRED_INCLUDES ${CURL_INCLUDE_DIRS})
 395 set(CMAKE_REQUIRED_LIBRARIES ${CURL_LIBRARIES})
 396 CHECK_SYMBOL_EXISTS(curl_multi_wait curl/curl.h HAVE_CURL_MULTI_WAIT)
 397
 398 find_package(NSS REQUIRED)
 399 find_package(NSPR REQUIRED)
 400 find_package(OpenSSL REQUIRED)
 401 # TODO: use NSS only for validation of the OpenSSL-based implementations
 402 set(USE_NSS 1)
 403 set(USE_OPENSSL 1)
 404 set(CRYPTO_LIBS ${NSS_LIBRARIES} ${NSPR_LIBRARIES} OpenSSL::Crypto)
 405
 406 option(WITH_XIO "Enable XIO messaging" OFF)
 407 if(WITH_XIO)
 408   find_package(xio REQUIRED)
 409   set(HAVE_XIO ${XIO_FOUND})
 410 endif()
 411
 412 option(WITH_DPDK "Enable DPDK messaging" OFF)
 413 if(WITH_DPDK)
 414   find_package(dpdk)
 415   if(NOT DPDK_FOUND AND NOT TARGET dpdk-ext)
 416     include(BuildDPDK)
 417     build_dpdk(${CMAKE_BINARY_DIR}/src/dpdk)
 418   endif()
 419   set(HAVE_DPDK TRUE)
 420 endif()
 421
 422 option(WITH_BLKIN "Use blkin to emit LTTng tracepoints for Zipkin" OFF)
 423 if(WITH_BLKIN)
 424   set(BLKIN_LIBRARIES blkin ${LTTNGUST_LIBRARIES} lttng-ust-fork)
 425   include_directories(SYSTEM src/blkin/blkin-lib)
 426 endif(WITH_BLKIN)
 427
 428 option(WITH_BOOST_CONTEXT "Enable boost::asio stackful coroutines" ON)
 429 if(WITH_BOOST_CONTEXT)
 430   set(HAVE_BOOST_CONTEXT ON)
 431 endif()
 432
 433 #option for RGW
 434 option(WITH_RADOSGW "Rados Gateway is enabled" ON)
 435 option(WITH_RADOSGW_FCGI_FRONTEND "Rados Gateway's FCGI frontend is enabled" OFF)
 436 option(WITH_RADOSGW_BEAST_FRONTEND "Rados Gateway's Beast frontend is enabled" ON)
 437 option(WITH_RADOSGW_BEAST_OPENSSL "Rados Gateway's Beast frontend uses OpenSSL" ON)
 438 option(WITH_RADOSGW_AMQP_ENDPOINT "Rados Gateway's pubsub support for AMQP push endpoint" ON)
 439
 440 if(WITH_RADOSGW)
 441   find_package(EXPAT REQUIRED)
 442   if(WITH_RADOSGW_FCGI_FRONTEND)
 443     find_package(fcgi REQUIRED)
 444   endif()
 445   if(WITH_RADOSGW_BEAST_FRONTEND AND NOT WITH_BOOST_CONTEXT)
 446     message(WARNING "disabling WITH_RADOSGW_BEAST_FRONTEND, which depends on WITH_BOOST_CONTEXT")
 447     set(WITH_RADOSGW_BEAST_FRONTEND OFF)
 448   endif()
 449   find_package(OATH REQUIRED)
 450
 451 # https://curl.haxx.se/docs/install.html mentions the
 452 # configure flags for various ssl backends
 453   execute_process(
 454     COMMAND
 455   "sh" "-c"
 456   "curl-config --configure | grep with-ssl"
 457   RESULT_VARIABLE NO_CURL_SSL_LINK
 458   ERROR_VARIABLE CURL_CONFIG_ERRORS
 459   )
 460   if (CURL_CONFIG_ERRORS)
 461     message(WARNING "unable to run curl-config; rgw cannot make ssl requests to external systems reliably")
 462   endif()
 463
 464   if (WITH_RADOSGW_BEAST_FRONTEND AND WITH_RADOSGW_BEAST_OPENSSL)
 465     find_package(OpenSSL REQUIRED)
 466   else()
 467     find_package(OpenSSL)
 468   endif()
 469
 470   if (OPENSSL_FOUND)
 471     if (NOT NO_CURL_SSL_LINK)
 472       message(STATUS "libcurl is linked with openssl: explicitly setting locks")
 473       set(WITH_CURL_OPENSSL ON)
 474     endif() # CURL_SSL_LINK
 475     execute_process(
 476       COMMAND
 477         "sh" "-c"
 478         "objdump -p ${OPENSSL_SSL_LIBRARY} | sed -n 's/^  SONAME  *//p'"
 479       OUTPUT_VARIABLE LIBSSL_SONAME
 480       ERROR_VARIABLE OBJDUMP_ERRORS
 481       RESULT_VARIABLE OBJDUMP_RESULTS
 482       OUTPUT_STRIP_TRAILING_WHITESPACE)
 483     if (OBJDUMP_RESULTS)
 484       message(FATAL_ERROR "can't run objdump: ${OBJDUMP_RESULTS}")
 485     endif()
 486     if (NOT OBJDUMP_ERRORS STREQUAL "")
 487       message(WARNING "message from objdump: ${OBJDUMP_ERRORS}")
 488     endif()
 489     execute_process(
 490       COMMAND
 491         "sh" "-c"
 492         "objdump -p ${OPENSSL_CRYPTO_LIBRARY} | sed -n 's/^  SONAME  *//p'"
 493       OUTPUT_VARIABLE LIBCRYPTO_SONAME
 494       ERROR_VARIABLE OBJDUMP_ERRORS
 495       RESULT_VARIABLE OBJDUMP_RESULTS
 496       OUTPUT_STRIP_TRAILING_WHITESPACE)
 497     if (OBJDUMP_RESULTS)
 498       message(FATAL_ERROR "can't run objdump: ${OBJDUMP_RESULTS}")
 499     endif()
 500     if (NOT OBJDUMP_ERRORS STREQUAL "")
 501       message(WARNING "message from objdump: ${OBJDUMP_ERRORS}")
 502     endif()
 503     message(STATUS "ssl soname: ${LIBSSL_SONAME}")
 504     message(STATUS "crypto soname: ${LIBCRYPTO_SONAME}")
 505   else()
 506     message(WARNING "ssl not found: rgw civetweb may fail to dlopen libssl libcrypto")
 507   endif()  # OPENSSL_FOUND
 508 endif (WITH_RADOSGW)
 509
 510 #option for CephFS
 511 option(WITH_CEPHFS "CephFS is enabled" ON)
 512
 513 #option for Mgr
 514 option(WITH_MGR "ceph-mgr is enabled" ON)
 515 if(WITH_MGR)
 516   # Please specify 3 or 3.[0-7] if you want to build with python3 support.
 517   # FindPyhonInterp and FindPythonLibs think they belong to different families.
 518   set(MGR_PYTHON_VERSION "2.7" CACHE
 519     STRING "minimal required version of python runtime for running mgr plugins. ")
 520   find_package(PythonInterp ${MGR_PYTHON_VERSION} REQUIRED)
 521   find_package(PythonLibs ${MGR_PYTHON_VERSION} REQUIRED)
 522   set(MGR_PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 523   set(MGR_PYTHON_LIBRARIES ${PYTHON_LIBRARIES})
 524   set(MGR_PYTHON_VERSION_MAJOR ${PYTHON_VERSION_MAJOR})
 525   set(MGR_PYTHON_VERSION_MINOR ${PYTHON_VERSION_MINOR})
 526   # Boost dependency check deferred to Boost section
 527 endif(WITH_MGR)
 528
 529 option(WITH_THREAD_SAFE_RES_QUERY "res_query is thread safe" OFF)
 530 if(WITH_THREAD_SAFE_RES_QUERY)
 531   set(HAVE_THREAD_SAFE_RES_QUERY 1 CACHE INTERNAL "Thread safe res_query supported.")
 532 endif()
 533
 534 option(WITH_REENTRANT_STRSIGNAL "strsignal is reentrant" OFF)
 535 if(WITH_REENTRANT_STRSIGNAL)
 536   set(HAVE_REENTRANT_STRSIGNAL 1 CACHE INTERNAL "Reentrant strsignal is supported.")
 537 endif()
 538
 539 set(HAVE_LIBROCKSDB 1)
 540
 541 # -lz link into kv
 542 find_package(ZLIB REQUIRED)
 543
 544 #option for EventTrace
 545 option(WITH_EVENTTRACE "Event tracing support" OFF)
 546
 547 #option for LTTng
 548 option(WITH_LTTNG "LTTng tracing is enabled" ON)
 549 if(${WITH_LTTNG})
 550   find_package(LTTngUST REQUIRED)
 551   find_program(LTTNG_GEN_TP
 552     lttng-gen-tp)
 553   if(NOT LTTNG_GEN_TP)
 554     message(FATAL_ERROR "Can't find lttng-gen-tp.")
 555   endif()
 556 endif(${WITH_LTTNG})
 557
 558 option(WITH_OSD_INSTRUMENT_FUNCTIONS OFF)
 559
 560 #option for Babeltrace
 561 option(WITH_BABELTRACE "Babeltrace libraries are enabled" ON)
 562 if(WITH_BABELTRACE)
 563   set(HAVE_BABELTRACE ON)
 564   find_package(babeltrace REQUIRED)
 565   set(HAVE_BABELTRACE_BABELTRACE_H ${BABELTRACE_FOUND})
 566   set(HAVE_BABELTRACE_CTF_EVENTS_H ${BABELTRACE_FOUND})
 567   set(HAVE_BABELTRACE_CTF_ITERATOR_H ${BABELTRACE_FOUND})
 568 endif(WITH_BABELTRACE)
 569
 570 option(DEBUG_GATHER "C_Gather debugging is enabled" ON)
 571 option(ENABLE_COVERAGE "Coverage is enabled" OFF)
 572 option(PG_DEBUG_REFS "PG Ref debugging is enabled" OFF)
 573
 574 option(WITH_TESTS "enable the build of ceph-test package scripts/binaries" ON)
 575 set(UNIT_TESTS_BUILT ${WITH_TESTS})
 576 set(CEPH_TEST_TIMEOUT 3600 CACHE STRING
 577   "Maximum time before a CTest gets killed" )
 578
 579 # fio
 580 option(WITH_FIO "build with fio plugin enabled" OFF)
 581 option(WITH_SYSTEM_FIO "require and build with system fio" OFF)
 582 if(WITH_SYSTEM_FIO)
 583   find_package(fio REQUIRED)
 584 elseif(WITH_FIO)
 585   set(FIO_INCLUDE_DIR ${CMAKE_BINARY_DIR}/src/fio)
 586   include(BuildFIO)
 587   build_fio()
 588 endif()
 589
 590 if(LINUX)
 591   add_definitions(-D__linux__)
 592 endif(LINUX)
 593
 594 # ASAN and friends
 595 option(WITH_ASAN "build with ASAN" OFF)
 596 if(WITH_ASAN)
 597   list(APPEND sanitizers "address")
 598 endif()
 599
 600 option(WITH_ASAN_LEAK "explicitly enable ASAN leak detection" OFF)
 601 if(WITH_ASAN_LEAK)
 602   list(APPEND sanitizers "leak")
 603 endif()
 604
 605 option(WITH_TSAN "build with TSAN" OFF)
 606 if(WITH_TSAN)
 607   list(APPEND sanitizers "thread")
 608 endif()
 609
 610 option(WITH_UBSAN "build with UBSAN" OFF)
 611 if(WITH_UBSAN)
 612   list(APPEND sanitizers "undefined-behavior")
 613 endif()
 614
 615 if(sanitizers)
 616   find_package(Sanitizers REQUIRED ${sanitizers})
 617   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${Sanitizers_COMPILE_OPTIONS}")
 618   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Sanitizers_COMPILE_OPTIONS}")
 619   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${Sanitizers_COMPILE_OPTIONS}")
 620   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${Sanitizers_COMPILE_OPTIONS}")
 621 endif()
 622
 623 # Rocksdb
 624 option(WITH_SYSTEM_ROCKSDB "require and build with system rocksdb" OFF)
 625 if (WITH_SYSTEM_ROCKSDB)
 626   find_package(RocksDB 5.8 REQUIRED)
 627 endif()
 628
 629 option(WITH_SEASTAR "Build seastar components")
 630 set(HAVE_SEASTAR ${WITH_SEASTAR})
 631
 632 # Boost
 633 option(WITH_SYSTEM_BOOST "require and build with system Boost" OFF)
 634
 635 # Boost::thread depends on Boost::atomic, so list it explicitly.
 636 set(BOOST_COMPONENTS
 637   atomic chrono thread system regex random program_options date_time
 638   iostreams)
 639 set(BOOST_HEADER_COMPONENTS container)
 640
 641 if(WITH_MGR)
 642   list(APPEND BOOST_COMPONENTS
 643     python${MGR_PYTHON_VERSION_MAJOR}${MGR_PYTHON_VERSION_MINOR})
 644 endif()
 645 if(WITH_BOOST_CONTEXT)
 646   list(APPEND BOOST_COMPONENTS context coroutine)
 647 endif()
 648 if(WITH_SEASTAR)
 649   list(APPEND BOOST_COMPONENTS filesystem timer)
 650 endif()
 651
 652 set(Boost_USE_MULTITHREADED ON)
 653 # require minimally the bundled version
 654 if(WITH_SYSTEM_BOOST)
 655   if(ENABLE_SHARED)
 656     set(Boost_USE_STATIC_LIBS OFF)
 657   else()
 658     set(Boost_USE_STATIC_LIBS ON)
 659   endif()
 660   if(BOOST_ROOT AND CMAKE_LIBRARY_ARCHITECTURE)
 661     set(BOOST_LIBRARYDIR "${BOOST_ROOT}/lib/${CMAKE_LIBRARY_ARCHITECTURE}")
 662   endif()
 663   find_package(Boost 1.67 COMPONENTS ${BOOST_COMPONENTS} REQUIRED)
 664 else()
 665   set(BOOST_J 1 CACHE STRING
 666     "max jobs for Boost build") # override w/-DBOOST_J=<n>
 667   set(Boost_USE_STATIC_LIBS ON)
 668   include(BuildBoost)
 669   build_boost(1.67
 670     COMPONENTS ${BOOST_COMPONENTS} ${BOOST_HEADER_COMPONENTS})
 671 endif()
 672 include_directories(BEFORE SYSTEM ${Boost_INCLUDE_DIRS})
 673 set(Boost_USE_MULTITHREADED ON)
 674
 675 # dashboard angular2 frontend
 676 option(WITH_MGR_DASHBOARD_FRONTEND "Build the mgr/dashboard frontend using `npm`" ON)
 677 option(WITH_SYSTEM_NPM "Assume that dashboard build tools already installed through packages" OFF)
 678 if(WITH_SYSTEM_NPM)
 679   find_program(NPM npm)
 680   if(NOT NPM)
 681     message(FATAL_ERROR "Can't find npm.")
 682   endif()
 683 endif()
 684
 685 include_directories(SYSTEM ${PROJECT_BINARY_DIR}/include)
 686
 687 find_package(Threads REQUIRED)
 688
 689
 690 option(WITH_SELINUX "build SELinux policy" OFF)
 691 if(WITH_SELINUX)
 692   find_file(SELINUX_MAKEFILE selinux/devel/Makefile
 693     PATH /usr/share)
 694   if(NOT SELINUX_MAKEFILE)
 695     message(FATAL_ERROR "Can't find selinux's Makefile")
 696   endif()
 697   add_subdirectory(selinux)
 698 endif(WITH_SELINUX)
 699
 700 # enables testing and creates Make check command
 701 add_custom_target(tests
 702   COMMENT "Building tests")
 703 enable_testing()
 704 set(CMAKE_CTEST_COMMAND ctest)
 705 add_custom_target(check
 706   COMMAND ${CMAKE_CTEST_COMMAND}
 707   DEPENDS tests)
 708
 709 add_subdirectory(src)
 710
 711 add_subdirectory(doc)
 712 if(WITH_MANPAGE)
 713   add_subdirectory(man)
 714 endif(WITH_MANPAGE)
 715
 716 option(WITH_SYSTEMD "install systemd target and service files" ON)
 717 if(WITH_SYSTEMD)
 718   add_subdirectory(systemd)
 719 endif()
 720
 721 if(LINUX)
 722   add_subdirectory(etc/sysctl)
 723 endif()
 724
 725 option(WITH_GRAFANA "install grafana dashboards" OFF)
 726 if(WITH_GRAFANA)
 727   add_subdirectory(monitoring/grafana/dashboards)
 728 endif()
 729
 730 include(CTags)
 731 option(CTAG_EXCLUDES "Exclude files/directories when running ctag.")
 732 add_tags(ctags
 733   SRC_DIR src
 734   TAG_FILE tags
 735   EXCLUDE_OPTS ${CTAG_EXCLUDES}
 736   EXCLUDES "*.js" "*.css")
 737 add_custom_target(tags DEPENDS ctags)