ceph/cmake/modules/Buildpmem.cmake

   1 function(build_pmem)
   2   include(FindMake)
   3   find_make("MAKE_EXECUTABLE" "make_cmd")
   4
   5   if(EXISTS "${PROJECT_SOURCE_DIR}/src/pmdk/Makefile")
   6     set(source_dir_args
   7       SOURCE_DIR "${PROJECT_SOURCE_DIR}/src/pmdk")
   8   else()
   9     set(source_dir_args
  10       SOURCE_DIR ${CMAKE_BINARY_DIR}/src/pmdk
  11       GIT_REPOSITORY https://github.com/ceph/pmdk.git
  12       GIT_TAG "1.10"
  13       GIT_SHALLOW TRUE
  14       GIT_CONFIG advice.detachedHead=false)
  15   endif()
  16
  17   # Use debug PMDK libs in debug lib/rbd builds
  18   if(CMAKE_BUILD_TYPE STREQUAL Debug)
  19     set(PMDK_LIB_DIR "debug")
  20   else()
  21     set(PMDK_LIB_DIR "nondebug")
  22   endif()
  23
  24   set(pmdk_cflags "-Wno-error -fno-lto")
  25   include(ExternalProject)
  26   ExternalProject_Add(pmdk_ext
  27       ${source_dir_args}
  28       CONFIGURE_COMMAND ""
  29       # Explicitly built w/o NDCTL, otherwise if ndtcl is present on the
  30       # build system tests statically linking to librbd (which uses
  31       # libpmemobj) will not link (because we don't build the ndctl
  32       # static library here).
  33       BUILD_COMMAND ${make_cmd} CC=${CMAKE_C_COMPILER} "EXTRA_CFLAGS=${pmdk_cflags}" NDCTL_ENABLE=n BUILD_EXAMPLES=n BUILD_BENCHMARKS=n DOC=n
  34       BUILD_IN_SOURCE 1
  35       BUILD_BYPRODUCTS "<SOURCE_DIR>/src/${PMDK_LIB_DIR}/libpmem.a" "<SOURCE_DIR>/src/${PMDK_LIB_DIR}/libpmemobj.a"
  36       INSTALL_COMMAND "")
  37   unset(make_cmd)
  38
  39   ExternalProject_Get_Property(pmdk_ext source_dir)
  40   set(PMDK_SRC "${source_dir}/src")
  41   set(PMDK_INCLUDE "${source_dir}/src/include")
  42   set(PMDK_LIB "${source_dir}/src/${PMDK_LIB_DIR}")
  43
  44   # libpmem
  45   add_library(pmem::pmem STATIC IMPORTED GLOBAL)
  46   add_dependencies(pmem::pmem pmdk_ext)
  47   file(MAKE_DIRECTORY ${PMDK_INCLUDE})
  48   find_package(Threads)
  49   set_target_properties(pmem::pmem PROPERTIES
  50     INTERFACE_INCLUDE_DIRECTORIES ${PMDK_INCLUDE}
  51     IMPORTED_LOCATION "${PMDK_LIB}/libpmem.a"
  52     INTERFACE_LINK_LIBRARIES Threads::Threads)
  53
  54   # libpmemobj
  55   add_library(pmem::pmemobj STATIC IMPORTED GLOBAL)
  56   add_dependencies(pmem::pmemobj pmdk_ext)
  57   set_target_properties(pmem::pmemobj PROPERTIES
  58     INTERFACE_INCLUDE_DIRECTORIES ${PMDK_INCLUDE}
  59     IMPORTED_LOCATION "${PMDK_LIB}/libpmemobj.a"
  60     INTERFACE_LINK_LIBRARIES "pmem::pmem;${CMAKE_THREAD_LIBS_INIT}")
  61 endfunction()