ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/aws-sdk-cpp/portfile.cmake

   1 vcpkg_buildpath_length_warning(37)
   2
   3 vcpkg_from_github(
   4     OUT_SOURCE_PATH SOURCE_PATH
   5     REPO aws/aws-sdk-cpp
   6     REF b11ed430fa6a574cc842532192dfeb9bb09e62b4 # 1.8.126
   7     SHA512 39e71f85d977b183df6f0d6d61a028db33573026f6abb8856f35e0e71398e2749db6dbdd033818a2c045ec42076fb23cdbae92608117db0a08ca88a05c825683
   8     HEAD_REF master
   9     PATCHES
  10         patch-relocatable-rpath.patch
  11         fix-AWSSDKCONFIG.patch
  12 )
  13
  14 string(COMPARE EQUAL "${VCPKG_CRT_LINKAGE}" "dynamic" FORCE_SHARED_CRT)
  15
  16 set(BUILD_ONLY core)
  17
  18 include(${CMAKE_CURRENT_LIST_DIR}/compute_build_only.cmake)
  19
  20 set(EXTRA_ARGS)
  21 if(VCPKG_TARGET_IS_OSX OR VCPKG_TARGET_IS_IOS)
  22     set(rpath "@loader_path")
  23 elseif (VCPKG_TARGET_IS_ANDROID)
  24     set(EXTRA_ARGS "-DTARGET_ARCH=ANDROID"
  25             "-DGIT_EXECUTABLE=--invalid-git-executable--"
  26             "-DGIT_FOUND=TRUE"
  27             "-DNDK_DIR=$ENV{ANDROID_NDK_HOME}"
  28             "-DANDROID_BUILD_ZLIB=FALSE"
  29             "-DANDROID_BUILD_CURL=FALSE"
  30             "-DANDROID_BUILD_OPENSSL=FALSE"
  31             "-DENABLE_HW_OPTIMIZATION=OFF"
  32             "-DCURL_HAS_H2_EXITCODE=0"
  33             "-DCURL_HAS_H2_EXITCODE__TRYRUN_OUTPUT=\"\""
  34             "-DCURL_HAS_TLS_PROXY_EXITCODE=0"
  35             "-DCURL_HAS_TLS_PROXY_EXITCODE__TRYRUN_OUTPUT=\"\""
  36             )
  37 else()
  38     set(rpath "\$ORIGIN")
  39 endif()
  40 vcpkg_configure_cmake(
  41     SOURCE_PATH ${SOURCE_PATH}
  42     DISABLE_PARALLEL_CONFIGURE
  43     PREFER_NINJA
  44     OPTIONS
  45         ${EXTRA_ARGS}
  46         -DENABLE_UNITY_BUILD=ON
  47         -DENABLE_TESTING=OFF
  48         -DFORCE_SHARED_CRT=${FORCE_SHARED_CRT}
  49         -DCMAKE_DISABLE_FIND_PACKAGE_Git=TRUE
  50         "-DBUILD_ONLY=${BUILD_ONLY}"
  51         -DBUILD_DEPS=OFF
  52         -DCMAKE_INSTALL_RPATH=${rpath}
  53 )
  54
  55 vcpkg_install_cmake()
  56
  57 vcpkg_fixup_cmake_targets(CONFIG_PATH lib/cmake TARGET_PATH share)
  58
  59 vcpkg_copy_pdbs()
  60
  61 file(GLOB_RECURSE AWS_TARGETS "${CURRENT_PACKAGES_DIR}/share/*/*-targets-*.cmake")
  62 foreach(AWS_TARGET IN LISTS AWS_TARGETS)
  63     file(READ ${AWS_TARGET} _contents)
  64     string(REGEX REPLACE
  65         "bin\\/([A-Za-z0-9_.-]+\\.lib)"
  66         "lib/\\1"
  67         _contents "${_contents}")
  68     file(WRITE ${AWS_TARGET} "${_contents}")
  69 endforeach()
  70
  71 file(GLOB AWS_CONFIGS "${CURRENT_PACKAGES_DIR}/share/*/aws-cpp-sdk-*-config.cmake")
  72 list(FILTER AWS_CONFIGS EXCLUDE REGEX "aws-cpp-sdk-core-config\\.cmake\$")
  73 foreach(AWS_CONFIG IN LISTS AWS_CONFIGS)
  74     file(READ "${AWS_CONFIG}" _contents)
  75     file(WRITE "${AWS_CONFIG}" "include(CMakeFindDependencyMacro)\nfind_dependency(aws-cpp-sdk-core)\n${_contents}")
  76 endforeach()
  77
  78 file(REMOVE_RECURSE
  79     ${CURRENT_PACKAGES_DIR}/debug/include
  80     ${CURRENT_PACKAGES_DIR}/debug/share
  81     ${CURRENT_PACKAGES_DIR}/lib/pkgconfig
  82     ${CURRENT_PACKAGES_DIR}/debug/lib/pkgconfig
  83     ${CURRENT_PACKAGES_DIR}/nuget
  84     ${CURRENT_PACKAGES_DIR}/debug/nuget
  85 )
  86
  87 if(VCPKG_LIBRARY_LINKAGE STREQUAL dynamic)
  88     file(GLOB LIB_FILES ${CURRENT_PACKAGES_DIR}/bin/*.lib)
  89     if(LIB_FILES)
  90         file(COPY ${LIB_FILES} DESTINATION ${CURRENT_PACKAGES_DIR}/lib)
  91         file(REMOVE ${LIB_FILES})
  92     endif()
  93     file(GLOB DEBUG_LIB_FILES ${CURRENT_PACKAGES_DIR}/debug/bin/*.lib)
  94     if(DEBUG_LIB_FILES)
  95         file(COPY ${DEBUG_LIB_FILES} DESTINATION ${CURRENT_PACKAGES_DIR}/debug/lib)
  96         file(REMOVE ${DEBUG_LIB_FILES})
  97     endif()
  98
  99     file(APPEND ${CURRENT_PACKAGES_DIR}/include/aws/core/SDKConfig.h "#ifndef USE_IMPORT_EXPORT\n#define USE_IMPORT_EXPORT\n#endif")
 100 endif()
 101
 102 configure_file(${CURRENT_PORT_DIR}/usage ${CURRENT_PACKAGES_DIR}/share/${PORT}/usage @ONLY)
 103
 104 # Handle copyright
 105 file(INSTALL ${SOURCE_PATH}/LICENSE DESTINATION ${CURRENT_PACKAGES_DIR}/share/${PORT} RENAME copyright)