ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/flashlight-cuda/portfile.cmake

   1 if (EXISTS "${CURRENT_INSTALLED_DIR}/share/flashlight-cpu")
   2   message(FATAL_ERROR "flashlight-cpu is installed; only one Flashlight "
   3     "backend package can be installed at once. Uninstall and try again:"
   4     "\n    vcpkg remove flashlight-cpu\n")
   5 endif()
   6
   7 vcpkg_from_github(
   8     OUT_SOURCE_PATH SOURCE_PATH
   9     REPO flashlight/flashlight
  10     REF 76f7fa7f5a162c73d6bf8befdb8e197a4dc7515d # 0.3 branch tip
  11     SHA512 87786f9443d27ac9b513cf582caea13dccfa344e55a4970c0c2c7df7530260ad38cc578690ebf2fa256e8ea943abea547e0e6d5ee0ba090b336c4f7af8d2f53f
  12     HEAD_REF master
  13 )
  14
  15 ################################### Build ###################################
  16 # Default flags
  17 set(FL_DEFAULT_VCPKG_CMAKE_FLAGS
  18   -DFL_BUILD_TESTS=OFF
  19   -DFL_BUILD_EXAMPLES=OFF
  20   -DFL_BACKEND=CUDA # this port is CUDA-backend only
  21   -DFL_BUILD_STANDALONE=OFF
  22   -DFL_INSTALL_CMAKE_DIR=${CURRENT_PACKAGES_DIR}/share/${PORT} # for CMake configs/targets
  23 )
  24
  25 # Determine which components to build via specified feature
  26 vcpkg_check_features(
  27     OUT_FEATURE_OPTIONS FEATURE_OPTIONS
  28     FEATURES
  29     lib FL_BUILD_LIBRARIES
  30     fl FL_BUILD_CORE
  31     asr FL_BUILD_APP_ASR
  32     imgclass FL_BUILD_APP_IMGCLASS
  33     lm FL_BUILD_APP_LM
  34     objdet FL_BUILD_APP_OBJDET
  35     )
  36
  37 # Build and install
  38 vcpkg_configure_cmake(
  39     SOURCE_PATH ${SOURCE_PATH}
  40     PREFER_NINJA
  41     OPTIONS
  42         ${FL_DEFAULT_VCPKG_CMAKE_FLAGS}
  43         ${FEATURE_OPTIONS}
  44 )
  45 vcpkg_install_cmake()
  46
  47 file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/include")
  48 file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/share")
  49
  50 # Binaries/tools
  51 set(FLASHLIGHT_TOOLS "")
  52 if ("imgclass" IN_LIST FEATURES)
  53   list(APPEND FLASHLIGHT_TOOLS
  54     fl_img_imagenet_resnet34
  55     fl_img_imagenet_eval
  56     fl_img_imagenet_vit
  57   )
  58 endif()
  59 if ("asr" IN_LIST FEATURES)
  60   list(APPEND FLASHLIGHT_TOOLS
  61     fl_asr_train
  62     fl_asr_test
  63     fl_asr_decode
  64     fl_asr_align
  65     fl_asr_voice_activity_detection_ctc
  66     fl_asr_arch_benchmark
  67   )
  68 endif()
  69 if ("lm" IN_LIST FEATURES)
  70   list(APPEND FLASHLIGHT_TOOLS
  71     fl_lm_dictionary_builder
  72     fl_lm_train
  73     fl_lm_test
  74     )
  75 endif()
  76 list(LENGTH FLASHLIGHT_TOOLS NUM_TOOLS)
  77 if (NUM_TOOLS GREATER 0)
  78   vcpkg_copy_tools(TOOL_NAMES ${FLASHLIGHT_TOOLS} AUTO_CLEAN)
  79 endif()
  80
  81 # Copyright
  82 file(INSTALL ${SOURCE_PATH}/LICENSE DESTINATION ${CURRENT_PACKAGES_DIR}/share/${PORT} RENAME copyright)