ceph/src/jaegertracing/opentelemetry-cpp/exporters/ostream/CMakeLists.txt

   1 add_library(opentelemetry_exporter_ostream_span src/span_exporter.cc)
   2
   3 set_target_properties(opentelemetry_exporter_ostream_span
   4                       PROPERTIES EXPORT_NAME ostream_span_exporter)
   5
   6 target_include_directories(
   7   opentelemetry_exporter_ostream_span
   8   PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}/include>")
   9
  10 target_link_libraries(opentelemetry_exporter_ostream_span
  11                       PUBLIC opentelemetry_trace)
  12
  13 install(
  14   TARGETS opentelemetry_exporter_ostream_span
  15   EXPORT "${PROJECT_NAME}-target"
  16   RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
  17   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
  18   ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})
  19
  20 install(
  21   DIRECTORY include/opentelemetry/exporters/ostream
  22   DESTINATION include/opentelemetry/exporters
  23   PATTERN "*.h"
  24   PATTERN "metrics_exporter.h" EXCLUDE
  25   PATTERN "log_Exporter.h" EXCLUDE)
  26
  27 if(BUILD_TESTING)
  28   add_executable(ostream_span_test test/ostream_span_test.cc)
  29   target_link_libraries(ostream_span_test ${GTEST_BOTH_LIBRARIES}
  30                         opentelemetry_exporter_ostream_span)
  31   gtest_add_tests(
  32     TARGET ostream_span_test
  33     TEST_PREFIX exporter.
  34     TEST_LIST ostream_span_test)
  35 endif() # BUILD_TESTING
  36
  37 if(WITH_METRICS_PREVIEW)
  38   add_library(opentelemetry_exporter_ostream_metrics_deprecated
  39               src/metrics_exporter.cc)
  40   set_target_properties(opentelemetry_exporter_ostream_metrics_deprecated
  41                         PROPERTIES EXPORT_NAME ostream_metrics_exporter)
  42   target_include_directories(
  43     opentelemetry_exporter_ostream_metrics_deprecated
  44     PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}/include>")
  45   target_link_libraries(opentelemetry_exporter_ostream_metrics_deprecated
  46                         PUBLIC opentelemetry_metrics_deprecated)
  47   install(
  48     TARGETS opentelemetry_exporter_ostream_metrics_deprecated
  49     EXPORT "${PROJECT_NAME}-target"
  50     RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
  51     LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
  52     ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})
  53   install(
  54     DIRECTORY include/opentelemetry/exporters/ostream
  55     DESTINATION include/opentelemetry/exporters
  56     PATTERN "metrics_exporter.h")
  57   if(BUILD_TESTING)
  58     add_executable(ostream_metrics_test test/ostream_metrics_test.cc)
  59     target_link_libraries(ostream_metrics_test ${GTEST_BOTH_LIBRARIES}
  60                           opentelemetry_exporter_ostream_metrics_deprecated)
  61     gtest_add_tests(
  62       TARGET ostream_metrics_test
  63       TEST_PREFIX exporter.
  64       TEST_LIST ostream_metrics_test)
  65   endif()
  66 else()
  67   add_library(opentelemetry_exporter_ostream_metrics src/metric_exporter.cc)
  68   set_target_properties(opentelemetry_exporter_ostream_metrics
  69                         PROPERTIES EXPORT_NAME ostream_metrics_exporter)
  70   target_include_directories(
  71     opentelemetry_exporter_ostream_metrics
  72     PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}/include>")
  73   target_link_libraries(opentelemetry_exporter_ostream_metrics
  74                         PUBLIC opentelemetry_metrics)
  75   install(
  76     TARGETS opentelemetry_exporter_ostream_metrics
  77     EXPORT "${PROJECT_NAME}-target"
  78     RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
  79     LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
  80     ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})
  81   install(
  82     DIRECTORY include/opentelemetry/exporters/ostream
  83     DESTINATION include/opentelemetry/exporters
  84     PATTERN "metric_exporter.h")
  85   if(BUILD_TESTING)
  86     add_executable(ostream_metric_test test/ostream_metric_test.cc)
  87     target_link_libraries(
  88       ostream_metric_test ${GTEST_BOTH_LIBRARIES}
  89       opentelemetry_exporter_ostream_metrics opentelemetry_resources)
  90     gtest_add_tests(
  91       TARGET ostream_metric_test
  92       TEST_PREFIX exporter.
  93       TEST_LIST ostream_metric_test)
  94   endif()
  95 endif()
  96
  97 if(WITH_LOGS_PREVIEW)
  98   add_library(opentelemetry_exporter_ostream_logs src/log_exporter.cc)
  99   set_target_properties(opentelemetry_exporter_ostream_logs
 100                         PROPERTIES EXPORT_NAME ostream_log_exporter)
 101   target_include_directories(
 102     opentelemetry_exporter_ostream_logs
 103     PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}/include>")
 104   target_link_libraries(opentelemetry_exporter_ostream_logs
 105                         PUBLIC opentelemetry_logs)
 106   install(
 107     TARGETS opentelemetry_exporter_ostream_logs
 108     EXPORT "${PROJECT_NAME}-target"
 109     RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 110     LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 111     ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})
 112   install(
 113     DIRECTORY include/opentelemetry/exporters/ostream
 114     DESTINATION include/opentelemetry/exporters
 115     PATTERN "log_exporter.h")
 116   if(BUILD_TESTING)
 117     add_executable(ostream_log_test test/ostream_log_test.cc)
 118     target_link_libraries(ostream_log_test ${GTEST_BOTH_LIBRARIES}
 119                           opentelemetry_exporter_ostream_logs)
 120     gtest_add_tests(
 121       TARGET ostream_log_test
 122       TEST_PREFIX exporter.
 123       TEST_LIST ostream_log_test)
 124   endif()
 125 endif()