ceph/src/boost/libs/beast/CMakeLists.txt

   1 #
   2 # Copyright (c) 2016-2017 Vinnie Falco (vinnie dot falco at gmail dot com)
   3 #
   4 # Distributed under the Boost Software License, Version 1.0. (See accompanying
   5 # file LICENSE_1_0.txt or copy at http://www.boost.org/LICENSE_1_0.txt)
   6 #
   7 # Official repository: https://github.com/boostorg/beast
   8 #
   9
  10 cmake_minimum_required (VERSION 3.5.1)
  11
  12 project (Beast VERSION 144)
  13
  14 set_property (GLOBAL PROPERTY USE_FOLDERS ON)
  15 option (Beast_BUILD_EXAMPLES "Build examples" ON)
  16 option (Beast_BUILD_TESTS "Build tests" ON)
  17
  18 if (MSVC)
  19     set (CMAKE_VERBOSE_MAKEFILE FALSE)
  20
  21     add_definitions (-D_WIN32_WINNT=0x0601)
  22     add_definitions (-D_SCL_SECURE_NO_WARNINGS=1)
  23     add_definitions (-D_CRT_SECURE_NO_WARNINGS=1)
  24
  25     add_compile_options(
  26         /bigobj       # large object file format
  27         /permissive-  # strict C++
  28         #/wd4503      # decorated name length exceeded, name was truncated
  29         /W4           # enable all warnings
  30         /MP           # Multi-processor compilation
  31         )
  32
  33     set (Boost_USE_STATIC_LIBS ON)
  34     set (Boost_USE_STATIC_RUNTIME ON)
  35
  36     set (CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} /MTd")
  37     set (CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} /Ob2 /Oi /Ot /GL /MT")
  38     set (CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO} /Oi /Ot /MT")
  39
  40     set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /SAFESEH:NO")
  41     set (CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} /LTCG")
  42
  43     # for RelWithDebInfo builds, disable incremental linking
  44     # since CMake sets it ON by default for that build type and it
  45     # causes warnings
  46     #
  47     string (REPLACE "/INCREMENTAL" "/INCREMENTAL:NO" replacement_flags
  48         ${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO})
  49     set (CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO ${replacement_flags})
  50
  51 else()
  52     set (THREADS_PREFER_PTHREAD_FLAG ON)
  53     find_package (Threads)
  54
  55     set( CMAKE_CXX_FLAGS
  56       "${CMAKE_CXX_FLAGS} -std=c++11 -Wall -Wextra -Wpedantic -Wno-unused-parameter")
  57
  58     if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
  59         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wrange-loop-analysis")
  60     endif ()
  61 endif()
  62
  63 # Must come before Boost includes, otherwise the
  64 # IDE sees the wrong file due to boost/ symlinks.
  65 include_directories (include)
  66
  67 #-------------------------------------------------------------------------------
  68 #
  69 # Boost
  70 #
  71
  72 get_filename_component (BOOST_ROOT ../../ ABSOLUTE)
  73
  74 # VFALCO I want static but "b2 stage" builds a minimal set which excludes static
  75 add_definitions (-DBOOST_ALL_STATIC_LINK=1)
  76
  77 add_definitions (-DBOOST_ASIO_NO_DEPRECATED=1)
  78 add_definitions (-DBOOST_ASIO_DISABLE_BOOST_ARRAY=1)
  79 add_definitions (-DBOOST_ASIO_DISABLE_BOOST_BIND=1)
  80 add_definitions (-DBOOST_ASIO_DISABLE_BOOST_DATE_TIME=1)
  81 add_definitions (-DBOOST_ASIO_DISABLE_BOOST_REGEX=1)
  82 add_definitions (-DBOOST_COROUTINES_NO_DEPRECATION_WARNING=1)
  83
  84 include_directories (${BOOST_ROOT})
  85
  86 link_directories(${BOOST_ROOT}/stage/lib)
  87
  88 if (MINGW)
  89     link_libraries(ws2_32 mswsock)
  90 endif()
  91
  92 #-------------------------------------------------------------------------------
  93 #
  94 # OpenSSL
  95 #
  96
  97 if (APPLE AND NOT DEFINED ENV{OPENSSL_ROOT_DIR})
  98   find_program(HOMEBREW brew)
  99   if (NOT HOMEBREW STREQUAL "HOMEBREW-NOTFOUND")
 100     execute_process(COMMAND brew --prefix openssl
 101       OUTPUT_VARIABLE OPENSSL_ROOT_DIR
 102       OUTPUT_STRIP_TRAILING_WHITESPACE)
 103   endif()
 104 endif()
 105
 106 find_package(OpenSSL)
 107
 108 if (OPENSSL_FOUND)
 109     add_definitions (-DBOOST_BEAST_USE_OPENSSL=1)
 110
 111 else()
 112     add_definitions (-DBOOST_BEAST_USE_OPENSSL=0)
 113     message("OpenSSL not found.")
 114 endif()
 115
 116 #
 117 #-------------------------------------------------------------------------------
 118
 119 function (DoGroupSources curdir rootdir folder)
 120     file (GLOB children RELATIVE ${PROJECT_SOURCE_DIR}/${curdir} ${PROJECT_SOURCE_DIR}/${curdir}/*)
 121     foreach (child ${children})
 122         if (IS_DIRECTORY ${PROJECT_SOURCE_DIR}/${curdir}/${child})
 123             DoGroupSources (${curdir}/${child} ${rootdir} ${folder})
 124         elseif (${child} STREQUAL "CMakeLists.txt")
 125             source_group("" FILES ${PROJECT_SOURCE_DIR}/${curdir}/${child})
 126         else()
 127             string (REGEX REPLACE ^${rootdir} ${folder} groupname ${curdir})
 128             string (REPLACE "/" "\\" groupname ${groupname})
 129             source_group (${groupname} FILES ${PROJECT_SOURCE_DIR}/${curdir}/${child})
 130         endif()
 131     endforeach()
 132 endfunction()
 133
 134 function (GroupSources curdir folder)
 135     DoGroupSources (${curdir} ${curdir} ${folder})
 136 endfunction()
 137
 138 #-------------------------------------------------------------------------------
 139
 140 if ("${VARIANT}" STREQUAL "coverage")
 141     if (MSVC)
 142     else()
 143         set (CMAKE_BUILD_TYPE DEBUG)
 144         set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -msse4.2 --coverage")
 145         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} --coverage")
 146     endif()
 147
 148 elseif ("${VARIANT}" STREQUAL "ubasan")
 149     if (MSVC)
 150     else()
 151         set (CMAKE_BUILD_TYPE RELWITHDEBINFO)
 152         set (CMAKE_CXX_FLAGS
 153           "${CMAKE_CXX_FLAGS} -DBOOST_BEAST_NO_SLOW_TESTS=1 -msse4.2 -funsigned-char -fno-omit-frame-pointer -fsanitize=address,undefined -fsanitize-blacklist=${PROJECT_SOURCE_DIR}/tools/blacklist.supp")
 154         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fsanitize=address,undefined")
 155     endif()
 156
 157 elseif ("${VARIANT}" STREQUAL "debug")
 158     set (CMAKE_BUILD_TYPE DEBUG)
 159
 160 elseif ("${VARIANT}" STREQUAL "release")
 161     set (CMAKE_BUILD_TYPE RELEASE)
 162
 163 endif()
 164
 165 #-------------------------------------------------------------------------------
 166 #
 167 # Tests and examples
 168 #
 169
 170 include_directories (.)
 171
 172 if (OPENSSL_FOUND)
 173     include_directories (${OPENSSL_INCLUDE_DIR})
 174 endif()
 175
 176 file (GLOB_RECURSE BOOST_BEAST_FILES
 177     ${PROJECT_SOURCE_DIR}/include/boost/beast/*.hpp
 178     ${PROJECT_SOURCE_DIR}/include/boost/beast/*.ipp
 179 )
 180
 181 file (GLOB_RECURSE COMMON_FILES
 182     ${PROJECT_SOURCE_DIR}/example/common/*.hpp
 183   )
 184
 185 if (Beast_BUILD_EXAMPLES AND
 186     (NOT "${VARIANT}" STREQUAL "coverage") AND
 187     (NOT "${VARIANT}" STREQUAL "ubasan"))
 188     add_subdirectory (example)
 189 endif()
 190
 191 if (Beast_BUILD_TESTS)
 192     add_subdirectory (test)
 193 endif()