ceph/src/boost/libs/context/src/asm/ontop_arm_aapcs_elf_gas.S

   1 /*
   2             Copyright Oliver Kowalke 2009.
   3    Distributed under the Boost Software License, Version 1.0.
   4       (See accompanying file LICENSE_1_0.txt or copy at
   5           http://www.boost.org/LICENSE_1_0.txt)
   6 */
   7
   8 /*******************************************************
   9  *                                                     *
  10  *  -------------------------------------------------  *
  11  *  |  0  |  1  |  2  |  3  |  4  |  5  |  6  |  7  |  *
  12  *  -------------------------------------------------  *
  13  *  | 0x0 | 0x4 | 0x8 | 0xc | 0x10| 0x14| 0x18| 0x1c|  *
  14  *  -------------------------------------------------  *
  15  *  |hiddn|  v1 |  v2 |  v3 |  v4 |  v5 |  v6 |  v7 |  *
  16  *  -------------------------------------------------  *
  17  *  -------------------------------------------------  *
  18  *  |  8  |  9  |  10 |  11 |  12 |  13 |  14 |  15 |  *
  19  *  -------------------------------------------------  *
  20  *  | 0x20| 0x24| 0x28| 0x2c| 0x30| 0x34| 0x38| 0x3c|  *
  21  *  -------------------------------------------------  *
  22  *  |  v8 |  lr |  pc | FCTX| DATA|                 |  *
  23  *  -------------------------------------------------  *
  24  *                                                     *
  25  *******************************************************/
  26
  27 .text
  28 .globl ontop_fcontext
  29 .align 2
  30 .type ontop_fcontext,%function
  31 ontop_fcontext:
  32     @ save LR as PC
  33     push {lr}
  34     @ save hidden,V1-V8,LR
  35     push {a1,v1-v8,lr}
  36
  37     @ store RSP (pointing to context-data) in A1
  38     mov  a1, sp
  39
  40     @ restore RSP (pointing to context-data) from A2
  41     mov  sp, a2
  42
  43     @ store parent context in A2
  44     mov  a2, a1
  45
  46     @ restore hidden,V1-V8,LR
  47     pop {a1,v1-v8,lr}
  48
  49     @ return transfer_t from jump
  50     str  a2, [a1, #0]
  51     str  a3, [a1, #4]
  52     @ pass transfer_t as first arg in context function
  53     @ A1 == hidden, A2 == FCTX, A3 == DATA
  54
  55     @ skip PC
  56     add  sp, sp, #4
  57
  58     @ jump to ontop-function
  59     bx  a4
  60 .size ontop_fcontext,.-ontop_fcontext
  61
  62 @ Mark that we don't need executable stack.
  63 .section .note.GNU-stack,"",%progbits