ceph/cmake/modules/Findpmdk.cmake

   1 # - Find pmdk
   2 #
   3 # pmdk_INCLUDE_DIRS - Where to find pmdk headers
   4 # pmdk_LIBRARIES - List of libraries when using pmdk.
   5 # pmdk_FOUND - True if pmdk found.
   6
   7 find_package(PkgConfig QUIET REQUIRED)
   8
   9 # all pmdk libraries depend on pmem, so always find it
  10 set(pmdk_FIND_COMPONENTS ${pmdk_FIND_COMPONENTS} pmem)
  11 list(REMOVE_DUPLICATES pmdk_FIND_COMPONENTS)
  12
  13 foreach(component ${pmdk_FIND_COMPONENTS})
  14   set(pmdk_COMPONENTS pmem pmemobj)
  15   list(FIND pmdk_COMPONENTS "${component}" found)
  16   if(found EQUAL -1)
  17     message(FATAL_ERROR "unknown pmdk component: ${component}")
  18   endif()
  19   pkg_check_modules(PKG_${component} QUIET "lib${component}")
  20   if(NOT pmdk_VERSION_STRING OR PKG_${component}_VERSION VERSION_LESS pmdk_VERSION_STRING)
  21     set(pmdk_VERSION_STRING ${PKG_${component}_VERSION})
  22   endif()
  23   find_path(pmdk_${component}_INCLUDE_DIR
  24     NAMES lib${component}.h
  25     HINTS ${PKG_${component}_INCLUDE_DIRS})
  26   find_library(pmdk_${component}_LIBRARY
  27     NAMES ${component}
  28     HINTS ${PKG_${component}_LIBRARY_DIRS})
  29   mark_as_advanced(
  30     pmdk_${component}_INCLUDE_DIR
  31     pmdk_${component}_LIBRARY)
  32   list(APPEND pmdk_INCLUDE_DIRS "pmdk_${component}_INCLUDE_DIR")
  33   list(APPEND pmdk_LIBRARIES "pmdk_${component}_LIBRARY")
  34 endforeach()
  35
  36 include(FindPackageHandleStandardArgs)
  37 find_package_handle_standard_args(pmdk
  38   REQUIRED_VARS pmdk_INCLUDE_DIRS pmdk_LIBRARIES
  39   VERSION_VAR pmdk_VERSION_STRING)
  40
  41 mark_as_advanced(
  42   pmdk_INCLUDE_DIRS
  43   pmdk_LIBRARIES)
  44
  45 if(pmdk_FOUND)
  46   foreach(component pmem ${pmdk_FIND_COMPONENTS})
  47     if(NOT TARGET pmdk::${component})
  48       add_library(pmdk::${component} UNKNOWN IMPORTED)
  49       set_target_properties(pmdk::${component} PROPERTIES
  50         INTERFACE_INCLUDE_DIRECTORIES "${pmdk_${component}_INCLUDE_DIR}"
  51         IMPORTED_LINK_INTERFACE_LANGUAGES "C"
  52         IMPORTED_LOCATION "${pmdk_${component}_LIBRARY}")
  53       # all pmdk libraries call into pmdk::pmem
  54       if(NOT component STREQUAL pmem)
  55         set_target_properties(pmdk::${component} PROPERTIES
  56           INTERFACE_LINK_LIBRARIES pmdk::pmem)
  57       endif()
  58     endif()
  59   endforeach()
  60 endif()