ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/glibmm/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.9)
   2 project(glibmm)
   3
   4 set(CMAKE_CXX_STANDARD 17)
   5
   6 set(GLIBMM_DLL_SUFFIX 2)
   7 set(GLIBMM_LIB_SUFFIX 2.0)
   8 set(GLIBMM_EXTRA_LIB_SUFFIX 2.4)
   9
  10 find_path(GLIB_INCLUDE_DIR NAMES glib.h)
  11 find_library(GLIB_LIBRARY NAMES glib-2.0)
  12 find_library(GIO_LIBRARY NAMES gio-2.0)
  13 find_library(GOBJECT_LIBRARY NAMES gobject-2.0)
  14 find_library(GMODULE_LIBRARY NAMES gmodule-2.0)
  15 find_library(GTHREAD_LIBRARY NAMES gthread-2.0)
  16 find_program(GLIB_COMPILE_SCHEMAS NAMES glib-compile-schemas)
  17 find_library(PCRE_LIBRARY NAMES pcre)
  18 find_library(SIGC_LIBRARY NAMES sigc-2.0)
  19 find_library(FFI_LIBRARY NAMES ffi libffi)
  20
  21 include_directories(${GLIB_INCLUDE_DIR})
  22 link_libraries(
  23     ${GIO_LIBRARY}
  24     ${GOBJECT_LIBRARY}
  25     ${GMODULE_LIBRARY}
  26     ${GTHREAD_LIBRARY}
  27     ${GLIB_LIBRARY}
  28     ${PCRE_LIBRARY}
  29     ${SIGC_LIBRARY}
  30     ${FFI_LIBRARY}
  31 )
  32
  33 find_package(Intl REQUIRED)
  34 find_package(Iconv REQUIRED)
  35 link_libraries(${Intl_LIBRARIES} Iconv::Iconv)
  36
  37 if(APPLE)
  38   find_library(COREFOUNDATION_LIBRARY CoreFoundation)
  39   find_library(CORESERVICES_LIBRARY CoreServices)
  40   find_library(FOUNDATION_LIBRARY Foundation)
  41   link_libraries(${COREFOUNDATION_LIBRARY} ${CORESERVICES_LIBRARY} ${FOUNDATION_LIBRARY})
  42 endif()
  43
  44 # Activate workaround for exporting all symbols from Windows DLLs to mimic the
  45 # behavior on Linux, where dynamic libraries always export all symbols.
  46 # The same approach was already used by the upstream MSVC build (see MSVC_NMake/gendef/gendef.cc)
  47 if (WIN32)
  48     set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS TRUE)
  49 endif()
  50
  51 if(NOT BUILD_SHARED_LIBS)
  52     add_definitions(-DGLIBMM_STATIC_LIB -DGIOMM_STATIC_LIB)
  53 endif()
  54
  55 if(WIN32)
  56     add_compile_options(/FI${WARNINGS_HEADER} -DSIZEOF_WCHAR_T=2)
  57 else()
  58     set(THREADS_PREFER_PTHREAD_FLAG ON)
  59     find_package(Threads REQUIRED)
  60     link_libraries(Threads::Threads ${CMAKE_DL_LIBS})
  61 endif()
  62
  63 if(WIN32)
  64     configure_file(MSVC_Net2013/giomm/giommconfig.h ${CMAKE_BINARY_DIR}/config/gio/giommconfig.h COPYONLY)
  65     configure_file(MSVC_Net2013/glibmm/glibmmconfig.h ${CMAKE_BINARY_DIR}/config/glib/glibmmconfig.h COPYONLY)
  66 else()
  67     set(ENV{GLIB_COMPILE_SCHEMAS} "${GLIB_COMPILE_SCHEMAS}")
  68     set(ENV{GLIBMM_CFLAGS} -I${GLIB_INCLUDE_DIR})
  69     set(ENV{GLIBMM_LIBS} "${GLIB_LIBRARY}")
  70     set(ENV{GIOMM_CFLAGS} -I${GLIB_INCLUDE_DIR})
  71     set(ENV{GIOMM_LIBS} "${GIO_LIBRARY}")
  72     set(ENV{PKG_CONFIG} "echo")
  73
  74     file(MAKE_DIRECTORY ${CMAKE_BINARY_DIR}/config)
  75     execute_process(
  76         COMMAND "${CMAKE_SOURCE_DIR}/configure"
  77         WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/config
  78         RESULT_VARIABLE res
  79     )
  80     if(NOT res EQUAL 0)
  81         message(FATAL_ERROR "Configure failed.")
  82     endif()
  83 endif()
  84
  85 file(GLOB GLIBMM_SOURCES glib/glibmm/*.cc)
  86 add_library(glibmm ${GLIBMM_SOURCES})
  87 target_compile_definitions(glibmm PRIVATE -DGLIBMM_BUILD)
  88 target_include_directories(glibmm PUBLIC glib ${CMAKE_BINARY_DIR}/config/glib)
  89 set_target_properties(glibmm PROPERTIES OUTPUT_NAME glibmm-${GLIBMM_DLL_SUFFIX} ARCHIVE_OUTPUT_NAME glibmm-${GLIBMM_LIB_SUFFIX})
  90
  91 set(GLIBMM_EXTRA_SOURCES tools/extra_defs_gen/generate_extra_defs.cc)
  92 add_library(glibmm_generate_extra_defs ${GLIBMM_EXTRA_SOURCES})
  93 target_include_directories(glibmm_generate_extra_defs PUBLIC glib ${CMAKE_BINARY_DIR}/config/glib)
  94 set_target_properties(glibmm_generate_extra_defs PROPERTIES
  95     OUTPUT_NAME glibmm_generate_extra_defs-${GLIBMM_EXTRA_LIB_SUFFIX}
  96     ARCHIVE_OUTPUT_NAME glibmm_generate_extra_defs-${GLIBMM_EXTRA_LIB_SUFFIX})
  97
  98 set(prefix ${CMAKE_INSTALL_PREFIX})
  99 set(exec_prefix ${CMAKE_INSTALL_PREFIX})
 100 set(libdir ${CMAKE_INSTALL_PREFIX}/lib)
 101 set(includedir ${CMAKE_INSTALL_PREFIX}/include)
 102 set(GLIBMM_API_VERSION 2.0)
 103 set(GLIBMM_MODULE_NAME glibmm)
 104 set(PACKAGE_VERSION 2.52.1)
 105 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/glib/glibmm.pc.in" "${CMAKE_CURRENT_BINARY_DIR}/glibmm.pc" @ONLY)
 106 install(FILES "${CMAKE_CURRENT_BINARY_DIR}/glibmm.pc" DESTINATION lib/pkgconfig)
 107 install(FILES "${CMAKE_CURRENT_BINARY_DIR}/glibmm.pc" DESTINATION lib/pkgconfig RENAME glibmm-2.4.pc)
 108
 109 file(GLOB GIOMM_SOURCES gio/giomm/*.cc)
 110 if(WIN32)
 111     list(FILTER GIOMM_SOURCES EXCLUDE REGEX "desktopappinfo.cc\$|/unix[^/]+.cc\$")
 112 endif()
 113 add_library(giomm ${GIOMM_SOURCES})
 114 target_compile_definitions(giomm PRIVATE -DGIOMM_BUILD)
 115 target_link_libraries(giomm PUBLIC glibmm)
 116 target_include_directories(giomm PUBLIC gio ${CMAKE_BINARY_DIR}/config/gio)
 117
 118 install(
 119     TARGETS glibmm giomm glibmm_generate_extra_defs
 120     RUNTIME DESTINATION bin
 121     ARCHIVE DESTINATION lib
 122     LIBRARY DESTINATION lib
 123 )
 124
 125 if(NOT DISABLE_INSTALL_HEADERS)
 126     install(
 127         FILES
 128             ${CMAKE_BINARY_DIR}/config/gio/giommconfig.h
 129             gio/giomm.h
 130             ${CMAKE_BINARY_DIR}/config/glib/glibmmconfig.h
 131             glib/glibmm.h
 132         DESTINATION include
 133     )
 134     install(
 135         DIRECTORY gio/giomm glib/glibmm
 136         DESTINATION include
 137         FILES_MATCHING PATTERN *.h
 138     )
 139     install(
 140         DIRECTORY tools/extra_defs_gen/
 141         DESTINATION include/glibmm_generate_extra_defs/
 142         FILES_MATCHING PATTERN *.h
 143     )
 144 endif()
 145
 146 if(NOT DISABLE_EXAMPLES)
 147     add_executable(options examples/options/main.cc)
 148     target_link_libraries(options PRIVATE giomm)
 149 endif()