ceph/src/boost/libs/context/src/asm/jump_arm_aapcs_elf_gas.S

   1 /*
   2             Copyright Oliver Kowalke 2009.
   3    Distributed under the Boost Software License, Version 1.0.
   4       (See accompanying file LICENSE_1_0.txt or copy at
   5           http://www.boost.org/LICENSE_1_0.txt)
   6 */
   7
   8 /*******************************************************
   9  *                                                     *
  10  *  -------------------------------------------------  *
  11  *  |  0  |  1  |  2  |  3  |  4  |  5  |  6  |  7  |  *
  12  *  -------------------------------------------------  *
  13  *  | 0x0 | 0x4 | 0x8 | 0xc | 0x10| 0x14| 0x18| 0x1c|  *
  14  *  -------------------------------------------------  *
  15  *  | s16 | s17 | s18 | s19 | s20 | s21 | s22 | s23 |  *
  16  *  -------------------------------------------------  *
  17  *  -------------------------------------------------  *
  18  *  |  8  |  9  |  10 |  11 |  12 |  13 |  14 |  15 |  *
  19  *  -------------------------------------------------  *
  20  *  | 0x20| 0x24| 0x28| 0x2c| 0x30| 0x34| 0x38| 0x3c|  *
  21  *  -------------------------------------------------  *
  22  *  | s24 | s25 | s26 | s27 | s28 | s29 | s30 | s31 |  *
  23  *  -------------------------------------------------  *
  24  *  -------------------------------------------------  *
  25  *  |  16 |  17 |  18 |  19 |  20 |  21 |  22 |  23 |  *
  26  *  -------------------------------------------------  *
  27  *  | 0x40| 0x44| 0x48| 0x4c| 0x50| 0x54| 0x58| 0x5c|  *
  28  *  -------------------------------------------------  *
  29  *  |hiddn|  v1 |  v2 |  v3 |  v4 |  v5 |  v6 |  v7 |  *
  30  *  -------------------------------------------------  *
  31  *  -------------------------------------------------  *
  32  *  |  24 |  25 |  26 |  27 |  28 |  29 |  30 |  31 |  *
  33  *  -------------------------------------------------  *
  34  *  | 0x60| 0x64| 0x68| 0x6c| 0x70| 0x74| 0x78| 0x7c|  *
  35  *  -------------------------------------------------  *
  36  *  |  v8 |  lr |  pc | FCTX| DATA|                 |  *
  37  *  -------------------------------------------------  *
  38  *                                                     *
  39  *******************************************************/
  40
  41 .text
  42 .globl jump_fcontext
  43 .align 2
  44 .type jump_fcontext,%function
  45 jump_fcontext:
  46     @ save LR as PC
  47     push {lr}
  48     @ save hidden,V1-V8,LR
  49     push {a1,v1-v8,lr}
  50
  51     @ prepare stack for FPU
  52     sub  sp, sp, #64
  53 #if (defined(__VFP_FP__) && !defined(__SOFTFP__))
  54     @ save S16-S31
  55     vstmia sp, {d8-d15}
  56 #endif
  57
  58     @ store RSP (pointing to context-data) in A1
  59     mov  a1, sp
  60
  61     @ restore RSP (pointing to context-data) from A2
  62     mov  sp, a2
  63
  64 #if (defined(__VFP_FP__) && !defined(__SOFTFP__))
  65     @ restore S16-S31
  66     vldmia  sp, {d8-d15}
  67 #endif
  68     @ prepare stack for FPU
  69     add  sp, sp, #64
  70
  71     @ restore hidden,V1-V8,LR
  72     pop {a4,v1-v8,lr}
  73
  74     @ return transfer_t from jump
  75     str  a1, [a4, #0]
  76     str  a3, [a4, #4]
  77     @ pass transfer_t as first arg in context function
  78     @ A1 == FCTX, A2 == DATA
  79     mov  a2, a3
  80
  81     @ restore PC
  82     pop {pc}
  83 .size jump_fcontext,.-jump_fcontext
  84
  85 @ Mark that we don't need executable stack.
  86 .section .note.GNU-stack,"",%progbits