ceph/src/jaegertracing/opentelemetry-cpp/exporters/etw/CMakeLists.txt

   1 add_library(opentelemetry_exporter_etw INTERFACE)
   2
   3 target_include_directories(
   4   opentelemetry_exporter_etw
   5   INTERFACE "$<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}/include>"
   6             "$<INSTALL_INTERFACE:include>")
   7
   8 set_target_properties(opentelemetry_exporter_etw PROPERTIES EXPORT_NAME
   9                                                             etw_exporter)
  10
  11 target_link_libraries(opentelemetry_exporter_etw
  12                       INTERFACE nlohmann_json::nlohmann_json)
  13 if(nlohmann_json_clone)
  14   add_dependencies(opentelemetry_exporter_etw nlohmann_json::nlohmann_json)
  15 endif()
  16
  17 install(
  18   TARGETS opentelemetry_exporter_etw
  19   EXPORT "${PROJECT_NAME}-target"
  20   RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
  21   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
  22   ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})
  23
  24 install(
  25   DIRECTORY include/opentelemetry/exporters/etw
  26   DESTINATION include/opentelemetry/exporters
  27   FILES_MATCHING
  28   PATTERN "*.h")
  29
  30 if(BUILD_TESTING)
  31   add_executable(etw_provider_test test/etw_provider_test.cc)
  32   add_executable(etw_tracer_test test/etw_tracer_test.cc)
  33   add_executable(etw_logger_test test/etw_logger_test.cc)
  34
  35   add_executable(etw_perf_test test/etw_perf_test.cc)
  36
  37   target_link_libraries(etw_provider_test ${GTEST_BOTH_LIBRARIES}
  38                         opentelemetry_exporter_etw ${CMAKE_THREAD_LIBS_INIT})
  39
  40   target_link_libraries(etw_tracer_test ${GTEST_BOTH_LIBRARIES}
  41                         opentelemetry_exporter_etw ${CMAKE_THREAD_LIBS_INIT})
  42
  43   target_link_libraries(etw_logger_test ${GTEST_BOTH_LIBRARIES}
  44                         opentelemetry_exporter_etw ${CMAKE_THREAD_LIBS_INIT})
  45
  46   target_link_libraries(
  47     etw_perf_test benchmark::benchmark ${GTEST_BOTH_LIBRARIES}
  48     opentelemetry_exporter_etw ${CMAKE_THREAD_LIBS_INIT})
  49
  50   gtest_add_tests(
  51     TARGET etw_provider_test
  52     TEST_PREFIX exporter.
  53     TEST_LIST etw_provider_test)
  54   gtest_add_tests(
  55     TARGET etw_tracer_test
  56     TEST_PREFIX exporter.
  57     TEST_LIST etw_tracer_test)
  58   gtest_add_tests(
  59     TARGET etw_logger_test
  60     TEST_PREFIX exporter.
  61     TEST_LIST etw_logger_test)
  62
  63 endif() # BUILD_TESTING