ceph/cmake/modules/BuildRocksDB.cmake

   1 function(build_rocksdb)
   2   set(rocksdb_CMAKE_ARGS -DCMAKE_POSITION_INDEPENDENT_CODE=ON)
   3   list(APPEND rocksdb_CMAKE_ARGS -DWITH_GFLAGS=OFF)
   4
   5   # cmake doesn't properly handle arguments containing ";", such as
   6   # CMAKE_PREFIX_PATH, for which reason we'll have to use some other separator.
   7   string(REPLACE ";" "!" CMAKE_PREFIX_PATH_ALT_SEP "${CMAKE_PREFIX_PATH}")
   8   list(APPEND rocksdb_CMAKE_ARGS -DCMAKE_PREFIX_PATH=${CMAKE_PREFIX_PATH_ALT_SEP})
   9   if(CMAKE_TOOLCHAIN_FILE)
  10     list(APPEND rocksdb_CMAKE_ARGS
  11          -DCMAKE_TOOLCHAIN_FILE=${CMAKE_TOOLCHAIN_FILE})
  12   endif()
  13
  14   if(ALLOCATOR STREQUAL "jemalloc")
  15     list(APPEND rocksdb_CMAKE_ARGS -DWITH_JEMALLOC=ON)
  16     list(APPEND rocksdb_INTERFACE_LINK_LIBRARIES JeMalloc::JeMalloc)
  17   endif()
  18
  19   if (WITH_CCACHE AND CCACHE_FOUND)
  20     list(APPEND rocksdb_CMAKE_ARGS -DCMAKE_CXX_COMPILER_LAUNCHER=ccache)
  21   endif()
  22   list(APPEND rocksdb_CMAKE_ARGS -DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER})
  23
  24   list(APPEND rocksdb_CMAKE_ARGS -DWITH_SNAPPY=${SNAPPY_FOUND})
  25   if(SNAPPY_FOUND)
  26     list(APPEND rocksdb_INTERFACE_LINK_LIBRARIES snappy::snappy)
  27   endif()
  28   # libsnappy is a C++ library, we need to force rocksdb to link against
  29   # libsnappy statically.
  30   if(SNAPPY_FOUND AND WITH_STATIC_LIBSTDCXX)
  31     list(APPEND rocksdb_CMAKE_ARGS -DWITH_SNAPPY_STATIC_LIB=ON)
  32   endif()
  33
  34   list(APPEND rocksdb_CMAKE_ARGS -DWITH_LZ4=${LZ4_FOUND})
  35   if(LZ4_FOUND)
  36     list(APPEND rocksdb_INTERFACE_LINK_LIBRARIES LZ4::LZ4)
  37     # When cross compiling, cmake may fail to locate lz4.
  38     list(APPEND rocksdb_CMAKE_ARGS -Dlz4_INCLUDE_DIRS=${LZ4_INCLUDE_DIR})
  39     list(APPEND rocksdb_CMAKE_ARGS -Dlz4_LIBRARIES=${LZ4_LIBRARY})
  40   endif()
  41
  42   list(APPEND rocksdb_CMAKE_ARGS -DWITH_ZLIB=${ZLIB_FOUND})
  43   if(ZLIB_FOUND)
  44     list(APPEND rocksdb_INTERFACE_LINK_LIBRARIES ZLIB::ZLIB)
  45   endif()
  46
  47   list(APPEND rocksdb_CMAKE_ARGS -DPORTABLE=ON)
  48   list(APPEND rocksdb_CMAKE_ARGS -DCMAKE_AR=${CMAKE_AR})
  49   list(APPEND rocksdb_CMAKE_ARGS -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE})
  50   list(APPEND rocksdb_CMAKE_ARGS -DFAIL_ON_WARNINGS=OFF)
  51   list(APPEND rocksdb_CMAKE_ARGS -DUSE_RTTI=1)
  52   list(APPEND rocksdb_CMAKE_ARGS -G${CMAKE_GENERATOR})
  53   CHECK_C_COMPILER_FLAG("-Wno-stringop-truncation" HAS_WARNING_STRINGOP_TRUNCATION)
  54   if(HAS_WARNING_STRINGOP_TRUNCATION)
  55     list(APPEND rocksdb_CMAKE_ARGS -DCMAKE_C_FLAGS=-Wno-stringop-truncation)
  56   endif()
  57   include(CheckCXXCompilerFlag)
  58   check_cxx_compiler_flag("-Wno-deprecated-copy" HAS_WARNING_DEPRECATED_COPY)
  59   if(HAS_WARNING_DEPRECATED_COPY)
  60     set(rocksdb_CXX_FLAGS -Wno-deprecated-copy)
  61   endif()
  62   check_cxx_compiler_flag("-Wno-pessimizing-move" HAS_WARNING_PESSIMIZING_MOVE)
  63   if(HAS_WARNING_PESSIMIZING_MOVE)
  64     set(rocksdb_CXX_FLAGS "${rocksdb_CXX_FLAGS} -Wno-pessimizing-move")
  65   endif()
  66   if(rocksdb_CXX_FLAGS)
  67     list(APPEND rocksdb_CMAKE_ARGS -DCMAKE_CXX_FLAGS='${rocksdb_CXX_FLAGS}')
  68   endif()
  69   # we use an external project and copy the sources to bin directory to ensure
  70   # that object files are built outside of the source tree.
  71   include(ExternalProject)
  72   set(rocksdb_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/rocksdb")
  73   set(rocksdb_BINARY_DIR "${CMAKE_CURRENT_BINARY_DIR}/rocksdb")
  74   set(rocksdb_LIBRARY "${rocksdb_BINARY_DIR}/librocksdb.a")
  75   if(CMAKE_MAKE_PROGRAM MATCHES "make")
  76     # try to inherit command line arguments passed by parent "make" job
  77     set(make_cmd $(MAKE) rocksdb)
  78   else()
  79     set(make_cmd ${CMAKE_COMMAND} --build <BINARY_DIR> --target rocksdb)
  80   endif()
  81
  82   ExternalProject_Add(rocksdb_ext
  83     SOURCE_DIR "${rocksdb_SOURCE_DIR}"
  84     CMAKE_ARGS ${rocksdb_CMAKE_ARGS}
  85     BINARY_DIR "${rocksdb_BINARY_DIR}"
  86     BUILD_COMMAND "${make_cmd}"
  87     BUILD_BYPRODUCTS "${rocksdb_LIBRARY}"
  88     INSTALL_COMMAND "true"
  89     LIST_SEPARATOR !)
  90
  91   add_library(RocksDB::RocksDB STATIC IMPORTED)
  92   add_dependencies(RocksDB::RocksDB rocksdb_ext)
  93   set(rocksdb_INCLUDE_DIR "${rocksdb_SOURCE_DIR}/include")
  94   foreach(ver "MAJOR" "MINOR" "PATCH")
  95     file(STRINGS "${rocksdb_INCLUDE_DIR}/rocksdb/version.h" ROCKSDB_VER_${ver}_LINE
  96       REGEX "^#define[ \t]+ROCKSDB_${ver}[ \t]+[0-9]+$")
  97     string(REGEX REPLACE "^#define[ \t]+ROCKSDB_${ver}[ \t]+([0-9]+)$"
  98       "\\1" ROCKSDB_VERSION_${ver} "${ROCKSDB_VER_${ver}_LINE}")
  99     unset(ROCKDB_VER_${ver}_LINE)
 100   endforeach()
 101   set(rocksdb_VERSION_STRING
 102     "${ROCKSDB_VERSION_MAJOR}.${ROCKSDB_VERSION_MINOR}.${ROCKSDB_VERSION_PATCH}")
 103   set_target_properties(RocksDB::RocksDB PROPERTIES
 104     INTERFACE_INCLUDE_DIRECTORIES "${rocksdb_INCLUDE_DIR}"
 105     INTERFACE_LINK_LIBRARIES "${rocksdb_INTERFACE_LINK_LIBRARIES}"
 106     IMPORTED_LINK_INTERFACE_LANGUAGES "CXX"
 107     IMPORTED_LOCATION "${rocksdb_LIBRARY}"
 108     VERSION "${rocksdb_VERSION_STRING}")
 109 endfunction()