ceph/src/boost/libs/context/src/asm/jump_ppc32_sysv_macho_gas.S

   1 /*
   2             Copyright Oliver Kowalke 2009.
   3    Distributed under the Boost Software License, Version 1.0.
   4       (See accompanying file LICENSE_1_0.txt or copy at
   5           http://www.boost.org/LICENSE_1_0.txt)
   6 */
   7
   8 /*******************************************************
   9  *                                                     *
  10  *  -------------------------------------------------  *
  11  *  |  0  |  1  |  2  |  3  |  4  |  5  |  6  |  7  |  *
  12  *  -------------------------------------------------  *
  13  *  |  0  |  4  |  8  |  12 |  16 |  20 |  24 |  28 |  *
  14  *  -------------------------------------------------  *
  15  *  | R13 | R14 | R15 | R16 | R17 | R18 | R19 | R20 |  *
  16  *  -------------------------------------------------  *
  17  *  -------------------------------------------------  *
  18  *  |  8  |  9  |  10 |  11 |  12 |  13 |  14 |  15 |  *
  19  *  -------------------------------------------------  *
  20  *  |  32 |  36 |  40 |  44 |  48 |  52 |  56 |  60 |  *
  21  *  -------------------------------------------------  *
  22  *  | R21 | R22 | R23 | R24 | R25 | R26 | R27 | R28 |  *
  23  *  -------------------------------------------------  *
  24  *  -------------------------------------------------  *
  25  *  |  16 |  17 |  18 |  19 |  20 |  21 |  22 |  23 |  *
  26  *  -------------------------------------------------  *
  27  *  |  64 |  68 |  72 |  76 |  80 |  84 |  88 |  92 |  *
  28  *  -------------------------------------------------  *
  29  *  | R29 | R30 | R31 |hiddn|  CR |  LR |  PC | FCTX|  *
  30  *  -------------------------------------------------  *
  31  *  -------------------------------------------------  *
  32  *  |  24 |  25 |  26 |  27 |  28 |  29 |  30 |  31 |  *
  33  *  -------------------------------------------------  *
  34  *  |  96 | 100 | 104 | 108 | 112 | 116 | 120 | 124 |  *
  35  *  -------------------------------------------------  *
  36  *  | DATA|     |     |     |                       |  *
  37  *  -------------------------------------------------  *
  38  *                                                     *
  39  *******************************************************/
  40
  41 .text
  42 .globl _jump_fcontext
  43 .align 2
  44 _jump_fcontext:
  45     ; reserve space on stack
  46     subi  r1, r1, 92
  47
  48     stw  r13, 0(r1)  # save R13
  49     stw  r14, 4(r1)  # save R14
  50     stw  r15, 8(r1)  # save R15
  51     stw  r16, 12(r1)  # save R16
  52     stw  r17, 16(r1)  # save R17
  53     stw  r18, 20(r1)  # save R18
  54     stw  r19, 24(r1)  # save R19
  55     stw  r20, 28(r1)  # save R20
  56     stw  r21, 32(r1)  # save R21
  57     stw  r22, 36(r1)  # save R22
  58     stw  r23, 40(r1)  # save R23
  59     stw  r24, 44(r1)  # save R24
  60     stw  r25, 48(r1)  # save R25
  61     stw  r26, 52(r1)  # save R26
  62     stw  r27, 56(r1)  # save R27
  63     stw  r28, 60(r1)  # save R28
  64     stw  r29, 64(r1)  # save R29
  65     stw  r30, 68(r1)  # save R30
  66     stw  r31, 72(r1)  # save R31
  67     stw  r3,  76(r1)  # save hidden
  68
  69     # save CR
  70     mfcr  r0
  71     stw  r0, 80(r1)
  72     # save LR
  73     mflr  r0
  74     stw  r0, 84(r1)
  75     # save LR as PC
  76     stw  r0, 88(r1)
  77
  78     # store RSP (pointing to context-data) in R6
  79     mr  r6, r1
  80
  81     # restore RSP (pointing to context-data) from R4
  82     mr  r1, r4
  83
  84     lwz  r13, 0(r1)  # restore R13
  85     lwz  r14, 4(r1)  # restore R14
  86     lwz  r15, 8(r1)  # restore R15
  87     lwz  r16, 12(r1)  # restore R16
  88     lwz  r17, 16(r1)  # restore R17
  89     lwz  r18, 20(r1)  # restore R18
  90     lwz  r19, 24(r1)  # restore R19
  91     lwz  r20, 28(r1)  # restore R20
  92     lwz  r21, 32(r1)  # restore R21
  93     lwz  r22, 36(r1)  # restore R22
  94     lwz  r23, 40(r1)  # restore R23
  95     lwz  r24, 44(r1)  # restore R24
  96     lwz  r25, 48(r1)  # restore R25
  97     lwz  r26, 52(r1)  # restore R26
  98     lwz  r27, 56(r1)  # restore R27
  99     lwz  r28, 60(r1)  # restore R28
 100     lwz  r29, 64(r1)  # restore R29
 101     lwz  r30, 68(r1)  # restore R30
 102     lwz  r31, 72(r1)  # restore R31
 103     lwz  r3,  76(r1)  # restore hidden
 104
 105     # restore CR
 106     lwz  r0, 80(r1)
 107     mtcr  r0
 108     # restore LR
 109     lwz  r0, 84(r1)
 110     mtlr  r0
 111
 112     # load PC
 113     lwz  r0, 88(r1)
 114     # restore CTR
 115     mtctr  r0
 116
 117     # adjust stack
 118     addi  r1, r1, 92
 119
 120     # return transfer_t
 121     stw  r6, 0(r3)
 122     stw  r5, 4(r3)
 123
 124     # jump to context
 125     bctr