ceph/src/boost/libs/context/src/asm/make_arm_aapcs_elf_gas.S

   1 /*
   2             Copyright Oliver Kowalke 2009.
   3    Distributed under the Boost Software License, Version 1.0.
   4       (See accompanying file LICENSE_1_0.txt or copy at
   5           http://www.boost.org/LICENSE_1_0.txt)
   6 */
   7
   8 /*******************************************************
   9  *                                                     *
  10  *  -------------------------------------------------  *
  11  *  |  0  |  1  |  2  |  3  |  4  |  5  |  6  |  7  |  *
  12  *  -------------------------------------------------  *
  13  *  | 0x0 | 0x4 | 0x8 | 0xc | 0x10| 0x14| 0x18| 0x1c|  *
  14  *  -------------------------------------------------  *
  15  *  |hiddn|  v1 |  v2 |  v3 |  v4 |  v5 |  v6 |  v7 |  *
  16  *  -------------------------------------------------  *
  17  *  -------------------------------------------------  *
  18  *  |  8  |  9  |  10 |  11 |  12 |  13 |  14 |  15 |  *
  19  *  -------------------------------------------------  *
  20  *  | 0x20| 0x24| 0x28| 0x2c| 0x30| 0x34| 0x38| 0x3c|  *
  21  *  -------------------------------------------------  *
  22  *  |  v8 |  lr |  pc | FCTX| DATA|                 |  *
  23  *  -------------------------------------------------  *
  24  *                                                     *
  25  *******************************************************/
  26
  27 .text
  28 .globl make_fcontext
  29 .align 2
  30 .type make_fcontext,%function
  31 make_fcontext:
  32     @ shift address in A1 to lower 16 byte boundary
  33     bic  a1, a1, #15
  34
  35     @ reserve space for context-data on context-stack
  36     sub  a1, a1, #60
  37
  38     @ third arg of make_fcontext() == address of context-function
  39     str  a3, [a1, #40]
  40
  41     @ compute address of returned transfer_t
  42     add  a2, a1, #44
  43     mov  a3, a2
  44     str  a3, [a1, #0]
  45
  46     @ compute abs address of label finish
  47     adr  a2, finish
  48     @ save address of finish as return-address for context-function
  49     @ will be entered after context-function returns
  50     str  a2, [a1, #36]
  51
  52     bx  lr @ return pointer to context-data
  53
  54 finish:
  55     @ exit code is zero
  56     mov  a1, #0
  57     @ exit application
  58     bl  _exit@PLT
  59 .size make_fcontext,.-make_fcontext
  60
  61 @ Mark that we don't need executable stack.
  62 .section .note.GNU-stack,"",%progbits