ceph/src/jaegertracing/opentelemetry-cpp/tools/vcpkg/ports/jsonnet/portfile.cmake

   1 if (VCPKG_TARGET_IS_WINDOWS)
   2   vcpkg_check_linkage(ONLY_STATIC_LIBRARY)
   3 endif()
   4
   5 vcpkg_from_github(
   6   OUT_SOURCE_PATH SOURCE_PATH
   7   REPO google/jsonnet
   8   REF 3f58aa551c917d6a7a2c6d042ee27f93d895ac0b # v0.16.0
   9   SHA512 448f4ff433a43ec21c3b67ea508d624e03dac420878e453e908a465cd517c79ae657f107c92e28a4ae2d2527baaf9a3ae1c6ea4c7e7e4f5062d3fad4e76e668c
  10   HEAD_REF master
  11   PATCHES
  12     001-enable-msvc.patch
  13     002-fix-dependency-and-install.patch
  14     0003-use-upstream-nlohmann-json.patch
  15     0004-incorporate-md5.patch
  16 )
  17
  18 if(VCPKG_TARGET_IS_WINDOWS)
  19   find_program(PWSH_PATH pwsh)
  20   vcpkg_execute_required_process(
  21     COMMAND "${PWSH_PATH}" -Command "((Get-Content -AsByteStream \"${SOURCE_PATH}/stdlib/std.jsonnet\") -join ',') + ',0' | Out-File -Encoding Ascii \"${SOURCE_PATH}/core/std.jsonnet.h\""
  22     WORKING_DIRECTORY "${SOURCE_PATH}"
  23     LOGNAME "std.jsonnet"
  24   )
  25 else()
  26   vcpkg_execute_required_process(
  27     COMMAND bash -c "((od -v -Anone -t u1 \"${SOURCE_PATH}/stdlib/std.jsonnet\" | tr ' ' '\\n' | grep -v '^$' | tr '\\n' ',' ) && echo '0') > \"${SOURCE_PATH}/core/std.jsonnet.h\""
  28     WORKING_DIRECTORY "${SOURCE_PATH}"
  29     LOGNAME "std.jsonnet"
  30   )
  31 endif()
  32
  33 if(VCPKG_LIBRARY_LINKAGE STREQUAL "dynamic")
  34     set(BUILD_SHARED ON)
  35     set(BUILD_STATIC OFF)
  36 else()
  37     set(BUILD_SHARED OFF)
  38     set(BUILD_STATIC ON)
  39 endif()
  40
  41 vcpkg_configure_cmake(
  42   SOURCE_PATH ${SOURCE_PATH}
  43   PREFER_NINJA
  44   OPTIONS
  45     -DBUILD_SHARED_BINARIES=${BUILD_SHARED}
  46     -DBUILD_STATIC_LIBS=${BUILD_STATIC}
  47     -DBUILD_JSONNET=OFF
  48     -DBUILD_JSONNETFMT=OFF
  49     -DBUILD_TESTS=OFF
  50     -DUSE_SYSTEM_JSON=ON
  51 )
  52
  53 vcpkg_install_cmake()
  54 vcpkg_copy_pdbs()
  55 vcpkg_copy_tool_dependencies(${CURRENT_PACKAGES_DIR}/tools/jsonnet)
  56
  57 file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/debug/include)
  58
  59 file(INSTALL ${SOURCE_PATH}/LICENSE DESTINATION ${CURRENT_PACKAGES_DIR}/share/${PORT} RENAME copyright)