ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/glew/portfile.cmake

   1 # Don't change to vcpkg_from_github! The sources in the git repository (archives) are missing some files that are distributed inside releases.
   2 # More info: https://github.com/nigels-com/glew/issues/31 and https://github.com/nigels-com/glew/issues/13
   3 vcpkg_download_distfile(ARCHIVE
   4     URLS "https://github.com/nigels-com/glew/releases/download/glew-2.1.0/glew-2.1.0.tgz"
   5     FILENAME "glew-2.1.0.tgz"
   6     SHA512 9a9b4d81482ccaac4b476c34ed537585ae754a82ebb51c3efa16d953c25cc3931be46ed2e49e79c730cd8afc6a1b78c97d52cd714044a339c3bc29734cd4d2ab
   7 )
   8
   9 vcpkg_extract_source_archive_ex(
  10     OUT_SOURCE_PATH SOURCE_PATH
  11     ARCHIVE ${ARCHIVE}
  12     REF glew
  13     PATCHES fix-LNK2019.patch
  14 )
  15
  16 vcpkg_configure_cmake(
  17     SOURCE_PATH ${SOURCE_PATH}/build/cmake
  18     PREFER_NINJA
  19     DISABLE_PARALLEL_CONFIGURE
  20     OPTIONS
  21         -DBUILD_UTILS=OFF
  22 )
  23
  24 vcpkg_install_cmake()
  25 vcpkg_fixup_cmake_targets(CONFIG_PATH lib/cmake/glew)
  26 # Skip check the required dependency opengl
  27 vcpkg_fixup_pkgconfig(SKIP_CHECK)
  28
  29 if(VCPKG_TARGET_IS_WINDOWS AND NOT VCPKG_TARGET_IS_MINGW)
  30 set(_targets_cmake_files)
  31 if(NOT DEFINED VCPKG_BUILD_TYPE OR VCPKG_BUILD_TYPE STREQUAL "debug")
  32     list(APPEND _targets_cmake_files "${CURRENT_PACKAGES_DIR}/share/glew/glew-targets-debug.cmake")
  33 endif()
  34 if(NOT DEFINED VCPKG_BUILD_TYPE OR VCPKG_BUILD_TYPE STREQUAL "release")
  35     list(APPEND _targets_cmake_files "${CURRENT_PACKAGES_DIR}/share/glew/glew-targets-release.cmake")
  36 endif()
  37
  38 foreach(FILE ${_targets_cmake_files})
  39     file(READ ${FILE} _contents)
  40     string(REPLACE "libglew32" "glew32" _contents "${_contents}")
  41     file(WRITE ${FILE} "${_contents}")
  42 endforeach()
  43
  44 if(EXISTS ${CURRENT_PACKAGES_DIR}/lib/libglew32.lib)
  45     file(RENAME ${CURRENT_PACKAGES_DIR}/lib/libglew32.lib ${CURRENT_PACKAGES_DIR}/lib/glew32.lib)
  46 endif()
  47 if(EXISTS ${CURRENT_PACKAGES_DIR}/debug/lib/libglew32d.lib)
  48     file(RENAME ${CURRENT_PACKAGES_DIR}/debug/lib/libglew32d.lib ${CURRENT_PACKAGES_DIR}/debug/lib/glew32d.lib)
  49 endif()
  50 endif()
  51
  52 if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")
  53     file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/debug/bin)
  54     file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/bin)
  55     foreach(FILE ${CURRENT_PACKAGES_DIR}/include/GL/glew.h ${CURRENT_PACKAGES_DIR}/include/GL/wglew.h ${CURRENT_PACKAGES_DIR}/include/GL/glxew.h)
  56         file(READ ${FILE} _contents)
  57         string(REPLACE "#ifdef GLEW_STATIC" "#if 1" _contents "${_contents}")
  58         file(WRITE ${FILE} "${_contents}")
  59     endforeach()
  60 endif()
  61
  62 vcpkg_copy_pdbs()
  63
  64 file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/debug/include)
  65 file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/debug/share)
  66
  67 file(INSTALL ${CMAKE_CURRENT_LIST_DIR}/vcpkg-cmake-wrapper.cmake DESTINATION ${CURRENT_PACKAGES_DIR}/share/${PORT})
  68 file(INSTALL ${SOURCE_PATH}/LICENSE.txt DESTINATION ${CURRENT_PACKAGES_DIR}/share/${PORT} RENAME copyright)
  69 file(COPY ${CMAKE_CURRENT_LIST_DIR}/usage DESTINATION ${CURRENT_PACKAGES_DIR}/share/${PORT})