ceph/src/boost/libs/beast/CMakeLists.txt

   1 #
   2 # Copyright (c) 2016-2017 Vinnie Falco (vinnie dot falco at gmail dot com)
   3 #
   4 # Distributed under the Boost Software License, Version 1.0. (See accompanying
   5 # file LICENSE_1_0.txt or copy at http://www.boost.org/LICENSE_1_0.txt)
   6 #
   7 # Official repository: https://github.com/boostorg/beast
   8 #
   9
  10 cmake_minimum_required (VERSION 3.5.1)
  11
  12 project (Beast VERSION 167)
  13
  14 set_property (GLOBAL PROPERTY USE_FOLDERS ON)
  15 option (Beast_BUILD_EXAMPLES "Build examples" ON)
  16 option (Beast_BUILD_TESTS "Build tests" ON)
  17
  18 if (MSVC)
  19     set (CMAKE_VERBOSE_MAKEFILE FALSE)
  20
  21     add_definitions (-D_WIN32_WINNT=0x0601)
  22     add_definitions (-D_SCL_SECURE_NO_WARNINGS=1)
  23     add_definitions (-D_CRT_SECURE_NO_WARNINGS=1)
  24
  25     add_compile_options(
  26         /bigobj       # large object file format
  27         /permissive-  # strict C++
  28         #/wd4503      # decorated name length exceeded, name was truncated
  29         /W4           # enable all warnings
  30         /MP           # Multi-processor compilation
  31         )
  32
  33     set (Boost_USE_STATIC_LIBS ON)
  34     set (Boost_USE_STATIC_RUNTIME ON)
  35
  36     set (CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} /MTd")
  37     set (CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} /Ob2 /Oi /Ot /GL /MT")
  38     set (CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO} /Oi /Ot /MT")
  39
  40     set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /SAFESEH:NO")
  41     set (CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} /LTCG")
  42
  43     # for RelWithDebInfo builds, disable incremental linking
  44     # since CMake sets it ON by default for that build type and it
  45     # causes warnings
  46     #
  47     string (REPLACE "/INCREMENTAL" "/INCREMENTAL:NO" replacement_flags
  48         ${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO})
  49     set (CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO ${replacement_flags})
  50
  51 else()
  52     set (THREADS_PREFER_PTHREAD_FLAG ON)
  53     find_package (Threads)
  54
  55     set( CMAKE_CXX_FLAGS
  56       "${CMAKE_CXX_FLAGS} -std=c++11 -Wall -Wextra -Wpedantic -Wno-unused-parameter")
  57
  58     if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
  59         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wrange-loop-analysis")
  60     endif ()
  61 endif()
  62
  63 # Must come before Boost includes, otherwise the
  64 # IDE sees the wrong file due to boost/ symlinks.
  65 include_directories (include)
  66
  67 #-------------------------------------------------------------------------------
  68 #
  69 # Boost
  70 #
  71
  72 get_filename_component (BOOST_ROOT ../../ ABSOLUTE)
  73
  74 # VFALCO I want static but "b2 stage" builds a minimal set which excludes static
  75 add_definitions (-DBOOST_ALL_STATIC_LINK=1)
  76
  77 # Some of the tests use deprecated APIs
  78 #add_definitions (-DBOOST_ASIO_NO_DEPRECATED=1)
  79
  80 add_definitions (-DBOOST_ASIO_DISABLE_BOOST_ARRAY=1)
  81 add_definitions (-DBOOST_ASIO_DISABLE_BOOST_BIND=1)
  82 add_definitions (-DBOOST_ASIO_DISABLE_BOOST_DATE_TIME=1)
  83 add_definitions (-DBOOST_ASIO_DISABLE_BOOST_REGEX=1)
  84 add_definitions (-DBOOST_COROUTINES_NO_DEPRECATION_WARNING=1)
  85
  86 include_directories (${BOOST_ROOT})
  87
  88 link_directories(${BOOST_ROOT}/stage/lib)
  89
  90 if (MINGW)
  91     link_libraries(ws2_32 mswsock)
  92 endif()
  93
  94 #-------------------------------------------------------------------------------
  95 #
  96 # OpenSSL
  97 #
  98
  99 if (APPLE AND NOT DEFINED ENV{OPENSSL_ROOT_DIR})
 100   find_program(HOMEBREW brew)
 101   if (NOT HOMEBREW STREQUAL "HOMEBREW-NOTFOUND")
 102     execute_process(COMMAND brew --prefix openssl
 103       OUTPUT_VARIABLE OPENSSL_ROOT_DIR
 104       OUTPUT_STRIP_TRAILING_WHITESPACE)
 105   endif()
 106 endif()
 107
 108 find_package(OpenSSL)
 109
 110 if (OPENSSL_FOUND)
 111     add_definitions (-DBOOST_BEAST_USE_OPENSSL=1)
 112
 113 else()
 114     add_definitions (-DBOOST_BEAST_USE_OPENSSL=0)
 115     message("OpenSSL not found.")
 116 endif()
 117
 118 #
 119 #-------------------------------------------------------------------------------
 120
 121 function (DoGroupSources curdir rootdir folder)
 122     file (GLOB children RELATIVE ${PROJECT_SOURCE_DIR}/${curdir} ${PROJECT_SOURCE_DIR}/${curdir}/*)
 123     foreach (child ${children})
 124         if (IS_DIRECTORY ${PROJECT_SOURCE_DIR}/${curdir}/${child})
 125             DoGroupSources (${curdir}/${child} ${rootdir} ${folder})
 126         elseif (${child} STREQUAL "CMakeLists.txt")
 127             source_group("" FILES ${PROJECT_SOURCE_DIR}/${curdir}/${child})
 128         else()
 129             string (REGEX REPLACE ^${rootdir} ${folder} groupname ${curdir})
 130             string (REPLACE "/" "\\" groupname ${groupname})
 131             source_group (${groupname} FILES ${PROJECT_SOURCE_DIR}/${curdir}/${child})
 132         endif()
 133     endforeach()
 134 endfunction()
 135
 136 function (GroupSources curdir folder)
 137     DoGroupSources (${curdir} ${curdir} ${folder})
 138 endfunction()
 139
 140 #-------------------------------------------------------------------------------
 141
 142 if ("${VARIANT}" STREQUAL "coverage")
 143     if (MSVC)
 144     else()
 145         set (CMAKE_BUILD_TYPE DEBUG)
 146         set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -msse4.2 --coverage")
 147         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} --coverage")
 148     endif()
 149
 150 elseif ("${VARIANT}" STREQUAL "ubasan")
 151     if (MSVC)
 152     else()
 153         set (CMAKE_BUILD_TYPE RELWITHDEBINFO)
 154         set (CMAKE_CXX_FLAGS
 155           "${CMAKE_CXX_FLAGS} -DBOOST_BEAST_NO_SLOW_TESTS=1 -msse4.2 -funsigned-char -fno-omit-frame-pointer -fsanitize=address,undefined -fno-sanitize-recover=address,undefined -fsanitize-blacklist=${PROJECT_SOURCE_DIR}/tools/blacklist.supp")
 156         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fsanitize=address,undefined -fno-sanitize-recover=address,undefined")
 157     endif()
 158
 159 elseif ("${VARIANT}" STREQUAL "debug")
 160     set (CMAKE_BUILD_TYPE DEBUG)
 161
 162 elseif ("${VARIANT}" STREQUAL "release")
 163     set (CMAKE_BUILD_TYPE RELEASE)
 164
 165 endif()
 166
 167 #-------------------------------------------------------------------------------
 168 #
 169 # Tests and examples
 170 #
 171
 172 include_directories (.)
 173
 174 if (OPENSSL_FOUND)
 175     include_directories (${OPENSSL_INCLUDE_DIR})
 176 endif()
 177
 178 file (GLOB_RECURSE BOOST_BEAST_FILES
 179     ${PROJECT_SOURCE_DIR}/include/boost/beast/*.hpp
 180     ${PROJECT_SOURCE_DIR}/include/boost/beast/*.ipp
 181 )
 182
 183 file (GLOB_RECURSE COMMON_FILES
 184     ${PROJECT_SOURCE_DIR}/example/common/*.hpp
 185   )
 186
 187 if (Beast_BUILD_EXAMPLES AND
 188     (NOT "${VARIANT}" STREQUAL "coverage") AND
 189     (NOT "${VARIANT}" STREQUAL "ubasan"))
 190     add_subdirectory (example)
 191 endif()
 192
 193 if (Beast_BUILD_TESTS)
 194     add_subdirectory (test)
 195 endif()