ceph/src/CMakeLists.txt

   1 include(GetGitRevisionDescription)
   2
   3 include(GNUInstallDirs)
   4 # for erasure and compressor plugins
   5 set(CEPH_INSTALL_PKGLIBDIR ${CMAKE_INSTALL_LIBDIR}/${PROJECT_NAME})
   6 set(CEPH_INSTALL_FULL_PKGLIBDIR ${CMAKE_INSTALL_FULL_LIBDIR}/${PROJECT_NAME})
   7 # for mgr plugins
   8 set(CEPH_INSTALL_DATADIR ${CMAKE_INSTALL_FULL_DATADIR}/${PROJECT_NAME})
   9 # so libceph-common can be found
  10 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  11 if(NOT CMAKE_INSTALL_RPATH)
  12   set(CMAKE_INSTALL_RPATH "${CEPH_INSTALL_FULL_PKGLIBDIR}")
  13 endif()
  14
  15 # to be compatible with configure_files shared with autoconfig
  16 set(bindir ${CMAKE_INSTALL_FULL_BINDIR})
  17 set(sbindir ${CMAKE_INSTALL_FULL_SBINDIR})
  18 set(libdir ${CMAKE_INSTALL_FULL_LIBDIR})
  19 set(sysconfdir ${CMAKE_INSTALL_FULL_SYSCONFDIR})
  20 set(libexecdir ${CMAKE_INSTALL_FULL_LIBEXECDIR})
  21 set(pkgdatadir ${CMAKE_INSTALL_FULL_DATADIR})
  22 set(datadir ${CEPH_INSTALL_DATADIR})
  23 set(prefix ${CMAKE_INSTALL_PREFIX})
  24
  25 add_definitions("-DHAVE_CONFIG_H -D__CEPH__ -D_REENTRANT -D_THREAD_SAFE -D__STDC_FORMAT_MACROS")
  26 add_definitions("-D_FILE_OFFSET_BITS=64")
  27 if(LINUX)
  28   add_definitions("-D_GNU_SOURCE")
  29 endif()
  30
  31 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wtype-limits -Wignored-qualifiers -Winit-self")
  32 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wpointer-arith -Werror=format-security -fno-strict-aliasing -fsigned-char")
  33
  34 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -ftemplate-depth-1024")
  35 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wnon-virtual-dtor")
  36 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-unknown-pragmas")
  37 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-ignored-qualifiers")
  38 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-unknown-pragmas")
  39 if(CMAKE_CXX_COMPILER_ID STREQUAL GNU)
  40   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -rdynamic")
  41   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wstrict-null-sentinel -Woverloaded-virtual")
  42   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-new-ttp-matching")
  43   # cmake does not add '-pie' for executables even if
  44   # CMAKE_POSITION_INDEPENDENT_CODE is TRUE.
  45   if(EXE_LINKER_USE_PIE)
  46     if (NOT WITH_OSD_INSTRUMENT_FUNCTIONS AND NOT HAVE_SEASTAR)
  47       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -pie")
  48     endif()
  49   endif()
  50 elseif(CMAKE_CXX_COMPILER_ID STREQUAL Clang)
  51   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_EXPORTS_C_FLAG}")
  52   set(CMAKE_LINKER_FLAGS "${CMAKE_LINKER_FLAGS} -rdynamic -export-dynamic ${CMAKE_EXE_EXPORTS_C_FLAG}")
  53   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-inconsistent-missing-override -Wno-mismatched-tags")
  54   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-unused-private-field")
  55   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-address-of-packed-member")
  56   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-unused-function")
  57   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-unused-local-typedef")
  58   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-varargs")
  59   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-gnu-designator")
  60   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-missing-braces -Wno-parentheses -Wno-deprecated-register")
  61   if(APPLE)
  62     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -undefined dynamic_lookup")
  63   endif()
  64 endif(CMAKE_CXX_COMPILER_ID STREQUAL GNU)
  65 set(CMAKE_CXX_FLAGS "${CMAKE_C_FLAGS} ${CMAKE_CXX_FLAGS}")
  66
  67 if(NOT CMAKE_BUILD_TYPE)
  68   set(CMAKE_BUILD_TYPE "RelWithDebInfo" CACHE STRING "Default BUILD_TYPE is RelWithDebInfo, other options are: Debug, Release, and MinSizeRel." FORCE)
  69 endif()
  70
  71 if(WITH_CEPH_DEBUG_MUTEX OR CMAKE_BUILD_TYPE STREQUAL Debug)
  72   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DCEPH_DEBUG_MUTEX")
  73 endif()
  74
  75 include(CheckCCompilerFlag)
  76 if(CMAKE_CXX_COMPILER_ID STREQUAL GNU)
  77   CHECK_C_COMPILER_FLAG("-U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2" HAS_FORTIFY_SOURCE)
  78   if(NOT CMAKE_BUILD_TYPE STREQUAL Debug)
  79     if(HAS_FORTIFY_SOURCE)
  80       set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2")
  81       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2")
  82     endif()
  83   endif()
  84   CHECK_C_COMPILER_FLAG(-fstack-protector-strong HAS_STACK_PROTECT)
  85   if (HAS_STACK_PROTECT)
  86     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fstack-protector-strong")
  87     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fstack-protector-strong")
  88   endif()
  89 endif(CMAKE_CXX_COMPILER_ID STREQUAL GNU)
  90
  91 include(SIMDExt)
  92 if(HAVE_INTEL)
  93   set(CMAKE_ASM_COMPILER  ${PROJECT_SOURCE_DIR}/src/yasm-wrapper)
  94   if(APPLE)
  95     set(object_format "macho64")
  96   else()
  97     set(object_format "elf64")
  98   endif()
  99   set(CMAKE_ASM_FLAGS "-f ${object_format}")
 100   include(CheckYasm)
 101   check_yasm_support(${object_format}
 102     HAVE_GOOD_YASM_ELF64
 103     HAVE_BETTER_YASM_ELF64)
 104 endif()
 105
 106
 107 # require c++17
 108 if(CMAKE_VERSION VERSION_LESS "3.8")
 109   include(CheckCXXCompilerFlag)
 110   CHECK_CXX_COMPILER_FLAG("-std=c++17" COMPILER_SUPPORTS_CXX17)
 111   if(NOT COMPILER_SUPPORTS_CXX17)
 112     message(FATAL_ERROR
 113       "The compiler ${CMAKE_CXX_COMPILER} has no C++17 support.")
 114   endif()
 115   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++17")
 116   include(CheckCCompilerFlag)
 117   CHECK_C_COMPILER_FLAG("-std=gnu99" COMPILER_SUPPORTS_GNU99)
 118   if(NOT COMPILER_SUPPORTS_GNU99)
 119     message(FATAL_ERROR
 120       "The compiler ${CMAKE_C_COMPILER} has no GNU C99 support.")
 121   endif()
 122   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=gnu99")
 123 else()
 124   set(CMAKE_CXX_STANDARD 17)
 125   set(CMAKE_CXX_EXTENSIONS OFF)
 126   set(CMAKE_CXX_STANDARD_REQUIRED ON)
 127   set(CMAKE_C_STANDARD 99)
 128   # we use `asm()` to inline assembly, so enable the GNU extension
 129   set(CMAKE_C_EXTENSIONS ON)
 130   set(C_STANDARD_REQUIRED ON)
 131 endif()
 132
 133 include(CheckCXXSourceCompiles)
 134 CHECK_CXX_SOURCE_COMPILES("
 135 #include <map>
 136 using Map = std::map<int, int>;
 137 int main() {
 138   Map m;
 139   m.merge(Map{});
 140 }
 141 " HAVE_STDLIB_MAP_SPLICING)
 142
 143 ## Handle diagnostics color if compiler supports them.
 144 CHECK_C_COMPILER_FLAG("-fdiagnostics-color=always"
 145   COMPILER_SUPPORTS_DIAGNOSTICS_COLOR)
 146
 147 set(DIAGNOSTICS_COLOR "auto"
 148   CACHE STRING "Used if the C/C++ compiler supports the -fdiagnostics-color option. May have one of three values -- 'auto' (default), 'always', or 'never'. If set to 'always' and the compiler supports the option, 'make [...] | less -R' will make visible diagnostics colorization of compiler output.")
 149
 150 if(COMPILER_SUPPORTS_DIAGNOSTICS_COLOR)
 151   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fdiagnostics-color=${DIAGNOSTICS_COLOR}")
 152   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fdiagnostics-color=${DIAGNOSTICS_COLOR}")
 153 endif()
 154
 155 set(EXTRALIBS ${CMAKE_DL_LIBS})
 156 if(NOT APPLE)
 157   list(APPEND EXTRALIBS rt)
 158 endif()
 159 if(LINUX OR APPLE)
 160   set(LIB_RESOLV resolv)
 161   list(APPEND EXTRALIBS ${LIB_RESOLV})
 162 endif()
 163
 164 if(${ENABLE_COVERAGE})
 165   find_program(HAVE_GCOV gcov)
 166   if(NOT HAVE_GCOV)
 167     message(FATAL_ERROR "Coverage Enabled but gcov Not Found")
 168   endif(NOT HAVE_GCOV)
 169   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fprofile-arcs -ftest-coverage -O0")
 170   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fprofile-arcs -ftest-coverage")
 171   list(APPEND EXTRALIBS gcov)
 172 endif(${ENABLE_COVERAGE})
 173
 174 include_directories(${NSS_INCLUDE_DIR} ${NSPR_INCLUDE_DIR})
 175
 176 set(GCOV_PREFIX_STRIP 4)
 177
 178 # the src/.git_version file may be written out by make-dist; otherwise
 179 # we pull the git version from .git
 180 option(ENABLE_GIT_VERSION "build Ceph with git version string" ON)
 181 if(${ENABLE_GIT_VERSION})
 182   get_git_head_revision(GIT_REFSPEC CEPH_GIT_VER)
 183   git_describe(CEPH_GIT_NICE_VER --always)
 184   #if building from a source tarball via make-dist
 185   if(${CEPH_GIT_VER} STREQUAL "GITDIR-NOTFOUND")
 186     message(STATUS "Ceph/.git directory not found, parsing ${CMAKE_CURRENT_SOURCE_DIR}/.git_version for CEPH_GIT_VER and CEPH_GIT_NICE_VER")
 187     file(STRINGS ${CMAKE_CURRENT_SOURCE_DIR}/.git_version CEPH_GIT_SHA_AND_TAG)
 188     list(GET CEPH_GIT_SHA_AND_TAG 0 CEPH_GIT_VER)
 189     list(GET CEPH_GIT_SHA_AND_TAG 1 CEPH_GIT_NICE_VER)
 190   endif(${CEPH_GIT_VER} STREQUAL "GITDIR-NOTFOUND")
 191   # remove 'v' prefix from raw git version
 192   string(SUBSTRING ${CEPH_GIT_NICE_VER} 1 -1 CEPH_GIT_NICE_VER)
 193 else(${ENABLE_GIT_VERSION})
 194   set(CEPH_GIT_VER "no_version")
 195   set(CEPH_GIT_NICE_VER "Development")
 196 endif(${ENABLE_GIT_VERSION})
 197
 198 # the src/ceph_release file is 3 lines,
 199 #   <release number, e.g. '12' for luminous>
 200 #   <release name, e.g. 'luminous'>
 201 #   <release type: 'dev' for x.0.z, 'rc' or x.1.z, or 'stable' or x.2.z>
 202 # note that the release name is semi-redundant and must match CEPH_RELEASE_*
 203 # definitions in include/rados.h and common/ceph_strings.c.
 204 file(STRINGS ${CMAKE_CURRENT_SOURCE_DIR}/ceph_release CEPH_RELEASE_FILE)
 205 list(GET CEPH_RELEASE_FILE 0 CEPH_RELEASE)
 206 list(GET CEPH_RELEASE_FILE 1 CEPH_RELEASE_NAME)
 207 list(GET CEPH_RELEASE_FILE 2 CEPH_RELEASE_TYPE)
 208
 209 option(WITH_OCF "build OCF-compliant cluster resource agent" OFF)
 210 if(WITH_OCF)
 211   add_subdirectory(ocf)
 212 endif()
 213
 214 option(WITH_CEPHFS_JAVA "build libcephfs Java bindings" OFF)
 215 if(WITH_CEPHFS_JAVA)
 216   add_subdirectory(java)
 217 endif()
 218
 219 # Python stuff
 220 option(WITH_PYTHON2 "build python2 bindings" ON)
 221 if(WITH_PYTHON2)
 222   find_package(PythonInterp 2 REQUIRED)
 223   find_package(PythonLibs ${PYTHON_VERSION_STRING} EXACT REQUIRED)
 224 endif()
 225
 226 set(WITH_PYTHON3 "OFF" CACHE STRING "build python3 bindings with specified python3 version")
 227 if(WITH_PYTHON3)
 228   if(WITH_PYTHON3 MATCHES "^(1|ON|YES|TRUE|Y)$")
 229     set(WITH_PYTHON3 "3")
 230   endif()
 231   find_package(Python3Interp ${WITH_PYTHON3} REQUIRED)
 232   find_package(Python3Libs ${PYTHON3_VERSION_STRING} EXACT REQUIRED)
 233 endif()
 234
 235 # the major version of the python bindings as a dependency of other
 236 # targets
 237 if(WITH_PYTHON2)
 238   set(PY_BINDING_INFIX "")
 239 else()
 240   set(PY_BINDING_INFIX 3)
 241 endif()
 242
 243 if(HAVE_XIO)
 244   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -I${XIO_INCLUDE_DIR}")
 245   list(APPEND EXTRALIBS ${XIO_LIBRARY} pthread)
 246 endif(HAVE_XIO)
 247
 248 # sort out which allocator to use
 249 if(ALLOCATOR STREQUAL "tcmalloc")
 250   set(ALLOC_LIBS gperftools::tcmalloc)
 251   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-builtin-malloc -fno-builtin-calloc -fno-builtin-realloc -fno-builtin-free")
 252 elseif(ALLOCATOR STREQUAL "tcmalloc_minimal")
 253   set(ALLOC_LIBS gperftools::tcmalloc_minimal)
 254   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-builtin-malloc -fno-builtin-calloc -fno-builtin-realloc -fno-builtin-free")
 255 elseif(ALLOCATOR STREQUAL "jemalloc")
 256   set(ALLOC_LIBS JeMalloc::JeMalloc)
 257   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-builtin-malloc -fno-builtin-calloc -fno-builtin-realloc -fno-builtin-free")
 258 endif()
 259
 260 if (WITH_BLKIN)
 261   add_subdirectory(blkin/blkin-lib)
 262 endif(WITH_BLKIN)
 263
 264 # Common infrastructure
 265 configure_file(
 266   ${CMAKE_SOURCE_DIR}/src/ceph_ver.h.in.cmake
 267   ${CMAKE_BINARY_DIR}/src/include/ceph_ver.h
 268   @ONLY)
 269
 270 set(mds_files)
 271 list(APPEND mds_files
 272   mds/MDSMap.cc
 273   mds/FSMap.cc
 274   mds/FSMapUser.cc
 275   mds/inode_backtrace.cc
 276   mds/mdstypes.cc
 277   mds/flock.cc)
 278
 279 add_subdirectory(json_spirit)
 280
 281 include_directories(SYSTEM "${CMAKE_SOURCE_DIR}/src/xxHash")
 282 include_directories(SYSTEM "${CMAKE_SOURCE_DIR}/src/rapidjson/include")
 283
 284 if(WITH_SEASTAR)
 285   find_package(fmt 5.2.1 QUIET)
 286   if(NOT fmt_FOUND)
 287     message(STATUS "Could not find fmt, will build it")
 288     add_subdirectory(seastar/fmt)
 289   endif()
 290   find_package(c-ares 1.13.0 QUIET)
 291   if(NOT c-ares_FOUND)
 292     message(STATUS "Could not find c-ares, will build it")
 293     include(Buildc-ares)
 294     build_c_ares()
 295   endif()
 296   macro(find_package name)
 297     if(NOT TARGET ${name})
 298       _find_package(${ARGV})
 299     endif()
 300   endmacro ()
 301   set(Seastar_HWLOC OFF CACHE BOOL "" FORCE)
 302   set(Seastar_STD_OPTIONAL_VARIANT_STRINGVIEW ON CACHE BOOL "" FORCE)
 303   set(Seastar_CXX_FLAGS "-Wno-sign-compare;-Wno-attributes;-Wno-pessimizing-move;-Wno-address-of-packed-member" CACHE STRING "" FORCE)
 304   add_subdirectory(seastar)
 305   # create the directory so cmake won't complain when looking at the imported
 306   # target: Seastar exports this directory created at build-time
 307   file(MAKE_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/seastar/gen/include")
 308   add_subdirectory(crimson)
 309 endif()
 310
 311 set(libcommon_files
 312   ${CMAKE_BINARY_DIR}/src/include/ceph_ver.h
 313   ceph_ver.c
 314   xxHash/xxhash.c
 315   log/Log.cc
 316   mon/MonCap.cc
 317   mon/MonClient.cc
 318   mon/MonMap.cc
 319   mon/MonSub.cc
 320   mgr/MgrClient.cc
 321   mon/PGMap.cc
 322   mgr/ServiceMap.cc
 323   osd/ECMsgTypes.cc
 324   osd/HitSet.cc
 325   osd/OSDMap.cc
 326   osd/OSDMapMapping.cc
 327   osd/osd_types.cc
 328   osd/PGPeeringEvent.cc
 329   osd/OpRequest.cc
 330   osdc/Striper.cc
 331   osdc/Objecter.cc
 332   librbd/Features.cc
 333   ${mds_files})
 334 set_source_files_properties(ceph_ver.c
 335   APPEND PROPERTY OBJECT_DEPENDS ${CMAKE_BINARY_DIR}/src/include/ceph_ver.h)
 336 add_library(common-objs OBJECT ${libcommon_files})
 337
 338 CHECK_C_COMPILER_FLAG("-fvar-tracking-assignments" HAS_VTA)
 339 add_subdirectory(auth)
 340 add_subdirectory(common)
 341 add_subdirectory(crush)
 342 add_subdirectory(msg)
 343 add_subdirectory(arch)
 344
 345 set(ceph_common_objs
 346   $<TARGET_OBJECTS:common-auth-objs>
 347   $<TARGET_OBJECTS:common-common-objs>
 348   $<TARGET_OBJECTS:common-msg-objs>
 349   $<TARGET_OBJECTS:common_buffer_obj>
 350   $<TARGET_OBJECTS:common_texttable_obj>
 351   $<TARGET_OBJECTS:compressor_objs>
 352   $<TARGET_OBJECTS:common-objs>
 353   $<TARGET_OBJECTS:common_mountcephfs_objs>
 354   $<TARGET_OBJECTS:global_common_objs>
 355   $<TARGET_OBJECTS:crush_objs>)
 356 set(ceph_common_deps
 357   json_spirit erasure_code arch crc32
 358   ${LIB_RESOLV}
 359   Boost::thread
 360   Boost::system
 361   Boost::random
 362   Boost::program_options
 363   Boost::date_time
 364   Boost::iostreams
 365   ${BLKID_LIBRARIES}
 366   ${Backtrace_LIBRARIES}
 367   ${BLKIN_LIBRARIES}
 368   ${CRYPTO_LIBS}
 369   ${GSSAPI_LIBRARIES}
 370   ${CMAKE_THREAD_LIBS_INIT}
 371   ${CMAKE_DL_LIBS})
 372 if(HAVE_UDEV)
 373   list(APPEND ceph_common_deps ${UDEV_LIBRARIES})
 374 endif()
 375
 376 if(HAVE_VERBS)
 377   list(APPEND ceph_common_deps IBVerbs::verbs)
 378 endif()
 379
 380 if(HAVE_RDMACM)
 381   list(APPEND ceph_common_deps RDMA::RDMAcm)
 382 endif()
 383
 384 if(NOT WITH_SYSTEM_BOOST)
 385   list(APPEND ceph_common_deps ${ZLIB_LIBRARIES})
 386 endif()
 387
 388 if(HAVE_QATZIP)
 389   list(APPEND ceph_common_deps ${QATZIP_LIBRARIES})
 390 endif()
 391
 392 if(WITH_DPDK)
 393   list(APPEND ceph_common_deps common_async_dpdk)
 394 endif()
 395
 396 add_library(common STATIC ${ceph_common_objs})
 397 target_link_libraries(common ${ceph_common_deps})
 398
 399 add_library(ceph-common SHARED ${ceph_common_objs})
 400 target_link_libraries(ceph-common ${ceph_common_deps})
 401 # appease dpkg-shlibdeps
 402 set_target_properties(ceph-common PROPERTIES
 403   SOVERSION 0
 404   INSTALL_RPATH "")
 405 if(NOT APPLE AND NOT FREEBSD)
 406   # Apple uses Mach-O, not ELF. so this option does not apply to APPLE.
 407   #
 408   # prefer the local symbol definitions when binding references to global
 409   # symbols. otherwise we could reference the symbols defined by the application
 410   # with the same name, instead of using the one defined in libceph-common.
 411   # in other words, we require libceph-common to use local symbols, even if redefined
 412   # in application".
 413   set_property(
 414     TARGET ceph-common
 415     APPEND APPEND_STRING
 416     PROPERTY LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions")
 417 endif()
 418
 419 install(
 420   TARGETS ceph-common
 421   LIBRARY
 422   DESTINATION ${CEPH_INSTALL_PKGLIBDIR}
 423   NAMELINK_SKIP)
 424
 425 if(${WITH_LTTNG})
 426   add_subdirectory(tracing)
 427   add_dependencies(common-objs oprequest-tp)
 428 endif(${WITH_LTTNG})
 429
 430 add_subdirectory(global)
 431
 432 add_subdirectory(lua)
 433
 434 # rados object classes
 435 add_subdirectory(cls)
 436
 437 # RADOS client/library
 438 add_subdirectory(osdc)
 439
 440 # heal_profiler
 441 add_subdirectory(perfglue)
 442
 443 add_library(rados_snap_set_diff_obj OBJECT librados/snap_set_diff.cc)
 444
 445 option(WITH_LIBRADOSSTRIPER "build with libradosstriper support" ON)
 446
 447 add_subdirectory(include)
 448 add_subdirectory(librados)
 449
 450 if(WITH_LIBRADOSSTRIPER)
 451   add_subdirectory(libradosstriper)
 452 endif()
 453
 454 if(WITH_MGR)
 455   add_subdirectory(mgr)
 456 endif()
 457
 458 set(librados_config_srcs
 459   librados-config.cc)
 460 add_executable(librados-config ${librados_config_srcs})
 461 target_link_libraries(librados-config librados global ${BLKID_LIBRARIES} ${CMAKE_DL_LIBS} ${GSSAPI_LIBRARIES})
 462
 463 install(TARGETS librados-config DESTINATION bin)
 464
 465 # virtualenv base directory for ceph-disk and ceph-detect-init
 466 set(CEPH_BUILD_VIRTUALENV $ENV{TMPDIR})
 467 if(NOT CEPH_BUILD_VIRTUALENV)
 468   set(CEPH_BUILD_VIRTUALENV ${CMAKE_BINARY_DIR})
 469 endif()
 470
 471 add_subdirectory(pybind)
 472 add_subdirectory(ceph-volume)
 473
 474 # Monitor
 475 add_subdirectory(mon)
 476 set(ceph_mon_srcs
 477   ceph_mon.cc)
 478 add_executable(ceph-mon ${ceph_mon_srcs}
 479   $<TARGET_OBJECTS:common_texttable_obj>)
 480 add_dependencies(ceph-mon erasure_code_plugins)
 481 target_link_libraries(ceph-mon mon os global-static ceph-common
 482   ${EXTRALIBS}
 483   ${CMAKE_DL_LIBS} ${GSSAPI_LIBRARIES})
 484 install(TARGETS ceph-mon DESTINATION bin)
 485
 486 # OSD/ObjectStore
 487 # make rocksdb statically
 488
 489 if(NOT WITH_SYSTEM_ROCKSDB)
 490   include(BuildRocksDB)
 491   build_rocksdb()
 492 endif(NOT WITH_SYSTEM_ROCKSDB)
 493
 494 include(TestBigEndian)
 495 test_big_endian(CEPH_BIG_ENDIAN)
 496 if(NOT CEPH_BIG_ENDIAN)
 497   set(CEPH_LITTLE_ENDIAN 1)
 498 endif()
 499
 500 add_subdirectory(kv)
 501 add_subdirectory(os)
 502
 503 add_subdirectory(osd)
 504
 505 set(ceph_osd_srcs
 506   ceph_osd.cc)
 507 add_executable(ceph-osd ${ceph_osd_srcs})
 508 add_dependencies(ceph-osd erasure_code_plugins)
 509 target_link_libraries(ceph-osd osd os global-static common
 510   ${BLKID_LIBRARIES})
 511 if(WITH_FUSE)
 512   target_link_libraries(ceph-osd ${FUSE_LIBRARIES})
 513 endif()
 514 set_target_properties(ceph-osd PROPERTIES
 515   POSITION_INDEPENDENT_CODE ${EXE_LINKER_USE_PIE}
 516   INSTALL_RPATH "")
 517 install(TARGETS ceph-osd DESTINATION bin)
 518
 519 if (WITH_CEPHFS)
 520   add_subdirectory(mds)
 521   set(ceph_mds_srcs
 522     ceph_mds.cc)
 523   add_executable(ceph-mds ${ceph_mds_srcs})
 524   target_link_libraries(ceph-mds mds ${CMAKE_DL_LIBS} global-static ceph-common
 525     Boost::thread)
 526   install(TARGETS ceph-mds DESTINATION bin)
 527 endif()
 528
 529 add_subdirectory(erasure-code)
 530
 531 # Support/Tools
 532 if(WITH_TESTS)
 533   option(WITH_SYSTEM_GTEST "require and build with system gtest and gmock" OFF)
 534   if(WITH_SYSTEM_GTEST)
 535     find_package(GTest REQUIRED)
 536     find_package(GMock REQUIRED)
 537   else()
 538     add_subdirectory(googletest/googlemock)
 539     add_library(GMock::GMock ALIAS gmock)
 540     add_library(GMock::Main ALIAS gmock_main)
 541     target_include_directories(gmock INTERFACE
 542       $<TARGET_PROPERTY:gtest,INTERFACE_INCLUDE_DIRECTORIES>)
 543     target_include_directories(gmock_main INTERFACE
 544       $<TARGET_PROPERTY:gtest,INTERFACE_INCLUDE_DIRECTORIES>)
 545     add_library(GTest::GTest ALIAS gtest)
 546     add_library(GTest::Main ALIAS gtest_main)
 547   endif()
 548 endif(WITH_TESTS)
 549
 550 # dmClock (after gmock)
 551 option(WITH_DMCLOCK_TESTS
 552   "enable the build of dmclock-tests and dmclock-data-struct tests binaries"
 553   OFF)
 554 if(WITH_TESTS AND WITH_DMCLOCK_TESTS)
 555   # note: add_test is not being called, so dmclock tests aren't part
 556   # of ceph tests
 557   set(dmclock_TEST ON CACHE BOOL "" FORCE)
 558 endif()
 559 add_subdirectory(dmclock)
 560
 561 add_subdirectory(compressor)
 562
 563 add_subdirectory(tools)
 564
 565 if(WITH_TESTS)
 566   add_subdirectory(test)
 567 endif()
 568
 569 add_subdirectory(crypto)
 570
 571 if(WITH_TESTS)
 572   configure_file(${CMAKE_SOURCE_DIR}/src/ceph-coverage.in
 573     ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/ceph-coverage @ONLY)
 574   configure_file(${CMAKE_SOURCE_DIR}/src/ceph-debugpack.in
 575     ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/ceph-debugpack @ONLY)
 576 endif()
 577
 578 configure_file(${CMAKE_SOURCE_DIR}/src/ceph.in
 579   ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/ceph @ONLY)
 580
 581 configure_file(${CMAKE_SOURCE_DIR}/src/init-ceph.in
 582   ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/init-ceph @ONLY)
 583
 584 configure_file(ceph-post-file.in
 585   ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/ceph-post-file @ONLY)
 586
 587 configure_file(ceph-crash.in
 588   ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/ceph-crash @ONLY)
 589
 590 if(WITH_TESTS)
 591   install(PROGRAMS
 592     ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/ceph-debugpack
 593     ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/ceph-coverage
 594     DESTINATION bin)
 595 endif()
 596
 597 install(PROGRAMS
 598   ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/ceph
 599   ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/ceph-post-file
 600   ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/ceph-crash
 601   ${CMAKE_SOURCE_DIR}/src/ceph-run
 602   ${CMAKE_SOURCE_DIR}/src/ceph-clsinfo
 603   DESTINATION bin)
 604 install(PROGRAMS
 605   ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/init-ceph
 606   DESTINATION ${CMAKE_INSTALL_SYSCONFDIR}/init.d
 607   RENAME ceph)
 608
 609 install(FILES
 610   ${CMAKE_SOURCE_DIR}/share/id_rsa_drop.ceph.com
 611   ${CMAKE_SOURCE_DIR}/share/id_rsa_drop.ceph.com.pub
 612   ${CMAKE_SOURCE_DIR}/share/known_hosts_drop.ceph.com
 613   DESTINATION ${CMAKE_INSTALL_DATADIR}/ceph)
 614
 615 install(PROGRAMS
 616   ceph_common.sh
 617   ceph-osd-prestart.sh
 618   DESTINATION ${CMAKE_INSTALL_LIBEXECDIR}/ceph)
 619
 620 install(PROGRAMS
 621   ${CMAKE_SOURCE_DIR}/src/ceph-create-keys
 622   DESTINATION sbin)
 623
 624 add_subdirectory(bash_completion)
 625 add_subdirectory(client)
 626
 627 if(WITH_LIBCEPHFS)
 628   find_package(PkgConfig QUIET REQUIRED)
 629   pkg_check_modules(CAPNG REQUIRED libcap-ng)
 630   set(libcephfs_srcs libcephfs.cc)
 631   add_library(cephfs ${CEPH_SHARED} ${libcephfs_srcs})
 632   target_link_libraries(cephfs PRIVATE client ceph-common
 633     ${CRYPTO_LIBS} ${EXTRALIBS})
 634   if(ENABLE_SHARED)
 635     set_target_properties(cephfs PROPERTIES
 636       OUTPUT_NAME cephfs
 637       VERSION 2.0.0
 638       SOVERSION 2)
 639     if(NOT APPLE)
 640       foreach(name ceph-common client osdc)
 641         set_property(TARGET cephfs APPEND_STRING PROPERTY
 642           LINK_FLAGS " -Wl,--exclude-libs,lib${name}.a")
 643       endforeach()
 644     endif()
 645   endif(ENABLE_SHARED)
 646   install(TARGETS cephfs DESTINATION ${CMAKE_INSTALL_LIBDIR})
 647   install(DIRECTORY
 648     "${CMAKE_SOURCE_DIR}/src/include/cephfs"
 649     DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 650   set(ceph_syn_srcs
 651     ceph_syn.cc
 652     client/SyntheticClient.cc)
 653   add_executable(ceph-syn ${ceph_syn_srcs})
 654   target_link_libraries(ceph-syn client global-static ceph-common)
 655   install(TARGETS ceph-syn DESTINATION bin)
 656   if(LINUX)
 657     add_subdirectory(mount)
 658   endif()
 659 endif(WITH_LIBCEPHFS)
 660
 661 if(WITH_FUSE)
 662   set(ceph_fuse_srcs
 663     ceph_fuse.cc
 664     client/fuse_ll.cc)
 665   add_executable(ceph-fuse ${ceph_fuse_srcs})
 666   target_link_libraries(ceph-fuse ${FUSE_LIBRARIES}
 667     ${GSSAPI_LIBRARIES} client ceph-common global-static)
 668   set_target_properties(ceph-fuse PROPERTIES
 669     COMPILE_FLAGS "-I${FUSE_INCLUDE_DIRS}"
 670     POSITION_INDEPENDENT_CODE ${EXE_LINKER_USE_PIE})
 671   install(TARGETS ceph-fuse DESTINATION bin)
 672   install(PROGRAMS mount.fuse.ceph DESTINATION ${CMAKE_INSTALL_SBINDIR})
 673 endif(WITH_FUSE)
 674
 675 add_subdirectory(journal)
 676
 677 if(WITH_RBD)
 678   if(WITH_KRBD)
 679     add_library(krbd STATIC krbd.cc
 680       $<TARGET_OBJECTS:parse_secret_objs>)
 681     target_link_libraries(krbd keyutils::keyutils)
 682   endif()
 683   add_subdirectory(librbd)
 684   if(WITH_FUSE)
 685     add_subdirectory(rbd_fuse)
 686   endif()
 687
 688   install(PROGRAMS
 689     ${CMAKE_SOURCE_DIR}/src/ceph-rbdnamer
 690     ${CMAKE_SOURCE_DIR}/src/rbd-replay-many
 691     ${CMAKE_SOURCE_DIR}/src/rbdmap
 692     DESTINATION ${CMAKE_INSTALL_BINDIR})
 693   add_subdirectory(rbd_replay)
 694 endif(WITH_RBD)
 695
 696 # RadosGW
 697 if(WITH_KVS)
 698   add_subdirectory(key_value_store)
 699 endif(WITH_KVS)
 700
 701 if(WITH_RADOSGW)
 702   set(civetweb_common_files civetweb/src/civetweb.c)
 703   add_library(civetweb_common_objs OBJECT ${civetweb_common_files})
 704   target_include_directories(civetweb_common_objs SYSTEM PRIVATE
 705         "${CMAKE_SOURCE_DIR}/src/civetweb/include")
 706   set_property(TARGET civetweb_common_objs
 707     APPEND PROPERTY COMPILE_DEFINITIONS USE_IPV6=1)
 708   if (LIBSSL_SONAME)
 709     set_property(TARGET civetweb_common_objs
 710       APPEND PROPERTY COMPILE_DEFINITIONS SSL_LIB="${LIBSSL_SONAME}")
 711     set_property(TARGET civetweb_common_objs
 712       APPEND PROPERTY COMPILE_DEFINITIONS CRYPTO_LIB="${LIBCRYPTO_SONAME}")
 713   endif()
 714
 715   if (OPENSSL_FOUND)
 716     # Use cmake to determine openssl version, a TODO is to make
 717     # civetweb itself do this based on openssl_api_compat strings
 718     if (NOT (OPENSSL_VERSION VERSION_LESS "1.1"))
 719       message(STATUS "Setting civetweb to use OPENSSL >= 1.1")
 720       set_property(TARGET civetweb_common_objs
 721         APPEND PROPERTY COMPILE_DEFINITIONS OPENSSL_API_1_1=1)
 722     endif()
 723   endif(OPENSSL_FOUND)
 724   add_subdirectory(rgw)
 725
 726 endif(WITH_RADOSGW)
 727
 728 install(FILES
 729   sample.ceph.conf
 730   DESTINATION ${CMAKE_INSTALL_DOCDIR})
 731
 732 # Now create a usable config.h
 733 configure_file(
 734   ${CMAKE_SOURCE_DIR}/src/include/config-h.in.cmake
 735   ${CMAKE_BINARY_DIR}/include/acconfig.h
 736 )
 737
 738 # Everything you need to spin up a cluster with vstart.sh
 739 add_custom_target(vstart-base DEPENDS
 740     ceph-osd
 741     ceph-mon
 742     ceph-authtool
 743     ceph-conf
 744     monmaptool
 745     crushtool
 746     rados
 747     cython${PY_BINDING_INFIX}_rados)
 748 if (WITH_MGR)
 749   add_dependencies(vstart-base ceph-mgr)
 750 endif()
 751
 752 add_custom_target(vstart DEPENDS vstart-base)
 753 if (WITH_RBD)
 754   add_dependencies(vstart cython${PY_BINDING_INFIX}_rbd)
 755 endif()
 756 if (WITH_CEPHFS)
 757   add_dependencies(vstart ceph-mds)
 758 endif()
 759 if(WITH_RADOSGW)
 760   add_dependencies(vstart radosgw radosgw-admin)
 761 endif(WITH_RADOSGW)
 762
 763 if(WITH_LTTNG)
 764   add_dependencies(vstart tracepoint_libraries)
 765 endif(WITH_LTTNG)
 766
 767 if(WITH_MGR AND WITH_MGR_DASHBOARD_FRONTEND AND CMAKE_SYSTEM_PROCESSOR MATCHES "x86_64|amd64")
 768   add_dependencies(vstart mgr-dashboard-frontend-build)
 769 endif()
 770
 771 if(WITH_MGR)
 772   add_dependencies(vstart ceph-volume-venv-setup)
 773 endif()
 774
 775 # Everything you need to run CephFS tests
 776 add_custom_target(cephfs_testing DEPENDS
 777     vstart
 778     rados
 779     cython${PY_BINDING_INFIX}_modules
 780     cephfs
 781     cls_cephfs
 782     ceph-fuse
 783     ceph-dencoder
 784     cephfs-journal-tool
 785     cephfs-data-scan
 786     cephfs-table-tool)
 787
 788 if (IS_DIRECTORY "${PROJECT_SOURCE_DIR}/.git")
 789   add_custom_target(
 790     git-update
 791     COMMAND git submodule sync
 792     COMMAND git submodule update --force --init --recursive
 793     WORKING_DIRECTORY "${PROJECT_SOURCE_DIR}")
 794 endif()
 795
 796 add_subdirectory(script)