ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/duktape/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.13)
   2
   3
   4 set(duktape_MAJOR_VERSION 2)
   5 set(duktape_MINOR_VERSION 4)
   6 set(duktape_PATCH_VERSION 0)
   7 set(duktape_VERSION ${duktape_MAJOR_VERSION}.${duktape_MINOR_VERSION}.${duktape_PATCH_VERSION})
   8
   9 option(CMAKE_VERBOSE_MAKEFILE "Create verbose makefile" OFF)
  10 option(BUILD_SHARED_LIBS "Create duktape as a shared library" ON)
  11
  12 project(duktape VERSION ${duktape_VERSION})
  13
  14 file(GLOB_RECURSE DUKTAPE_SOURCES "${CMAKE_CURRENT_LIST_DIR}/src/*.c")
  15 file(GLOB_RECURSE DUKTAPE_HEADERS "${CMAKE_CURRENT_LIST_DIR}/src/*.h")
  16
  17 add_library(duktape ${DUKTAPE_SOURCES} ${DUKTAPE_HEADERS})
  18 target_include_directories(duktape PRIVATE "${CMAKE_CURRENT_LIST_DIR}/src")
  19 set_target_properties(duktape PROPERTIES PUBLIC_HEADER "${DUKTAPE_HEADERS}")
  20 set_target_properties(duktape PROPERTIES VERSION ${duktape_VERSION})
  21 set_target_properties(duktape PROPERTIES SOVERSION ${duktape_MAJOR_VERSION})
  22
  23 if (BUILD_SHARED_LIBS)
  24   target_compile_definitions(duktape PRIVATE -DDUK_F_DLL_BUILD)
  25 endif ()
  26
  27 install(TARGETS duktape
  28         EXPORT duktapeTargets
  29         ARCHIVE DESTINATION "lib"
  30         LIBRARY DESTINATION "lib"
  31         RUNTIME DESTINATION "bin"
  32         PUBLIC_HEADER DESTINATION "include"
  33         COMPONENT dev
  34 )
  35
  36 install(EXPORT duktapeTargets
  37   FILE duktapeTargets.cmake
  38   NAMESPACE duktape::
  39   DESTINATION "share/duktape"
  40 )
  41
  42 export(PACKAGE duktape)
  43
  44 include(CMakePackageConfigHelpers)
  45 write_basic_package_version_file("${PROJECT_BINARY_DIR}/duktapeConfigVersion.cmake"
  46   COMPATIBILITY SameMajorVersion
  47 )
  48
  49 configure_file(duktapeConfig.cmake.in "${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/duktapeConfig.cmake" @ONLY)
  50
  51 install(FILES
  52   "${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/duktapeConfig.cmake"
  53   "${PROJECT_BINARY_DIR}/duktapeConfigVersion.cmake"
  54   DESTINATION "share/duktape"
  55 )