ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/breakpad/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.8)
   2 project(breakpad CXX)
   3
   4 set(CMAKE_CXX_STANDARD 11)
   5 set(CMAKE_CXX_STANDARD_REQUIRED ON)
   6
   7 add_definitions(
   8     -DNOMINMAX
   9     -DUNICODE
  10     -DWIN32_LEAN_AND_MEAN
  11     -D_CRT_SECURE_NO_WARNINGS
  12     -D_CRT_SECURE_NO_DEPRECATE
  13     -D_CRT_NONSTDC_NO_DEPRECATE
  14 )
  15
  16 set(CMAKE_DEBUG_POSTFIX d)
  17
  18 string(COMPARE EQUAL "${CMAKE_BUILD_TYPE}" "Release" DEFAULT_INSTALL_HEADERS)
  19 option(INSTALL_HEADERS "Install header files" ${DEFAULT_INSTALL_HEADERS})
  20
  21 # libbreakpad target
  22 if(NOT CMAKE_SYSTEM_NAME STREQUAL Android)
  23     file(GLOB_RECURSE LIBBREAKPAD_SOURCES src/processor/*.cc)
  24     if(WIN32)
  25         list(FILTER LIBBREAKPAD_SOURCES EXCLUDE REGEX
  26             "_unittest|synth_minidump|/tests|/testdata|/linux|/mac|/android|/solaris|microdump_stackwalk|minidump_dump|minidump_stackwalk")
  27     elseif(APPLE)
  28         list(FILTER LIBBREAKPAD_SOURCES EXCLUDE REGEX
  29             "_unittest|synth_minidump|/tests|/testdata|/linux|/windows|/android|/solaris|microdump_stackwalk|minidump_dump|minidump_stackwalk")
  30     else()
  31         list(FILTER LIBBREAKPAD_SOURCES EXCLUDE REGEX
  32             "_unittest|synth_minidump|/tests|/testdata|/mac|/windows|/android|/solaris|microdump_stackwalk|minidump_dump|minidump_stackwalk")
  33     endif()
  34
  35     find_library(LIBDISASM_LIB NAMES libdisasmd libdisasm)
  36
  37     add_library(libbreakpad ${LIBBREAKPAD_SOURCES})
  38     target_link_libraries(libbreakpad PRIVATE ${LIBDISASM_LIB})
  39
  40     target_include_directories(libbreakpad
  41         PUBLIC
  42             $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src>
  43             $<INSTALL_INTERFACE:include>
  44     )
  45
  46     set(TARGETS libbreakpad)
  47 endif()
  48
  49 # libbreakpad_client target
  50 if(CMAKE_SYSTEM_NAME STREQUAL Android)
  51     file(READ "android/google_breakpad/Android.mk" android_mk)
  52     string(REGEX MATCHALL "src/[^\n]*\\.cc" LIBBREAKPAD_CLIENT_SOURCES "${android_mk}")
  53 else()
  54     if(WIN32)
  55         file(GLOB_RECURSE LIBBREAKPAD_CLIENT_SOURCES src/client/windows/*.cc src/common/windows/*.cc)
  56         include_directories("$ENV{VSINSTALLDIR}/DIA SDK/include")
  57     elseif(APPLE)
  58         add_definitions(-DHAVE_MACH_O_NLIST_H)
  59         file(GLOB_RECURSE LIBBREAKPAD_CLIENT_SOURCES src/client/mac/*.cc src/common/mac/*.cc)
  60         list(APPEND LIBBREAKPAD_CLIENT_SOURCES src/common/mac/MachIPC.mm)
  61     else()
  62         add_definitions(-DHAVE_A_OUT_H)
  63         file(GLOB_RECURSE LIBBREAKPAD_CLIENT_SOURCES src/client/linux/*.cc src/common/linux/*.cc)
  64     endif()
  65     file(GLOB LIBBREAKPAD_COMMON_SOURCES src/common/*.cc src/common/*.c src/client/*.cc)
  66     list(APPEND LIBBREAKPAD_CLIENT_SOURCES ${LIBBREAKPAD_COMMON_SOURCES})
  67 endif()
  68 list(FILTER LIBBREAKPAD_CLIENT_SOURCES EXCLUDE REGEX "/sender|/tests|/unittests|/testcases|_unittest|_test")
  69 if(WIN32)
  70     list(FILTER LIBBREAKPAD_CLIENT_SOURCES EXCLUDE REGEX "language.cc|path_helper.cc|stabs_to_module.cc|stabs_reader.cc|minidump_file_writer.cc")
  71 elseif(NOT APPLE)
  72     try_compile(HAVE_GETCONTEXT ${CMAKE_BINARY_DIR}/check_getcontext ${CMAKE_CURRENT_LIST_DIR}/check_getcontext.cc OUTPUT_VARIABLE BUILD_OUT)
  73     if (NOT HAVE_GETCONTEXT)
  74         enable_language(ASM)
  75         list(APPEND LIBBREAKPAD_CLIENT_SOURCES src/common/linux/breakpad_getcontext.S)
  76     endif()
  77 endif()
  78
  79 add_library(libbreakpad_client ${LIBBREAKPAD_CLIENT_SOURCES})
  80 if(WIN32)
  81     target_link_libraries(libbreakpad_client PRIVATE wininet.lib)
  82 elseif(APPLE)
  83     find_library(CoreFoundation_FRAMEWORK CoreFoundation)
  84     target_link_libraries(libbreakpad_client PRIVATE ${CoreFoundation_FRAMEWORK})
  85 else()
  86     find_library(PTHREAD_LIBRARIES pthread)
  87     if(PTHREAD_LIBRARIES)
  88         target_link_libraries(libbreakpad_client PRIVATE ${PTHREAD_LIBRARIES})
  89     endif()
  90     if (HAVE_GETCONTEXT)
  91         target_compile_definitions(libbreakpad_client PRIVATE HAVE_GETCONTEXT=1)
  92     endif()
  93 endif()
  94
  95 target_include_directories(libbreakpad_client
  96     PUBLIC
  97         $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src>
  98         $<INSTALL_INTERFACE:include>
  99 )
 100 list(APPEND TARGETS libbreakpad_client)
 101
 102 # installation
 103 install(TARGETS ${TARGETS} EXPORT unofficial-breakpad-targets
 104     RUNTIME DESTINATION bin
 105     LIBRARY DESTINATION lib
 106     ARCHIVE DESTINATION lib
 107 )
 108
 109 if(INSTALL_HEADERS)
 110     if(WIN32)
 111         set(HEADER_EXCLUDE_REGEX "/apple|/ios|/linux|/mac|/solaris|/android|/dwarf|/tests|/testdata|/unittests")
 112     elseif(APPLE)
 113         set(HEADER_EXCLUDE_REGEX "/apple|/ios|/linux|/windows|/solaris|/android|/dwarf|/tests|/testdata|/unittests|/sender|/testapp|/*proj|/gcov")
 114     else()
 115         set(HEADER_EXCLUDE_REGEX "/apple|/ios|/client/linux/data|/client/linux/sender|/windows|/mac|/solaris|/android|/dwarf|/tests|/testdata|/unittests")
 116         install(
 117             DIRECTORY src/third_party/lss
 118             DESTINATION include/third_party
 119             FILES_MATCHING PATTERN "*.h"
 120             REGEX "${HEADER_EXCLUDE_REGEX}" EXCLUDE
 121         )
 122     endif()
 123     install(
 124         DIRECTORY src/client src/common src/google_breakpad
 125         DESTINATION include/
 126         FILES_MATCHING
 127         PATTERN "*.h"
 128         REGEX ${HEADER_EXCLUDE_REGEX} EXCLUDE
 129     )
 130 endif()
 131
 132 install(
 133     EXPORT unofficial-breakpad-targets
 134     FILE unofficial-breakpad-config.cmake
 135     NAMESPACE unofficial::breakpad::
 136     DESTINATION share/unofficial-breakpad
 137 )