ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/flashlight-cpu/portfile.cmake

   1 if (EXISTS "${CURRENT_INSTALLED_DIR}/share/flashlight-cuda")
   2   message(FATAL_ERROR "flashlight-cuda is installed; only one Flashlight "
   3     "backend package can be installed at once. Uninstall and try again:"
   4     "\n    vcpkg remove flashlight-cuda\n")
   5 endif()
   6
   7 vcpkg_from_github(
   8     OUT_SOURCE_PATH SOURCE_PATH
   9     REPO flashlight/flashlight
  10     REF 76f7fa7f5a162c73d6bf8befdb8e197a4dc7515d # 0.3 branch tip
  11     SHA512 87786f9443d27ac9b513cf582caea13dccfa344e55a4970c0c2c7df7530260ad38cc578690ebf2fa256e8ea943abea547e0e6d5ee0ba090b336c4f7af8d2f53f
  12     HEAD_REF master
  13 )
  14
  15 # Default flags
  16 set(FL_DEFAULT_VCPKG_CMAKE_FLAGS
  17   -DFL_BUILD_TESTS=OFF
  18   -DFL_BUILD_EXAMPLES=OFF
  19   -DFL_BACKEND=CPU # this port is CPU-backend only
  20   -DFL_BUILD_STANDALONE=OFF
  21   -DFL_INSTALL_CMAKE_DIR=${CURRENT_PACKAGES_DIR}/share/${PORT} # for CMake configs/targets
  22 )
  23
  24 # Determine which components to build via specified feature
  25 vcpkg_check_features(
  26     OUT_FEATURE_OPTIONS FEATURE_OPTIONS
  27     FEATURES
  28     lib FL_BUILD_LIBRARIES
  29     fl FL_BUILD_CORE
  30     asr FL_BUILD_APP_ASR
  31     imgclass FL_BUILD_APP_IMGCLASS
  32     lm FL_BUILD_APP_LM
  33     objdet FL_BUILD_APP_OBJDET
  34 )
  35
  36 # Build and install
  37 vcpkg_configure_cmake(
  38     SOURCE_PATH ${SOURCE_PATH}
  39     PREFER_NINJA
  40     OPTIONS
  41         ${FL_DEFAULT_VCPKG_CMAKE_FLAGS}
  42         ${FEATURE_OPTIONS}
  43 )
  44 vcpkg_install_cmake()
  45
  46 file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/include")
  47 file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/share")
  48
  49 # Binaries/tools
  50 set(FLASHLIGHT_TOOLS "")
  51 if ("imgclass" IN_LIST FEATURES)
  52   list(APPEND FLASHLIGHT_TOOLS
  53     fl_img_imagenet_resnet34
  54     fl_img_imagenet_eval
  55     fl_img_imagenet_vit
  56   )
  57 endif()
  58 if ("asr" IN_LIST FEATURES)
  59   list(APPEND FLASHLIGHT_TOOLS
  60     fl_asr_train
  61     fl_asr_test
  62     fl_asr_decode
  63     fl_asr_align
  64     fl_asr_voice_activity_detection_ctc
  65     fl_asr_arch_benchmark
  66   )
  67 endif()
  68 if ("lm" IN_LIST FEATURES)
  69   list(APPEND FLASHLIGHT_TOOLS
  70     fl_lm_dictionary_builder
  71     fl_lm_train
  72     fl_lm_test
  73   )
  74 endif()
  75 list(LENGTH FLASHLIGHT_TOOLS NUM_TOOLS)
  76 if (NUM_TOOLS GREATER 0)
  77   vcpkg_copy_tools(TOOL_NAMES ${FLASHLIGHT_TOOLS} AUTO_CLEAN)
  78 endif()
  79
  80 # Copyright
  81 file(INSTALL ${SOURCE_PATH}/LICENSE DESTINATION ${CURRENT_PACKAGES_DIR}/share/${PORT} RENAME copyright)