ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/clapack/FindLAPACK.cmake

   1 #.rst:
   2 # clapack config for vcpkg
   3 # ------------
   4 #
   5 # Find the clapack includes and library.
   6 #
   7 # Result Variables
   8 # ^^^^^^^^^^^^^^^^
   9 #
  10 # This script defines the following variables:
  11 #
  12 # ``CLAPACK_FOUND``
  13 #   True if clapack library found
  14 #
  15 # ``CLAPACK_VERSION``
  16 #   Containing the clapack version tag (manually defined)
  17 #
  18 # ``CLAPACK_INCLUDE_DIR``
  19 #   Location of clapack headers
  20 #
  21 # ``CLAPACK_LIBRARY``
  22 #   List of libraries to link with when using clapack
  23 #
  24 # Result Targets
  25 # ^^^^^^^^^^^^^^
  26 #
  27 # This script defines the following targets:
  28 #
  29 # ``clapack::clapack``
  30 #   Target to use clapack
  31 #
  32 # Compatibility Variables
  33 # ^^^^^^^^^^^^^^^^^^^^^^^
  34 #
  35 # This script defines the following variables for compatibility reasons:
  36 #
  37 # ``F2C_FOUND``
  38 #   True if f2c (fortran-to-c wrap layer) library found
  39 #
  40 # ``F2C_INCLUDE_DIR``
  41 #   Location of clapack headers
  42 #
  43 # ``F2C_LIBRARY``
  44 #   Library containing the fortran-to-c wrap layer, necessary for clapack and automatically included when used
  45 #
  46 # ``LAPACK_FOUND``
  47 #   True if clapack library found
  48 #
  49 # ``LAPACK_VERSION``
  50 #   Containing the clapack version tag (manually defined)
  51 #
  52 # ``LAPACK_INCLUDE_DIR``
  53 #   Location of clapack headers
  54 #
  55 # ``LAPACK_LIBRARY``
  56 #   List of libraries to link with when using clapack
  57 #
  58 # Compatibility Targets
  59 # ^^^^^^^^^^^^^^
  60 #
  61 # This script defines the following targets for compatibility reasons:
  62 #
  63 # ``lapack``
  64 #   Target to use lapack
  65
  66 include(${CMAKE_ROOT}/Modules/SelectLibraryConfigurations.cmake)
  67 include(${CMAKE_ROOT}/Modules/CheckSymbolExists.cmake)
  68 include(${CMAKE_ROOT}/Modules/FindPackageHandleStandardArgs.cmake)
  69 include(${CMAKE_ROOT}/Modules/CMakeFindDependencyMacro.cmake)
  70
  71 set(CLAPACK_VERSION "3.2.1")
  72
  73 set(CMAKE_THREAD_PREFER_PTHREAD TRUE)
  74 find_dependency(Threads)
  75
  76 if(UNIX)
  77   find_library(ADDITIONAL_LAPACK_LIBRARY m)
  78   set(PTHREAD_LINK_NAME "-pthread")
  79 endif()
  80
  81 if(NOT F2C_LIBRARY)
  82   find_library(F2C_LIBRARY_RELEASE NAMES f2c libf2c)
  83   find_library(F2C_LIBRARY_DEBUG NAMES f2cd libf2cd)
  84   select_library_configurations(F2C)
  85
  86   #keep a list of "pure" f2c libs, without dependencies
  87   set(oF2C_LIBRARY_RELEASE ${F2C_LIBRARY_RELEASE})
  88   set(oF2C_LIBRARY_DEBUG ${F2C_LIBRARY_DEBUG})
  89   set(oF2C_LIBRARY ${F2C_LIBRARY})
  90
  91   list(APPEND F2C_LIBRARY ${ADDITIONAL_LAPACK_LIBRARY})
  92 endif()
  93
  94 if(NOT LAPACK_LIBRARY)
  95   find_library(LAPACK_LIBRARY_RELEASE NAMES lapack)
  96   find_library(LAPACK_LIBRARY_DEBUG NAMES lapackd)
  97
  98   #keep a list of "pure" lapack libs, without dependencies
  99   set(oLAPACK_LIBRARY_RELEASE ${LAPACK_LIBRARY_RELEASE})
 100   set(oLAPACK_LIBRARY_DEBUG ${LAPACK_LIBRARY_DEBUG})
 101   select_library_configurations(oLAPACK)
 102
 103   list(APPEND LAPACK_LIBRARY_RELEASE ${F2C_LIBRARY_RELEASE})
 104   list(APPEND LAPACK_LIBRARY_DEBUG ${F2C_LIBRARY_DEBUG})
 105
 106   find_dependency(OpenBLAS)
 107   get_property(_loc TARGET OpenBLAS::OpenBLAS PROPERTY IMPORTED_IMPLIB_RELEASE)
 108   if(NOT _loc)
 109     get_property(_loc TARGET OpenBLAS::OpenBLAS PROPERTY LOCATION_RELEASE)
 110   endif()
 111   set(LAPACK_BLAS_LIBRARY_RELEASE ${_loc})
 112   get_property(_loc TARGET OpenBLAS::OpenBLAS PROPERTY IMPORTED_IMPLIB_DEBUG)
 113   if(NOT _loc)
 114     get_property(_loc TARGET OpenBLAS::OpenBLAS PROPERTY LOCATION_DEBUG)
 115   endif()
 116   set(LAPACK_BLAS_LIBRARY_DEBUG ${_loc})
 117   select_library_configurations(LAPACK_BLAS)
 118   list(APPEND LAPACK_LIBRARY_RELEASE ${LAPACK_BLAS_LIBRARY_RELEASE})
 119   list(APPEND LAPACK_LIBRARY_DEBUG ${LAPACK_BLAS_LIBRARY_DEBUG})
 120
 121   select_library_configurations(LAPACK)
 122   if(UNIX)
 123     list(APPEND LAPACK_LIBRARY ${PTHREAD_LINK_NAME})
 124   endif()
 125 endif()
 126
 127 if(NOT F2C_INCLUDE_DIR)
 128   find_path(F2C_INCLUDE_DIR NAMES f2c.h)
 129 endif()
 130
 131 if(NOT LAPACK_INCLUDE_DIR)
 132   find_path(LAPACK_INCLUDE_DIR NAMES clapack.h)
 133 endif()
 134
 135 list(APPEND LAPACK_INCLUDE_DIR ${F2C_INCLUDE_DIR})
 136 set(LAPACK_INCLUDE_DIR "${LAPACK_INCLUDE_DIR}" CACHE PATH "" FORCE)
 137 set(LAPACK_INCLUDE_DIRS "${LAPACK_INCLUDE_DIR}" CACHE PATH "" FORCE)
 138 set(CLAPACK_INCLUDE_DIR "${LAPACK_INCLUDE_DIR}" CACHE PATH "" FORCE)
 139 set(CLAPACK_INCLUDE_DIRS "${LAPACK_INCLUDE_DIR}" CACHE PATH "" FORCE)
 140 set(F2C_INCLUDE_DIRS "${F2C_INCLUDE_DIR}" CACHE PATH "" FORCE)
 141
 142 set(LAPACK_DLL_DIR ${LAPACK_INCLUDE_DIR})
 143 list(TRANSFORM LAPACK_DLL_DIR APPEND "/../bin")
 144 message(STATUS "LAPACK_DLL_DIR: ${LAPACK_DLL_DIR}")
 145
 146 if(WIN32)
 147   find_file(LAPACK_LIBRARY_RELEASE_DLL NAMES lapack.dll PATHS ${LAPACK_DLL_DIR})
 148   find_file(LAPACK_LIBRARY_DEBUG_FOLDER NAMES lapackd.dll PATHS ${LAPACK_DLL_DIR})
 149   find_file(F2C_LIBRARY_RELEASE_DLL NAMES f2c.dll libf2c.dll PATHS ${LAPACK_DLL_DIR})
 150   find_file(F2C_LIBRARY_DEBUG_DLL NAMES f2cd.dll libf2cd.dll PATHS ${LAPACK_DLL_DIR})
 151 endif()
 152
 153 set(LAPACK_BLAS_LIBRARY "${LAPACK_BLAS_LIBRARY}" CACHE STRING "" FORCE)
 154 set(F2C_LIBRARIES "${F2C_LIBRARY}" CACHE STRING "" FORCE)
 155 set(LAPACK_VERSION "${CLAPACK_VERSION}" CACHE STRING "" FORCE)
 156 set(LAPACK_LIBRARIES "${LAPACK_LIBRARY}" CACHE STRING "" FORCE)
 157 set(CLAPACK_LIBRARY "${LAPACK_LIBRARY}" CACHE STRING "" FORCE)
 158 set(CLAPACK_LIBRARIES "${LAPACK_LIBRARY}" CACHE STRING "" FORCE)
 159
 160 set(LAPACK_LIBRARY "${LAPACK_LIBRARY}" CACHE STRING "" FORCE)
 161 set(F2C_LIBRARY "${F2C_LIBRARY}" CACHE STRING "" FORCE)
 162 set(LAPACK_LIBRARY_RELEASE "${LAPACK_LIBRARY_RELEASE}" CACHE STRING "" FORCE)
 163 set(LAPACK_LIBRARY_DEBUG "${LAPACK_LIBRARY_DEBUG}" CACHE STRING "" FORCE)
 164 set(F2C_LIBRARY_RELEASE "${F2C_LIBRARY_RELEASE}" CACHE STRING "" FORCE)
 165 set(F2C_LIBRARY_DEBUG "${F2C_LIBRARY_DEBUG}" CACHE STRING "" FORCE)
 166
 167 find_package_handle_standard_args(LAPACK DEFAULT_MSG LAPACK_LIBRARY LAPACK_INCLUDE_DIR)
 168 mark_as_advanced(LAPACK_INCLUDE_DIR LAPACK_LIBRARY)
 169
 170 #TARGETS
 171 if(CLAPACK_FOUND AND NOT TARGET clapack::clapack)
 172   if(EXISTS "${LAPACK_LIBRARY_RELEASE_DLL}")
 173     add_library(clapack::clapack SHARED IMPORTED)
 174     set_target_properties(clapack::clapack PROPERTIES
 175       IMPORTED_LOCATION_RELEASE                 "${LAPACK_LIBRARY_RELEASE_DLL}"
 176       IMPORTED_IMPLIB_RELEASE                   "${oLAPACK_LIBRARY_RELEASE}"
 177       INTERFACE_INCLUDE_DIRECTORIES             "${LAPACK_INCLUDE_DIR}"
 178       INTERFACE_LINK_LIBRARIES                  "$<$<NOT:$<CONFIG:DEBUG>>:${oF2C_LIBRARY_RELEASE}>;$<$<CONFIG:DEBUG>:${oF2C_LIBRARY_DEBUG}>;$<$<NOT:$<CONFIG:DEBUG>>:${LAPACK_BLAS_LIBRARY_RELEASE}>;$<$<CONFIG:DEBUG>:${LAPACK_BLAS_LIBRARY_DEBUG}>;$<LINK_ONLY:${ADDITIONAL_LAPACK_LIBRARY}>;$<LINK_ONLY:${PTHREAD_LINK_NAME}>"
 179       IMPORTED_CONFIGURATIONS                   Release
 180       IMPORTED_LINK_INTERFACE_LANGUAGES         "C")
 181     if(EXISTS "${LAPACK_LIBRARY_DEBUG_DLL}")
 182       set_property(TARGET clapack::clapack APPEND PROPERTY IMPORTED_CONFIGURATIONS Debug)
 183       set_target_properties(clapack::clapack PROPERTIES
 184         IMPORTED_LOCATION_DEBUG                 "${LAPACK_LIBRARY_DEBUG_DLL}"
 185         IMPORTED_IMPLIB_DEBUG                   "${oLAPACK_LIBRARY_DEBUG}")
 186     endif()
 187   else()
 188     add_library(clapack::clapack UNKNOWN IMPORTED)
 189     set_target_properties(clapack::clapack PROPERTIES
 190       IMPORTED_LOCATION_RELEASE                 "${oLAPACK_LIBRARY_RELEASE}"
 191       INTERFACE_INCLUDE_DIRECTORIES             "${LAPACK_INCLUDE_DIR}"
 192       INTERFACE_LINK_LIBRARIES                  "$<$<NOT:$<CONFIG:DEBUG>>:${oF2C_LIBRARY_RELEASE}>;$<$<CONFIG:DEBUG>:${oF2C_LIBRARY_DEBUG}>;$<$<NOT:$<CONFIG:DEBUG>>:${LAPACK_BLAS_LIBRARY_RELEASE}>;$<$<CONFIG:DEBUG>:${LAPACK_BLAS_LIBRARY_DEBUG}>;$<LINK_ONLY:${ADDITIONAL_LAPACK_LIBRARY}>;$<LINK_ONLY:${PTHREAD_LINK_NAME}>"
 193       IMPORTED_CONFIGURATIONS                   Release
 194       IMPORTED_LINK_INTERFACE_LANGUAGES         "C")
 195     if(EXISTS "${LAPACK_LIBRARY_DEBUG}")
 196       set_property(TARGET clapack::clapack APPEND PROPERTY IMPORTED_CONFIGURATIONS Debug)
 197       set_target_properties(clapack::clapack PROPERTIES
 198         IMPORTED_LOCATION_DEBUG                 "${oLAPACK_LIBRARY_DEBUG}")
 199     endif()
 200   endif()
 201 endif()
 202
 203 if(CLAPACK_FOUND AND NOT TARGET lapack)
 204   if(EXISTS "${LAPACK_LIBRARY_RELEASE_DLL}")
 205     add_library(lapack SHARED IMPORTED)
 206     set_target_properties(lapack PROPERTIES
 207       IMPORTED_LOCATION_RELEASE                 "${LAPACK_LIBRARY_RELEASE_DLL}"
 208       IMPORTED_IMPLIB_RELEASE                   "${oLAPACK_LIBRARY_RELEASE}"
 209       INTERFACE_INCLUDE_DIRECTORIES             "${LAPACK_INCLUDE_DIR}"
 210       INTERFACE_LINK_LIBRARIES                  "$<$<NOT:$<CONFIG:DEBUG>>:${oF2C_LIBRARY_RELEASE}>;$<$<CONFIG:DEBUG>:${oF2C_LIBRARY_DEBUG}>;$<$<NOT:$<CONFIG:DEBUG>>:${LAPACK_BLAS_LIBRARY_RELEASE}>;$<$<CONFIG:DEBUG>:${LAPACK_BLAS_LIBRARY_DEBUG}>;$<LINK_ONLY:${ADDITIONAL_LAPACK_LIBRARY}>;$<LINK_ONLY:${PTHREAD_LINK_NAME}>"
 211       IMPORTED_CONFIGURATIONS                   Release
 212       IMPORTED_LINK_INTERFACE_LANGUAGES         "C")
 213     if(EXISTS "${LAPACK_LIBRARY_DEBUG_DLL}")
 214       set_property(TARGET lapack APPEND PROPERTY IMPORTED_CONFIGURATIONS Debug)
 215       set_target_properties(lapack PROPERTIES
 216         IMPORTED_LOCATION_DEBUG                 "${LAPACK_LIBRARY_DEBUG_DLL}"
 217         IMPORTED_IMPLIB_DEBUG                   "${oLAPACK_LIBRARY_DEBUG}")
 218     endif()
 219   else()
 220     add_library(lapack UNKNOWN IMPORTED)
 221     set_target_properties(lapack PROPERTIES
 222       IMPORTED_LOCATION_RELEASE                 "${oLAPACK_LIBRARY_RELEASE}"
 223       INTERFACE_INCLUDE_DIRECTORIES             "${LAPACK_INCLUDE_DIR}"
 224       IMPORTED_CONFIGURATIONS                   Release
 225       INTERFACE_LINK_LIBRARIES                  "$<$<NOT:$<CONFIG:DEBUG>>:${oF2C_LIBRARY_RELEASE}>;$<$<CONFIG:DEBUG>:${oF2C_LIBRARY_DEBUG}>;$<$<NOT:$<CONFIG:DEBUG>>:${LAPACK_BLAS_LIBRARY_RELEASE}>;$<$<CONFIG:DEBUG>:${LAPACK_BLAS_LIBRARY_DEBUG}>;$<LINK_ONLY:${ADDITIONAL_LAPACK_LIBRARY}>;$<LINK_ONLY:${PTHREAD_LINK_NAME}>"
 226       IMPORTED_LINK_INTERFACE_LANGUAGES         "C")
 227     if(EXISTS "${LAPACK_LIBRARY_DEBUG}")
 228       set_property(TARGET lapack APPEND PROPERTY IMPORTED_CONFIGURATIONS Debug)
 229       set_target_properties(lapack PROPERTIES
 230         IMPORTED_LOCATION_DEBUG                 "${oLAPACK_LIBRARY_DEBUG}")
 231     endif()
 232   endif()
 233 endif()