ceph/src/jaegertracing/opentelemetry-cpp/exporters/jaeger/CMakeLists.txt

   1 include_directories(thrift-gen)
   2
   3 find_package(Thrift REQUIRED)
   4 # vcpkg config recipe points to THRIFT_INCLUDE_DIR=...\thrift . Ensure that the
   5 # include dir for thrift-gen code is 1 level-up from that:
   6 include_directories(SYSTEM ${THRIFT_INCLUDE_DIR}/..)
   7
   8 set(JAEGER_THRIFT_GENCPP_SOURCES
   9     thrift-gen/Agent.cpp thrift-gen/jaeger_types.cpp thrift-gen/Collector.cpp
  10     thrift-gen/zipkincore_types.cpp)
  11
  12 set(JAEGER_EXPORTER_SOURCES
  13     src/jaeger_exporter.cc
  14     src/thrift_sender.cc
  15     src/udp_transport.cc
  16     src/recordable.cc
  17     src/TUDPTransport.cc
  18     src/http_transport.cc
  19     src/THttpTransport.cc)
  20
  21 add_library(opentelemetry_exporter_jaeger_trace ${JAEGER_EXPORTER_SOURCES}
  22                                                 ${JAEGER_THRIFT_GENCPP_SOURCES})
  23
  24 set_target_properties(opentelemetry_exporter_jaeger_trace
  25                       PROPERTIES EXPORT_NAME jaeger_trace_exporter)
  26
  27 target_include_directories(
  28   opentelemetry_exporter_jaeger_trace
  29   PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}/include>"
  30          "$<INSTALL_INTERFACE:include>")
  31
  32 target_link_libraries(
  33   opentelemetry_exporter_jaeger_trace
  34   PUBLIC opentelemetry_resources opentelemetry_http_client_curl
  35   PRIVATE thrift::thrift)
  36
  37 if(MSVC)
  38   target_compile_definitions(opentelemetry_exporter_jaeger_trace
  39                              PUBLIC NOMINMAX)
  40   if(NOT BUILD_SHARED_LIBS)
  41     target_compile_definitions(opentelemetry_exporter_jaeger_trace
  42                                PUBLIC THRIFT_STATIC_DEFINE)
  43   endif()
  44 endif()
  45
  46 install(
  47   TARGETS opentelemetry_exporter_jaeger_trace
  48   EXPORT "${PROJECT_NAME}-target"
  49   RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
  50   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
  51   ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})
  52
  53 install(
  54   DIRECTORY include/opentelemetry/exporters/jaeger
  55   DESTINATION include/opentelemetry/exporters
  56   FILES_MATCHING
  57   PATTERN "*.h"
  58   PATTERN "recordable.h" EXCLUDE)
  59
  60 if(BUILD_TESTING)
  61   add_definitions(-DGTEST_LINKED_AS_SHARED_LIBRARY=1)
  62
  63   add_executable(jaeger_recordable_test test/jaeger_recordable_test.cc)
  64   target_link_libraries(
  65     jaeger_recordable_test ${GTEST_BOTH_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT}
  66     opentelemetry_exporter_jaeger_trace)
  67
  68   gtest_add_tests(
  69     TARGET jaeger_recordable_test
  70     TEST_PREFIX exporter.
  71     TEST_LIST jaeger_recordable_test)
  72
  73   add_executable(jaeger_exporter_test test/jaeger_exporter_test.cc)
  74   if(MSVC)
  75     if(GMOCK_LIB)
  76       unset(GMOCK_LIB CACHE)
  77     endif()
  78   endif()
  79   if(MSVC AND CMAKE_BUILD_TYPE STREQUAL "Debug")
  80     find_library(GMOCK_LIB gmockd PATH_SUFFIXES lib)
  81   else()
  82     find_library(GMOCK_LIB gmock PATH_SUFFIXES lib)
  83   endif()
  84   target_link_libraries(
  85     jaeger_exporter_test ${GTEST_BOTH_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT}
  86     ${GMOCK_LIB} opentelemetry_trace opentelemetry_exporter_jaeger_trace)
  87
  88   target_include_directories(jaeger_exporter_test
  89                              PRIVATE ${CMAKE_CURRENT_LIST_DIR}/src)
  90
  91   gtest_add_tests(
  92     TARGET jaeger_exporter_test
  93     TEST_PREFIX exporter.
  94     TEST_LIST jaeger_exporter_test)
  95 endif() # BUILD_TESTING