ceph/src/boost/libs/context/src/asm/jump_arm64_aapcs_macho_gas.S

   1 /*******************************************************
   2  *                                                     *
   3  *  -------------------------------------------------  *
   4  *  |  0  |  1  |  2  |  3  |  4  |  5  |  6  |  7  |  *
   5  *  -------------------------------------------------  *
   6  *  | 0x0 | 0x4 | 0x8 | 0xc | 0x10| 0x14| 0x18| 0x1c|  *
   7  *  -------------------------------------------------  *
   8  *  |    x19    |    x20    |    x21    |    x22    |  *
   9  *  -------------------------------------------------  *
  10  *  -------------------------------------------------  *
  11  *  |  8  |  9  |  10 |  11 |  12 |  13 |  14 |  15 |  *
  12  *  -------------------------------------------------  *
  13  *  | 0x20| 0x24| 0x28| 0x2c| 0x30| 0x34| 0x38| 0x3c|  *
  14  *  -------------------------------------------------  *
  15  *  |    x23    |    x24    |    x25    |    x26    |  *
  16  *  -------------------------------------------------  *
  17  *  -------------------------------------------------  *
  18  *  |  16 |  17 |  18 |  19 |  20 |  21 |  22 |  23 |  *
  19  *  -------------------------------------------------  *
  20  *  | 0x40| 0x44| 0x48| 0x4c| 0x50| 0x54| 0x58| 0x5c|  *
  21  *  -------------------------------------------------  *
  22  *  |    x27    |    x28    |    FP     |     LR    |  *
  23  *  -------------------------------------------------  *
  24  *  -------------------------------------------------  *
  25  *  |  24 |  25 |  26 |  27 |  28 |  29 |  30 |  31 |  *
  26  *  -------------------------------------------------  *
  27  *  | 0x60| 0x64| 0x68| 0x6c| 0x70| 0x74| 0x78| 0x7c|  *
  28  *  -------------------------------------------------  *
  29  *  |     PC    |   align   |           |           |  *
  30  *  -------------------------------------------------  *
  31  *                                                     *
  32  *******************************************************/
  33
  34 .text
  35 .globl _jump_fcontext
  36 .balign 16
  37 _jump_fcontext:
  38     ; prepare stack for GP + FPU
  39     sub  sp, sp, #0x70
  40
  41     ; save x19-x30
  42     stp  x19, x20, [sp, #0x00]
  43     stp  x21, x22, [sp, #0x10]
  44     stp  x23, x24, [sp, #0x20]
  45     stp  x25, x26, [sp, #0x30]
  46     stp  x27, x28, [sp, #0x40]
  47     stp  fp,  lr,  [sp, #0x50]
  48
  49     ; save LR as PC
  50     str  lr, [sp, #0x60]
  51
  52     ; store RSP (pointing to context-data) in X0
  53     mov  x4, sp
  54
  55     ; restore RSP (pointing to context-data) from X1
  56     mov  sp, x0
  57
  58     ; load x19-x30
  59     ldp  x19, x20, [sp, #0x00]
  60     ldp  x21, x22, [sp, #0x10]
  61     ldp  x23, x24, [sp, #0x20]
  62     ldp  x25, x26, [sp, #0x30]
  63     ldp  x27, x28, [sp, #0x40]
  64     ldp  fp,  lr,  [sp, #0x50]
  65
  66     ; return transfer_t from jump
  67     ; pass transfer_t as first arg in context function
  68     ; X0 == FCTX, X1 == DATA
  69     mov x0, x4
  70
  71     ; load pc
  72     ldr  x4, [sp, #0x60]
  73
  74     ; restore stack from GP + FPU
  75     add  sp, sp, #0x70
  76
  77     ret x4