ceph/src/jaegertracing/opentelemetry-cpp/exporters/elasticsearch/CMakeLists.txt

   1 add_library(opentelemetry_exporter_elasticsearch_logs src/es_log_exporter.cc)
   2
   3 set_target_properties(opentelemetry_exporter_elasticsearch_logs
   4                       PROPERTIES EXPORT_NAME elasticsearch_log_exporter)
   5
   6 target_include_directories(
   7   opentelemetry_exporter_elasticsearch_logs
   8   PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}/include>"
   9          "$<INSTALL_INTERFACE:include>")
  10
  11 target_link_libraries(
  12   opentelemetry_exporter_elasticsearch_logs
  13   PUBLIC opentelemetry_trace opentelemetry_logs opentelemetry_http_client_curl
  14          nlohmann_json::nlohmann_json)
  15
  16 install(
  17   TARGETS opentelemetry_exporter_elasticsearch_logs
  18   EXPORT "${PROJECT_NAME}-target"
  19   RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
  20   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
  21   ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})
  22
  23 install(
  24   DIRECTORY include/opentelemetry/exporters/elasticsearch
  25   DESTINATION include/opentelemetry/exporters
  26   FILES_MATCHING
  27   PATTERN "*.h"
  28   PATTERN "es_log_recordable.h" EXCLUDE)
  29
  30 if(BUILD_TESTING)
  31   add_executable(es_log_exporter_test test/es_log_exporter_test.cc)
  32
  33   target_link_libraries(
  34     es_log_exporter_test ${GTEST_BOTH_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT}
  35     opentelemetry_exporter_elasticsearch_logs)
  36
  37   gtest_add_tests(
  38     TARGET es_log_exporter_test
  39     TEST_PREFIX exporter.
  40     TEST_LIST es_log_exporter_test)
  41 endif() # BUILD_TESTING