ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/folly/portfile.cmake

   1 if(NOT VCPKG_TARGET_ARCHITECTURE STREQUAL x64)
   2   message(FATAL_ERROR "Folly only supports the x64 architecture.")
   3 endif()
   4
   5 vcpkg_check_linkage(ONLY_STATIC_LIBRARY)
   6
   7 # Required to run build/generate_escape_tables.py et al.
   8 vcpkg_find_acquire_program(PYTHON3)
   9 get_filename_component(PYTHON3_DIR "${PYTHON3}" DIRECTORY)
  10 vcpkg_add_to_path("${PYTHON3_DIR}")
  11
  12 vcpkg_from_github(
  13     OUT_SOURCE_PATH SOURCE_PATH
  14     REPO facebook/folly
  15     REF 430aa0d8db79989dd56f8a0361fcb1c305618e41 # v2020.10.19.00
  16     SHA512 d9f6aa0f7a8aee044c01af289d71e4c80d63e40ff128ac840663e3103d19cdd0da161a0b0d106493d950b9ac9a905c5e2abf8c1970c2f16b94dd95c0d1b1943e
  17     HEAD_REF master
  18     PATCHES
  19         missing-include-atomic.patch
  20         reorder-glog-gflags.patch
  21         disable-non-underscore-posix-names.patch
  22         boost-1.70.patch
  23 )
  24
  25 file(COPY
  26     ${CMAKE_CURRENT_LIST_DIR}/FindLZ4.cmake
  27     ${CMAKE_CURRENT_LIST_DIR}/FindSnappy.cmake
  28     DESTINATION ${SOURCE_PATH}/CMake/
  29 )
  30 file(REMOVE ${SOURCE_PATH}/CMake/FindGFlags.cmake)
  31
  32 if(VCPKG_CRT_LINKAGE STREQUAL static)
  33     set(MSVC_USE_STATIC_RUNTIME ON)
  34 else()
  35     set(MSVC_USE_STATIC_RUNTIME OFF)
  36 endif()
  37
  38 set(FEATURE_OPTIONS)
  39
  40 macro(feature FEATURENAME PACKAGENAME)
  41     if("${FEATURENAME}" IN_LIST FEATURES)
  42         list(APPEND FEATURE_OPTIONS -DCMAKE_DISABLE_FIND_PACKAGE_${PACKAGENAME}=OFF)
  43     else()
  44         list(APPEND FEATURE_OPTIONS -DCMAKE_DISABLE_FIND_PACKAGE_${PACKAGENAME}=ON)
  45     endif()
  46 endmacro()
  47
  48 feature(zlib ZLIB)
  49 feature(bzip2 BZip2)
  50 feature(lzma LibLZMA)
  51 feature(lz4 LZ4)
  52 feature(zstd Zstd)
  53 feature(snappy Snappy)
  54
  55 vcpkg_configure_cmake(
  56     SOURCE_PATH ${SOURCE_PATH}
  57     PREFER_NINJA
  58     OPTIONS
  59         -DMSVC_USE_STATIC_RUNTIME=${MSVC_USE_STATIC_RUNTIME}
  60         -DCMAKE_DISABLE_FIND_PACKAGE_LibDwarf=ON
  61         -DCMAKE_DISABLE_FIND_PACKAGE_Libiberty=ON
  62         -DCMAKE_DISABLE_FIND_PACKAGE_LibAIO=ON
  63         -DLIBAIO_FOUND=OFF
  64         -DLIBURCU_FOUND=OFF
  65         -DCMAKE_DISABLE_FIND_PACKAGE_LibURCU=ON
  66         -DCMAKE_INSTALL_DIR=share/folly
  67         ${FEATURE_OPTIONS}
  68 )
  69
  70 vcpkg_install_cmake(ADD_BIN_TO_PATH)
  71
  72 vcpkg_copy_pdbs()
  73
  74 vcpkg_fixup_cmake_targets()
  75
  76 # Release folly-targets.cmake does not link to the right libraries in debug mode.
  77 # We substitute with generator expressions so that the right libraries are linked for debug and release.
  78 set(FOLLY_TARGETS_CMAKE "${CURRENT_PACKAGES_DIR}/share/folly/folly-targets.cmake")
  79 FILE(READ ${FOLLY_TARGETS_CMAKE} _contents)
  80 string(REPLACE "\${_IMPORT_PREFIX}/lib/zlib.lib" "ZLIB::ZLIB" _contents "${_contents}")
  81 STRING(REPLACE "\${_IMPORT_PREFIX}/lib/" "\${_IMPORT_PREFIX}/\$<\$<CONFIG:DEBUG>:debug/>lib/" _contents "${_contents}")
  82 STRING(REPLACE "\${_IMPORT_PREFIX}/debug/lib/" "\${_IMPORT_PREFIX}/\$<\$<CONFIG:DEBUG>:debug/>lib/" _contents "${_contents}")
  83 string(REPLACE "-vc140-mt.lib" "-vc140-mt\$<\$<CONFIG:DEBUG>:-gd>.lib" _contents "${_contents}")
  84 FILE(WRITE ${FOLLY_TARGETS_CMAKE} "${_contents}")
  85 FILE(READ ${CURRENT_PACKAGES_DIR}/share/folly/folly-config.cmake _contents)
  86 FILE(WRITE ${CURRENT_PACKAGES_DIR}/share/folly/folly-config.cmake
  87 "include(CMakeFindDependencyMacro)
  88 find_dependency(Threads)
  89 find_dependency(glog CONFIG)
  90 find_dependency(gflags CONFIG REQUIRED)
  91 find_dependency(ZLIB)
  92 ${_contents}")
  93
  94 file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/debug/include)
  95
  96 # Handle copyright
  97 file(INSTALL ${SOURCE_PATH}/LICENSE DESTINATION ${CURRENT_PACKAGES_DIR}/share/${PORT} RENAME copyright)