ceph/cmake/modules/BuildArrow.cmake

   1 # apache arrow and its parquet library are used in radosgw for s3 select
   2
   3 function(build_arrow)
   4   # only enable the parquet component
   5   set(arrow_CMAKE_ARGS -DARROW_PARQUET=ON)
   6
   7   # only use preinstalled dependencies for arrow, don't fetch/build any
   8   list(APPEND arrow_CMAKE_ARGS -DARROW_DEPENDENCY_SOURCE=SYSTEM)
   9
  10   # only build static version of arrow and parquet
  11   list(APPEND arrow_CMAKE_ARGS -DARROW_BUILD_SHARED=OFF)
  12   list(APPEND arrow_CMAKE_ARGS -DARROW_BUILD_STATIC=ON)
  13
  14   # arrow only supports its own bundled version of jemalloc, so can't
  15   # share the version ceph is using
  16   list(APPEND arrow_CMAKE_ARGS -DARROW_JEMALLOC=OFF)
  17
  18   # transitive dependencies
  19   list(APPEND arrow_INTERFACE_LINK_LIBRARIES thrift)
  20
  21   if (NOT WITH_SYSTEM_UTF8PROC)
  22     # forward utf8proc_ROOT from build_utf8proc()
  23     list(APPEND arrow_CMAKE_ARGS -Dutf8proc_ROOT=${utf8proc_ROOT})
  24     # non-system utf8proc is bundled as a static library
  25     list(APPEND arrow_CMAKE_ARGS -DARROW_UTF8PROC_USE_SHARED=OFF)
  26     # make sure utf8proc submodule builds first, so arrow can find its byproducts
  27     list(APPEND arrow_DEPENDS utf8proc::utf8proc)
  28   endif()
  29
  30   list(APPEND arrow_CMAKE_ARGS -DARROW_WITH_BROTLI=${HAVE_BROTLI})
  31   if (HAVE_BROTLI) # optional, off by default
  32     list(APPEND arrow_INTERFACE_LINK_LIBRARIES ${brotli_libs})
  33   endif (HAVE_BROTLI)
  34
  35   list(APPEND arrow_CMAKE_ARGS -DARROW_WITH_BZ2=OFF)
  36
  37   list(APPEND arrow_CMAKE_ARGS -DARROW_WITH_LZ4=${HAVE_LZ4})
  38   if (HAVE_LZ4) # optional, on by default
  39     list(APPEND arrow_INTERFACE_LINK_LIBRARIES LZ4::LZ4)
  40   endif (HAVE_LZ4)
  41
  42   list(APPEND arrow_CMAKE_ARGS -DARROW_WITH_SNAPPY=ON) # required
  43   list(APPEND arrow_INTERFACE_LINK_LIBRARIES snappy::snappy)
  44
  45   list(APPEND arrow_CMAKE_ARGS -DARROW_WITH_ZLIB=ON) # required
  46   list(APPEND arrow_INTERFACE_LINK_LIBRARIES ZLIB::ZLIB)
  47
  48   list(APPEND arrow_CMAKE_ARGS -DARROW_WITH_ZSTD=${WITH_SYSTEM_ZSTD})
  49   if (WITH_SYSTEM_ZSTD)
  50     find_package(Zstd 1.4.4 REQUIRED)
  51     list(APPEND arrow_INTERFACE_LINK_LIBRARIES Zstd::Zstd)
  52   endif (WITH_SYSTEM_ZSTD)
  53
  54   list(APPEND arrow_CMAKE_ARGS -DBOOST_ROOT=${BOOST_ROOT})
  55   list(APPEND arrow_CMAKE_ARGS -DBOOST_INCLUDEDIR=${Boost_INCLUDE_DIR})
  56   list(APPEND arrow_CMAKE_ARGS -DBOOST_LIBRARYDIR=${BOOST_LIBRARYDIR})
  57
  58   if (NOT WITH_SYSTEM_BOOST)
  59     # make sure boost submodule builds first, so arrow can find its byproducts
  60     list(APPEND arrow_DEPENDS Boost)
  61   endif()
  62
  63   # cmake doesn't properly handle arguments containing ";", such as
  64   # CMAKE_PREFIX_PATH, for which reason we'll have to use some other separator.
  65   string(REPLACE ";" "!" CMAKE_PREFIX_PATH_ALT_SEP "${CMAKE_PREFIX_PATH}")
  66   list(APPEND arrow_CMAKE_ARGS -DCMAKE_PREFIX_PATH=${CMAKE_PREFIX_PATH_ALT_SEP})
  67   if(CMAKE_TOOLCHAIN_FILE)
  68     list(APPEND arrow_CMAKE_ARGS
  69          -DCMAKE_TOOLCHAIN_FILE=${CMAKE_TOOLCHAIN_FILE})
  70   endif()
  71
  72   list(APPEND arrow_CMAKE_ARGS -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER})
  73   list(APPEND arrow_CMAKE_ARGS -DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER})
  74   list(APPEND arrow_CMAKE_ARGS -DCMAKE_AR=${CMAKE_AR})
  75   if(CMAKE_BUILD_TYPE AND NOT CMAKE_BUILD_TYPE STREQUAL "None")
  76     list(APPEND arrow_CMAKE_ARGS -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE})
  77   else()
  78     list(APPEND arrow_CMAKE_ARGS -DCMAKE_BUILD_TYPE=Release)
  79   endif()
  80
  81   # we use an external project and copy the sources to bin directory to ensure
  82   # that object files are built outside of the source tree.
  83   include(ExternalProject)
  84   set(arrow_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/arrow/cpp")
  85   set(arrow_BINARY_DIR "${CMAKE_CURRENT_BINARY_DIR}/arrow/cpp")
  86
  87   set(arrow_INSTALL_PREFIX "${CMAKE_CURRENT_BINARY_DIR}/arrow")
  88   list(APPEND arrow_CMAKE_ARGS -DCMAKE_INSTALL_PREFIX=${arrow_INSTALL_PREFIX})
  89
  90   set(arrow_INSTALL_LIBDIR "lib") # force lib so we don't have to guess between lib/lib64
  91   list(APPEND arrow_CMAKE_ARGS -DCMAKE_INSTALL_LIBDIR=${arrow_INSTALL_LIBDIR})
  92   set(arrow_LIBRARY_DIR "${arrow_INSTALL_PREFIX}/${arrow_INSTALL_LIBDIR}")
  93
  94   set(arrow_LIBRARY "${arrow_LIBRARY_DIR}/libarrow.a")
  95   set(parquet_LIBRARY "${arrow_LIBRARY_DIR}/libparquet.a")
  96
  97   set(arrow_INCLUDE_DIR "${arrow_INSTALL_PREFIX}/include")
  98   # this include directory won't exist until the install step, but the
  99   # imported targets need it early for INTERFACE_INCLUDE_DIRECTORIES
 100   file(MAKE_DIRECTORY "${arrow_INCLUDE_DIR}")
 101
 102   set(arrow_BYPRODUCTS ${arrow_LIBRARY})
 103   list(APPEND arrow_BYPRODUCTS ${parquet_LIBRARY})
 104
 105   if(CMAKE_MAKE_PROGRAM MATCHES "make")
 106     # try to inherit command line arguments passed by parent "make" job
 107     set(make_cmd $(MAKE))
 108     set(install_cmd $(MAKE) install)
 109   else()
 110     set(make_cmd ${CMAKE_COMMAND} --build <BINARY_DIR>)
 111     set(install_cmd ${CMAKE_COMMAND} --build <BINARY_DIR> --target install)
 112   endif()
 113
 114   # clear the DESTDIR environment variable from debian/rules,
 115   # because it messes with the internal install paths of arrow's bundled deps
 116   set(NO_DESTDIR_COMMAND ${CMAKE_COMMAND} -E env --unset=DESTDIR)
 117
 118   ExternalProject_Add(arrow_ext
 119     SOURCE_DIR "${arrow_SOURCE_DIR}"
 120     CMAKE_ARGS ${arrow_CMAKE_ARGS}
 121     BINARY_DIR "${arrow_BINARY_DIR}"
 122     BUILD_COMMAND ${NO_DESTDIR_COMMAND} ${make_cmd}
 123     BUILD_BYPRODUCTS "${arrow_BYPRODUCTS}"
 124     INSTALL_COMMAND ${NO_DESTDIR_COMMAND} ${install_cmd}
 125     INSTALL_DIR "${arrow_INSTALL_PREFIX}"
 126     DEPENDS "${arrow_DEPENDS}"
 127     LIST_SEPARATOR !)
 128
 129   add_library(Arrow::Arrow STATIC IMPORTED)
 130   add_dependencies(Arrow::Arrow arrow_ext)
 131   set_target_properties(Arrow::Arrow PROPERTIES
 132     INTERFACE_INCLUDE_DIRECTORIES "${arrow_INCLUDE_DIR}"
 133     INTERFACE_LINK_LIBRARIES "${arrow_INTERFACE_LINK_LIBRARIES}"
 134     IMPORTED_LINK_INTERFACE_LANGUAGES "CXX"
 135     IMPORTED_LOCATION "${arrow_LIBRARY}")
 136
 137   add_library(Arrow::Parquet STATIC IMPORTED)
 138   add_dependencies(Arrow::Parquet arrow_ext)
 139   target_link_libraries(Arrow::Parquet INTERFACE Arrow::Arrow)
 140   set_target_properties(Arrow::Parquet PROPERTIES
 141     IMPORTED_LINK_INTERFACE_LANGUAGES "CXX"
 142     IMPORTED_LOCATION "${parquet_LIBRARY}")
 143 endfunction()