ceph/cmake/modules/BuildDPDK.cmake

   1 function(do_build_dpdk dpdk_dir)
   2   # mk/machine/native/rte.vars.mk
   3   # rte_cflags are extracted from mk/machine/${machine}/rte.vars.mk
   4   # only 3 of them have -march=<arch> defined, so copying them here.
   5   # we need to pass the -march=<arch> to ${cc} as some headers in dpdk
   6   # require it to compile. for instance, dpdk/include/rte_memcpy.h.
   7   if(CMAKE_SYSTEM_PROCESSOR MATCHES "i386")
   8     set(arch "x86_64")
   9     set(machine "default")
  10     set(machine_tmpl "native")
  11   elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "i686")
  12     set(arch "i686")
  13     set(machine "default")
  14     set(machine_tmpl "native")
  15   elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "amd64|x86_64|AMD64")
  16     set(arch "x86_64")
  17     set(machine "default")
  18     set(machine_tmpl "native")
  19     set(rte_cflags "-march=core2")
  20   elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "arm|ARM")
  21     set(arch "arm")
  22     set(machine "armv7a")
  23     set(machine_tmpl "armv7a")
  24     set(rte_cflags "-march=armv7-a")
  25   elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "aarch64|AARCH64")
  26     set(arch "arm64")
  27     set(machine "armv8a")
  28     set(machine_tmpl "armv8a")
  29     set(rte_cflags "-march=armv8-a+crc")
  30   elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "(powerpc|ppc)64")
  31     set(arch "ppc_64")
  32     set(machine "power8")
  33     set(machine_tmpl "power8")
  34   else()
  35     message(FATAL_ERROR "not able to build DPDK support: "
  36       "unknown arch \"${CMAKE_SYSTEM_PROCESSOR}\"")
  37   endif()
  38   set(dpdk_rte_CFLAGS "${rte_cflags}" CACHE INTERNAL "")
  39   if(CMAKE_SYSTEM_NAME MATCHES "Linux")
  40     set(execenv "linux")
  41   elseif(CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
  42     set(execenv "freebsd")
  43   else()
  44     message(FATAL_ERROR "not able to build DPDK support: "
  45       "unsupported OS \"${CMAKE_SYSTEM_NAME}\"")
  46   endif()
  47
  48   if(CMAKE_C_COMPILER_ID STREQUAL GNU)
  49     set(toolchain "gcc")
  50   elseif(CMAKE_C_COMPILER_ID STREQUAL Clang)
  51     set(toolchain "clang")
  52   elseif(CMAKE_C_COMPILER_ID STREQUAL Intel)
  53     set(toolchain "icc")
  54   else()
  55     message(FATAL_ERROR "not able to build DPDK support: "
  56       "unknown compiler \"${CMAKE_C_COMPILER_ID}\"")
  57   endif()
  58
  59   set(target "${arch}-${machine_tmpl}-${execenv}-${toolchain}")
  60
  61   include(FindMake)
  62   find_make("MAKE_EXECUTABLE" "make_cmd")
  63   execute_process(
  64     COMMAND ${MAKE_EXECUTABLE} showconfigs
  65     WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/src/spdk/dpdk
  66     OUTPUT_VARIABLE supported_targets
  67     OUTPUT_STRIP_TRAILING_WHITESPACE)
  68   string(REPLACE "\n" ";" supported_targets "${supported_targets}")
  69   list(FIND supported_targets ${target} found)
  70   if(found EQUAL -1)
  71     message(FATAL_ERROR "not able to build DPDK support: "
  72       "unsupported target. "
  73       "\"${target}\" not listed in ${supported_targets}")
  74   endif()
  75
  76   if(Seastar_DPDK AND WITH_SPDK)
  77     message(FATAL_ERROR "not able to build DPDK with "
  78       "both Seastar_DPDK and WITH_SPDK enabled")
  79   elseif(Seastar_DPDK)
  80     set(dpdk_source_dir ${CMAKE_SOURCE_DIR}/src/seastar/dpdk)
  81   else() # WITH_SPDK or WITH_DPDK is enabled
  82     set(dpdk_source_dir ${CMAKE_SOURCE_DIR}/src/spdk/dpdk)
  83   endif()
  84
  85   include(ExternalProject)
  86   ExternalProject_Add(dpdk-ext
  87     SOURCE_DIR ${dpdk_source_dir}
  88     CONFIGURE_COMMAND ${make_cmd} config O=${dpdk_dir} T=${target}
  89     BUILD_COMMAND ${make_cmd} O=${dpdk_dir} CC=${CMAKE_C_COMPILER} EXTRA_CFLAGS=-fPIC
  90     BUILD_IN_SOURCE 1
  91     INSTALL_COMMAND "true")
  92   if(NUMA_FOUND)
  93     set(numa "y")
  94   else()
  95     set(numa "n")
  96   endif()
  97   ExternalProject_Add_Step(dpdk-ext patch-config
  98     COMMAND ${CMAKE_MODULE_PATH}/patch-dpdk-conf.sh ${dpdk_dir} ${machine} ${arch} ${numa}
  99     DEPENDEES configure
 100     DEPENDERS build)
 101   # easier to adjust the config
 102   ExternalProject_Add_StepTargets(dpdk-ext configure patch-config build)
 103 endfunction()
 104
 105 function(do_export_dpdk dpdk_dir)
 106   set(DPDK_INCLUDE_DIR ${dpdk_dir}/include)
 107   # create the directory so cmake won't complain when looking at the imported
 108   # target
 109   file(MAKE_DIRECTORY ${DPDK_INCLUDE_DIR})
 110
 111   if(NOT TARGET dpdk::cflags)
 112     add_library(dpdk::cflags INTERFACE IMPORTED)
 113     if (dpdk_rte_CFLAGS)
 114       set_target_properties(dpdk::cflags PROPERTIES
 115         INTERFACE_COMPILE_OPTIONS "${dpdk_rte_CFLAGS}")
 116     endif()
 117   endif()
 118
 119   list(APPEND dpdk_components
 120     bus_pci
 121     eal
 122     kvargs
 123     mbuf
 124     mempool
 125     mempool_ring
 126     pci
 127     ring
 128     telemetry)
 129   if(Seastar_DPDK)
 130     list(APPEND dpdk_components
 131       bus_vdev
 132       cfgfile
 133       hash
 134       net
 135       pmd_bnxt
 136       pmd_cxgbe
 137       pmd_e1000
 138       pmd_ena
 139       pmd_enic
 140       pmd_i40e
 141       pmd_ixgbe
 142       pmd_nfp
 143       pmd_qede
 144       pmd_ring
 145       pmd_sfc_efx
 146       timer)
 147   endif()
 148
 149   foreach(c ${dpdk_components})
 150     add_library(dpdk::${c} STATIC IMPORTED)
 151     add_dependencies(dpdk::${c} dpdk-ext)
 152     set(dpdk_${c}_LIBRARY
 153       "${dpdk_dir}/lib/${CMAKE_STATIC_LIBRARY_PREFIX}rte_${c}${CMAKE_STATIC_LIBRARY_SUFFIX}")
 154     set_target_properties(dpdk::${c} PROPERTIES
 155       INTERFACE_INCLUDE_DIRECTORIES ${DPDK_INCLUDE_DIR}
 156       INTERFACE_LINK_LIBRARIES dpdk::cflags
 157       IMPORTED_LOCATION "${dpdk_${c}_LIBRARY}")
 158     list(APPEND DPDK_LIBRARIES dpdk::${c})
 159     list(APPEND DPDK_ARCHIVES "${dpdk_${c}_LIBRARY}")
 160   endforeach()
 161
 162   if(NUMA_FOUND)
 163     set(dpdk_numa " -Wl,-lnuma")
 164   endif()
 165   add_library(dpdk::dpdk INTERFACE IMPORTED)
 166   add_dependencies(dpdk::dpdk
 167     ${DPDK_LIBRARIES})
 168   # workaround for https://gitlab.kitware.com/cmake/cmake/issues/16947
 169   set_target_properties(dpdk::dpdk PROPERTIES
 170     INTERFACE_INCLUDE_DIRECTORIES ${DPDK_INCLUDE_DIR}
 171     INTERFACE_LINK_LIBRARIES
 172     "-Wl,--whole-archive $<JOIN:${DPDK_ARCHIVES}, > -Wl,--no-whole-archive ${dpdk_numa} -Wl,-lpthread,-ldl")
 173   if(dpdk_rte_CFLAGS)
 174     set_target_properties(dpdk::dpdk PROPERTIES
 175       INTERFACE_COMPILE_OPTIONS "${dpdk_rte_CFLAGS}")
 176   endif()
 177 endfunction()
 178
 179 function(build_dpdk dpdk_dir)
 180   find_package(NUMA QUIET)
 181   if(NOT TARGET dpdk-ext)
 182     do_build_dpdk(${dpdk_dir})
 183   endif()
 184   if(NOT TARGET dpdk::dpdk)
 185     do_export_dpdk(${dpdk_dir})
 186   endif()
 187 endfunction()