ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/assimp/portfile.cmake

   1 vcpkg_from_github(
   2     OUT_SOURCE_PATH SOURCE_PATH
   3     REPO assimp/assimp
   4     REF 8f0c6b04b2257a520aaab38421b2e090204b69df # v5.0.1
   5     SHA512 59b213428e2f7494cb5da423e6b2d51556318f948b00cea420090d74d4f5f0f8970d38dba70cd47b2ef35a1f57f9e15df8597411b6cd8732b233395080147c0f
   6     HEAD_REF master
   7     PATCHES
   8         build_fixes.patch
   9         irrlicht.patch
  10 )
  11
  12 file(REMOVE ${SOURCE_PATH}/cmake-modules/FindZLIB.cmake)
  13 file(REMOVE ${SOURCE_PATH}/cmake-modules/FindIrrXML.cmake)
  14 #file(REMOVE_RECURSE ${SOURCE_PATH}/contrib/clipper) # https://github.com/assimp/assimp/issues/788
  15 file(REMOVE_RECURSE ${SOURCE_PATH}/contrib/poly2tri)
  16 file(REMOVE_RECURSE ${SOURCE_PATH}/contrib/zlib)
  17 file(REMOVE_RECURSE ${SOURCE_PATH}/contrib/gtest)
  18 file(REMOVE_RECURSE ${SOURCE_PATH}/contrib/irrXML)
  19 file(REMOVE_RECURSE ${SOURCE_PATH}/contrib/rapidjson)
  20 file(REMOVE_RECURSE ${SOURCE_PATH}/contrib/stb_image)
  21 file(REMOVE_RECURSE ${SOURCE_PATH}/contrib/zip)
  22 file(REMOVE_RECURSE ${SOURCE_PATH}/contrib/unzip)
  23 file(REMOVE_RECURSE ${SOURCE_PATH}/contrib/utf8cpp)
  24 #file(REMOVE_RECURSE ${SOURCE_PATH}/contrib/Open3DGC)      #TODO
  25 #file(REMOVE_RECURSE ${SOURCE_PATH}/contrib/openddlparser) #TODO
  26
  27 set(VCPKG_C_FLAGS "${VCPKG_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS")
  28 set(VCPKG_CXX_FLAGS "${VCPKG_CXX_FLAGS} -D_CRT_SECURE_NO_WARNINGS")
  29
  30 string(COMPARE EQUAL "${VCPKG_LIBRARY_LINKAGE}" "dynamic" ASSIMP_BUILD_SHARED_LIBS)
  31
  32 vcpkg_configure_cmake(
  33     SOURCE_PATH ${SOURCE_PATH}
  34     PREFER_NINJA
  35     OPTIONS -DASSIMP_BUILD_TESTS=OFF
  36             -DASSIMP_BUILD_ASSIMP_VIEW=OFF
  37             -DASSIMP_BUILD_ZLIB=OFF
  38             -DASSIMP_BUILD_SHARED_LIBS=${ASSIMP_BUILD_SHARED_LIBS}
  39             -DASSIMP_BUILD_ASSIMP_TOOLS=OFF
  40             -DASSIMP_INSTALL_PDB=OFF
  41             -DSYSTEM_IRRXML=ON
  42             -DIGNORE_GIT_HASH=ON
  43 )
  44
  45 vcpkg_install_cmake()
  46
  47 if(VCPKG_TARGET_IS_WINDOWS)
  48     set(VCVER vc140 vc141 vc142 )
  49     set(CRT mt md)
  50     set(DBG_NAMES)
  51     set(REL_NAMES)
  52     foreach(_ver IN LISTS VCVER)
  53         foreach(_crt IN LISTS CRT)
  54             list(APPEND DBG_NAMES assimp-${_ver}-${_crt}d)
  55             list(APPEND REL_NAMES assimp-${_ver}-${_crt})
  56         endforeach()
  57     endforeach()
  58 endif()
  59
  60 find_library(ASSIMP_REL NAMES assimp ${REL_NAMES} PATHS "${CURRENT_PACKAGES_DIR}/lib" NO_DEFAULT_PATH)
  61 find_library(ASSIMP_DBG NAMES assimp assimpd ${DBG_NAMES} PATHS "${CURRENT_PACKAGES_DIR}/debug/lib" NO_DEFAULT_PATH)
  62 if(ASSIMP_REL)
  63     get_filename_component(ASSIMP_NAME_REL "${ASSIMP_REL}" NAME_WLE)
  64     vcpkg_replace_string("${CURRENT_PACKAGES_DIR}/lib/pkgconfig/assimp.pc" "-lassimp" "-l${ASSIMP_NAME_REL}")
  65 endif()
  66 if(ASSIMP_DBG)
  67     get_filename_component(ASSIMP_NAME_DBG "${ASSIMP_DBG}" NAME_WLE)
  68     vcpkg_replace_string("${CURRENT_PACKAGES_DIR}/debug/lib/pkgconfig/assimp.pc" "-lassimp" "-l${ASSIMP_NAME_DBG}")
  69 endif()
  70
  71 vcpkg_fixup_cmake_targets()
  72 vcpkg_fixup_pkgconfig() # Probably requires more fixing for static builds. See qt5-3d and the config changes below
  73 vcpkg_copy_pdbs()
  74
  75 file(READ ${CURRENT_PACKAGES_DIR}/share/assimp/assimpConfig.cmake ASSIMP_CONFIG)
  76 file(WRITE ${CURRENT_PACKAGES_DIR}/share/assimp/assimpConfig.cmake "
  77 include(CMakeFindDependencyMacro)
  78 find_dependency(ZLIB)
  79 find_dependency(irrlicht CONFIG)
  80 find_dependency(polyclipping CONFIG)
  81 find_dependency(minizip CONFIG)
  82 find_dependency(kubazip CONFIG)
  83 find_dependency(poly2tri CONFIG)
  84 find_dependency(utf8cpp CONFIG)
  85 ${ASSIMP_CONFIG}")
  86
  87 file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/debug/include)
  88 file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/debug/share)
  89
  90 file(INSTALL ${SOURCE_PATH}/LICENSE DESTINATION ${CURRENT_PACKAGES_DIR}/share/${PORT} RENAME copyright)