ceph/src/boost/tools/cmake/test/boost_test/CMakeLists.txt

   1 # Copyright 2018, 2019 Peter Dimov
   2 # Distributed under the Boost Software License, Version 1.0.
   3 # See accompanying file LICENSE_1_0.txt or copy at http://www.boost.org/LICENSE_1_0.txt
   4
   5 cmake_minimum_required(VERSION 3.5...3.16)
   6
   7 project(boost_cmake_test LANGUAGES CXX)
   8
   9 include(CTest)
  10
  11 set(BUILD_TESTING OFF) # hide cache variable
  12
  13 add_subdirectory(../../../../libs/assert EXCLUDE_FROM_ALL boostorg/assert)
  14 add_subdirectory(../../../../libs/config EXCLUDE_FROM_ALL boostorg/config)
  15 add_subdirectory(../../../../libs/core EXCLUDE_FROM_ALL boostorg/core)
  16
  17 unset(BUILD_TESTING)
  18
  19 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../../include)
  20
  21 # boost_test
  22
  23 include(BoostTest)
  24
  25 boost_test(TYPE compile SOURCES compile.cpp)
  26 boost_test(TYPE compile-fail SOURCES compile_fail.cpp)
  27 boost_test(TYPE link SOURCES link.cpp)
  28 boost_test(TYPE link-fail SOURCES link_fail.cpp)
  29 boost_test(TYPE run SOURCES run.cpp)
  30 boost_test(TYPE run-fail SOURCES run_fail.cpp)
  31
  32 boost_test(TYPE run SOURCES arguments.cpp ARGUMENTS pumpkin LINK_LIBRARIES Boost::core)
  33
  34 boost_test(TYPE run NAME return_exit_code_pass SOURCES return_exit_code.cpp COMPILE_DEFINITIONS EXIT_CODE=0)
  35 boost_test(TYPE run-fail NAME return_exit_code_fail SOURCES return_exit_code.cpp COMPILE_DEFINITIONS EXIT_CODE=1)
  36
  37 boost_test(TYPE run SOURCES requires_variadic_templates.cpp COMPILE_FEATURES cxx_variadic_templates)
  38
  39 boost_test(TYPE run SOURCES requires_no_rtti.cpp COMPILE_OPTIONS -fno-rtti LINK_LIBRARIES Boost::config)
  40 boost_test(TYPE run SOURCES requires_no_exceptions.cpp COMPILE_OPTIONS -fno-exceptions LINK_LIBRARIES Boost::config)
  41
  42 boost_test(TYPE compile-fail SOURCES emits_warning.cpp COMPILE_OPTIONS -Wall -Werror)
  43
  44 # boost_test, w/ globals
  45
  46 set(BOOST_TEST_COMPILE_OPTIONS -fno-rtti -fno-exceptions)
  47 set(BOOST_TEST_LINK_LIBRARIES Boost::config)
  48
  49 boost_test(SOURCES requires_no_rtti.cpp PREFIX boost_cmake_test_globals)
  50 boost_test(SOURCES requires_no_exceptions.cpp PREFIX boost_cmake_test_globals)
  51
  52 # boost_test_jamfile
  53
  54 include(BoostTestJamfile)
  55
  56 boost_test_jamfile(FILE Jamfile PREFIX boost_cmake_test_jamfile)