ceph/src/jaegertracing/opentelemetry-cpp/third_party/googletest/googletest/CMakeLists.txt

   1 ########################################################################
   2 # Note: CMake support is community-based. The maintainers do not use CMake
   3 # internally.
   4 #
   5 # CMake build script for Google Test.
   6 #
   7 # To run the tests for Google Test itself on Linux, use 'make test' or
   8 # ctest.  You can select which tests to run using 'ctest -R regex'.
   9 # For more options, run 'ctest --help'.
  10
  11 # When other libraries are using a shared version of runtime libraries,
  12 # Google Test also has to use one.
  13 option(
  14   gtest_force_shared_crt
  15   "Use shared (DLL) run-time lib even when Google Test is built as static lib."
  16   OFF)
  17
  18 option(gtest_build_tests "Build all of gtest's own tests." OFF)
  19
  20 option(gtest_build_samples "Build gtest's sample programs." OFF)
  21
  22 option(gtest_disable_pthreads "Disable uses of pthreads in gtest." OFF)
  23
  24 option(
  25   gtest_hide_internal_symbols
  26   "Build gtest with internal symbols hidden in shared libraries."
  27   OFF)
  28
  29 # Defines pre_project_set_up_hermetic_build() and set_up_hermetic_build().
  30 include(cmake/hermetic_build.cmake OPTIONAL)
  31
  32 if (COMMAND pre_project_set_up_hermetic_build)
  33   pre_project_set_up_hermetic_build()
  34 endif()
  35
  36 ########################################################################
  37 #
  38 # Project-wide settings
  39
  40 # Name of the project.
  41 #
  42 # CMake files in this project can refer to the root source directory
  43 # as ${gtest_SOURCE_DIR} and to the root binary directory as
  44 # ${gtest_BINARY_DIR}.
  45 # Language "C" is required for find_package(Threads).
  46
  47 # Project version:
  48
  49 if (CMAKE_VERSION VERSION_LESS 3.0)
  50   project(gtest CXX C)
  51   set(PROJECT_VERSION ${GOOGLETEST_VERSION})
  52 else()
  53   cmake_policy(SET CMP0048 NEW)
  54   project(gtest VERSION ${GOOGLETEST_VERSION} LANGUAGES CXX C)
  55 endif()
  56 cmake_minimum_required(VERSION 2.6.4)
  57
  58 if (POLICY CMP0063) # Visibility
  59   cmake_policy(SET CMP0063 NEW)
  60 endif (POLICY CMP0063)
  61
  62 if (COMMAND set_up_hermetic_build)
  63   set_up_hermetic_build()
  64 endif()
  65
  66 # These commands only run if this is the main project
  67 if(CMAKE_PROJECT_NAME STREQUAL "gtest" OR CMAKE_PROJECT_NAME STREQUAL "googletest-distribution")
  68
  69   # BUILD_SHARED_LIBS is a standard CMake variable, but we declare it here to
  70   # make it prominent in the GUI.
  71   option(BUILD_SHARED_LIBS "Build shared libraries (DLLs)." OFF)
  72
  73 else()
  74
  75   mark_as_advanced(
  76     gtest_force_shared_crt
  77     gtest_build_tests
  78     gtest_build_samples
  79     gtest_disable_pthreads
  80     gtest_hide_internal_symbols)
  81
  82 endif()
  83
  84
  85 if (gtest_hide_internal_symbols)
  86   set(CMAKE_CXX_VISIBILITY_PRESET hidden)
  87   set(CMAKE_VISIBILITY_INLINES_HIDDEN 1)
  88 endif()
  89
  90 # Define helper functions and macros used by Google Test.
  91 include(cmake/internal_utils.cmake)
  92
  93 config_compiler_and_linker()  # Defined in internal_utils.cmake.
  94
  95 # Create the CMake package file descriptors.
  96 if (INSTALL_GTEST)
  97   include(CMakePackageConfigHelpers)
  98   set(cmake_package_name GTest)
  99   set(targets_export_name ${cmake_package_name}Targets CACHE INTERNAL "")
 100   set(generated_dir "${CMAKE_CURRENT_BINARY_DIR}/generated" CACHE INTERNAL "")
 101   set(cmake_files_install_dir "${CMAKE_INSTALL_LIBDIR}/cmake/${cmake_package_name}")
 102   set(version_file "${generated_dir}/${cmake_package_name}ConfigVersion.cmake")
 103   write_basic_package_version_file(${version_file} VERSION ${GOOGLETEST_VERSION} COMPATIBILITY AnyNewerVersion)
 104   install(EXPORT ${targets_export_name}
 105     NAMESPACE ${cmake_package_name}::
 106     DESTINATION ${cmake_files_install_dir})
 107   set(config_file "${generated_dir}/${cmake_package_name}Config.cmake")
 108   configure_package_config_file("${gtest_SOURCE_DIR}/cmake/Config.cmake.in"
 109     "${config_file}" INSTALL_DESTINATION ${cmake_files_install_dir})
 110   install(FILES ${version_file} ${config_file}
 111     DESTINATION ${cmake_files_install_dir})
 112 endif()
 113
 114 # Where Google Test's .h files can be found.
 115 set(gtest_build_include_dirs
 116   "${gtest_SOURCE_DIR}/include"
 117   "${gtest_SOURCE_DIR}")
 118 include_directories(${gtest_build_include_dirs})
 119
 120 ########################################################################
 121 #
 122 # Defines the gtest & gtest_main libraries.  User tests should link
 123 # with one of them.
 124
 125 # Google Test libraries.  We build them using more strict warnings than what
 126 # are used for other targets, to ensure that gtest can be compiled by a user
 127 # aggressive about warnings.
 128 cxx_library(gtest "${cxx_strict}" src/gtest-all.cc)
 129 set_target_properties(gtest PROPERTIES VERSION ${GOOGLETEST_VERSION})
 130 cxx_library(gtest_main "${cxx_strict}" src/gtest_main.cc)
 131 set_target_properties(gtest_main PROPERTIES VERSION ${GOOGLETEST_VERSION})
 132 # If the CMake version supports it, attach header directory information
 133 # to the targets for when we are part of a parent build (ie being pulled
 134 # in via add_subdirectory() rather than being a standalone build).
 135 if (DEFINED CMAKE_VERSION AND NOT "${CMAKE_VERSION}" VERSION_LESS "2.8.11")
 136   target_include_directories(gtest SYSTEM INTERFACE
 137     "$<BUILD_INTERFACE:${gtest_build_include_dirs}>"
 138     "$<INSTALL_INTERFACE:$<INSTALL_PREFIX>/${CMAKE_INSTALL_INCLUDEDIR}>")
 139   target_include_directories(gtest_main SYSTEM INTERFACE
 140     "$<BUILD_INTERFACE:${gtest_build_include_dirs}>"
 141     "$<INSTALL_INTERFACE:$<INSTALL_PREFIX>/${CMAKE_INSTALL_INCLUDEDIR}>")
 142 endif()
 143 target_link_libraries(gtest_main PUBLIC gtest)
 144
 145 ########################################################################
 146 #
 147 # Install rules
 148 install_project(gtest gtest_main)
 149
 150 ########################################################################
 151 #
 152 # Samples on how to link user tests with gtest or gtest_main.
 153 #
 154 # They are not built by default.  To build them, set the
 155 # gtest_build_samples option to ON.  You can do it by running ccmake
 156 # or specifying the -Dgtest_build_samples=ON flag when running cmake.
 157
 158 if (gtest_build_samples)
 159   cxx_executable(sample1_unittest samples gtest_main samples/sample1.cc)
 160   cxx_executable(sample2_unittest samples gtest_main samples/sample2.cc)
 161   cxx_executable(sample3_unittest samples gtest_main)
 162   cxx_executable(sample4_unittest samples gtest_main samples/sample4.cc)
 163   cxx_executable(sample5_unittest samples gtest_main samples/sample1.cc)
 164   cxx_executable(sample6_unittest samples gtest_main)
 165   cxx_executable(sample7_unittest samples gtest_main)
 166   cxx_executable(sample8_unittest samples gtest_main)
 167   cxx_executable(sample9_unittest samples gtest)
 168   cxx_executable(sample10_unittest samples gtest)
 169 endif()
 170
 171 ########################################################################
 172 #
 173 # Google Test's own tests.
 174 #
 175 # You can skip this section if you aren't interested in testing
 176 # Google Test itself.
 177 #
 178 # The tests are not built by default.  To build them, set the
 179 # gtest_build_tests option to ON.  You can do it by running ccmake
 180 # or specifying the -Dgtest_build_tests=ON flag when running cmake.
 181
 182 if (gtest_build_tests)
 183   # This must be set in the root directory for the tests to be run by
 184   # 'make test' or ctest.
 185   enable_testing()
 186
 187   if (WIN32)
 188     file(GENERATE OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIG>/RunTest.ps1"
 189          CONTENT
 190 "$project_bin = \"${CMAKE_BINARY_DIR}/bin/$<CONFIG>\"
 191 $env:Path = \"$project_bin;$env:Path\"
 192 & $args")
 193   elseif (MINGW OR CYGWIN)
 194     file(GENERATE OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/RunTest.ps1"
 195          CONTENT
 196 "$project_bin = (cygpath --windows ${CMAKE_BINARY_DIR}/bin)
 197 $env:Path = \"$project_bin;$env:Path\"
 198 & $args")
 199   endif()
 200
 201   ############################################################
 202   # C++ tests built with standard compiler flags.
 203
 204   cxx_test(googletest-death-test-test gtest_main)
 205   cxx_test(gtest_environment_test gtest)
 206   cxx_test(googletest-filepath-test gtest_main)
 207   cxx_test(googletest-listener-test gtest_main)
 208   cxx_test(gtest_main_unittest gtest_main)
 209   cxx_test(googletest-message-test gtest_main)
 210   cxx_test(gtest_no_test_unittest gtest)
 211   cxx_test(googletest-options-test gtest_main)
 212   cxx_test(googletest-param-test-test gtest
 213     test/googletest-param-test2-test.cc)
 214   cxx_test(googletest-port-test gtest_main)
 215   cxx_test(gtest_pred_impl_unittest gtest_main)
 216   cxx_test(gtest_premature_exit_test gtest
 217     test/gtest_premature_exit_test.cc)
 218   cxx_test(googletest-printers-test gtest_main)
 219   cxx_test(gtest_prod_test gtest_main
 220     test/production.cc)
 221   cxx_test(gtest_repeat_test gtest)
 222   cxx_test(gtest_sole_header_test gtest_main)
 223   cxx_test(gtest_stress_test gtest)
 224   cxx_test(googletest-test-part-test gtest_main)
 225   cxx_test(gtest_throw_on_failure_ex_test gtest)
 226   cxx_test(gtest-typed-test_test gtest_main
 227     test/gtest-typed-test2_test.cc)
 228   cxx_test(gtest_unittest gtest_main)
 229   cxx_test(gtest-unittest-api_test gtest)
 230   cxx_test(gtest_skip_in_environment_setup_test gtest_main)
 231   cxx_test(gtest_skip_test gtest_main)
 232
 233   ############################################################
 234   # C++ tests built with non-standard compiler flags.
 235
 236   # MSVC 7.1 does not support STL with exceptions disabled.
 237   if (NOT MSVC OR MSVC_VERSION GREATER 1310)
 238     cxx_library(gtest_no_exception "${cxx_no_exception}"
 239       src/gtest-all.cc)
 240     cxx_library(gtest_main_no_exception "${cxx_no_exception}"
 241       src/gtest-all.cc src/gtest_main.cc)
 242   endif()
 243   cxx_library(gtest_main_no_rtti "${cxx_no_rtti}"
 244     src/gtest-all.cc src/gtest_main.cc)
 245
 246   cxx_test_with_flags(gtest-death-test_ex_nocatch_test
 247     "${cxx_exception} -DGTEST_ENABLE_CATCH_EXCEPTIONS_=0"
 248     gtest test/googletest-death-test_ex_test.cc)
 249   cxx_test_with_flags(gtest-death-test_ex_catch_test
 250     "${cxx_exception} -DGTEST_ENABLE_CATCH_EXCEPTIONS_=1"
 251     gtest test/googletest-death-test_ex_test.cc)
 252
 253   cxx_test_with_flags(gtest_no_rtti_unittest "${cxx_no_rtti}"
 254     gtest_main_no_rtti test/gtest_unittest.cc)
 255
 256   cxx_shared_library(gtest_dll "${cxx_default}"
 257     src/gtest-all.cc src/gtest_main.cc)
 258
 259   cxx_executable_with_flags(gtest_dll_test_ "${cxx_default}"
 260     gtest_dll test/gtest_all_test.cc)
 261   set_target_properties(gtest_dll_test_
 262                         PROPERTIES
 263                         COMPILE_DEFINITIONS "GTEST_LINKED_AS_SHARED_LIBRARY=1")
 264
 265   ############################################################
 266   # Python tests.
 267
 268   cxx_executable(googletest-break-on-failure-unittest_ test gtest)
 269   py_test(googletest-break-on-failure-unittest)
 270
 271   py_test(gtest_skip_check_output_test)
 272   py_test(gtest_skip_environment_check_output_test)
 273
 274   # Visual Studio .NET 2003 does not support STL with exceptions disabled.
 275   if (NOT MSVC OR MSVC_VERSION GREATER 1310)  # 1310 is Visual Studio .NET 2003
 276     cxx_executable_with_flags(
 277       googletest-catch-exceptions-no-ex-test_
 278       "${cxx_no_exception}"
 279       gtest_main_no_exception
 280       test/googletest-catch-exceptions-test_.cc)
 281   endif()
 282
 283   cxx_executable_with_flags(
 284     googletest-catch-exceptions-ex-test_
 285     "${cxx_exception}"
 286     gtest_main
 287     test/googletest-catch-exceptions-test_.cc)
 288   py_test(googletest-catch-exceptions-test)
 289
 290   cxx_executable(googletest-color-test_ test gtest)
 291   py_test(googletest-color-test)
 292
 293   cxx_executable(googletest-env-var-test_ test gtest)
 294   py_test(googletest-env-var-test)
 295
 296   cxx_executable(googletest-filter-unittest_ test gtest)
 297   py_test(googletest-filter-unittest)
 298
 299   cxx_executable(gtest_help_test_ test gtest_main)
 300   py_test(gtest_help_test)
 301
 302   cxx_executable(googletest-list-tests-unittest_ test gtest)
 303   py_test(googletest-list-tests-unittest)
 304
 305   cxx_executable(googletest-output-test_ test gtest)
 306   py_test(googletest-output-test --no_stacktrace_support)
 307
 308   cxx_executable(googletest-shuffle-test_ test gtest)
 309   py_test(googletest-shuffle-test)
 310
 311   # MSVC 7.1 does not support STL with exceptions disabled.
 312   if (NOT MSVC OR MSVC_VERSION GREATER 1310)
 313     cxx_executable(googletest-throw-on-failure-test_ test gtest_no_exception)
 314     set_target_properties(googletest-throw-on-failure-test_
 315       PROPERTIES
 316       COMPILE_FLAGS "${cxx_no_exception}")
 317     py_test(googletest-throw-on-failure-test)
 318   endif()
 319
 320   cxx_executable(googletest-uninitialized-test_ test gtest)
 321   py_test(googletest-uninitialized-test)
 322
 323   cxx_executable(gtest_list_output_unittest_ test gtest)
 324   py_test(gtest_list_output_unittest)
 325
 326   cxx_executable(gtest_xml_outfile1_test_ test gtest_main)
 327   cxx_executable(gtest_xml_outfile2_test_ test gtest_main)
 328   py_test(gtest_xml_outfiles_test)
 329   py_test(googletest-json-outfiles-test)
 330
 331   cxx_executable(gtest_xml_output_unittest_ test gtest)
 332   py_test(gtest_xml_output_unittest --no_stacktrace_support)
 333   py_test(googletest-json-output-unittest --no_stacktrace_support)
 334 endif()